Wenn man nicht weiß, wieviel Einträge zu erwarten sind, legt man erst mal eine fiktive Größe von 1000 vor (kann auch 10.000 sein, tut niemandem weh). Und nach jeder Vergrößerung des Zählers prüft man, ob dieser Wert erreicht wurde. Wenn ja, wird an dieser Stelle ein ReDim mit Erweiterung des Array um die Blockgröße vorgenommen.
Das mildert das Problem erheblich ist aber noch nicht ganz der Königsweg.
Insbesondere bei großen Arrays sorgt die Blockgröße dann für eine immer noch hohe Anzahl an ReDims.
Besser wäre es daher, wenn auch die Blockgröße dynamisch mit der Arraygröße wächst.
Am allereinfachsten geht dies indem man die Arraygröße bei einem Resize schlicht verdoppelt (oder jeder andere beliebige Faktor).
Das ist flotter als mit festen Blockgrößen zu hantieren wo sich der Schreiber erstmal um eine vernünftige Größe hierfür Gedanken machen muss aber Code-mäßig sogar noch simpler:
Global $N = 1e5 + 20 ; Anzahl an Elementen, welche einzeln dem Array angefügt werden
Global $iTimer, $nDiff
#Region Variante mit festen Blockgrößen
$iTimer = TimerInit()
Global $iBlockSizeArray = 500
Global $aResult[$iBlockSizeArray]
Global $iCount = 0
For $i = 1 To $N
If $iCount = UBound($aResult) Then ReDim $aResult[UBound($aResult) +$iBlockSizeArray]
$aResult[$iCount] = $iCount
$iCount += 1
Next
; abschließendes ReDim um Endgröße festzumachen:
Redim $aResult[$iCount]
; Zeitmessung + Ergebnisausgabe
$nDiff = TimerDiff($iTimer)
ConsoleWrite(StringFormat("% 19s: % 8.3f ms\n", "feste Blockgrößen", $nDiff))
#endRegion
#Region Variante mit Verdopplung
$iTimer = TimerInit()
Global $aResult[1]
Global $iCount = 0
For $i = 1 To $N
If $iCount = UBound($aResult) Then ReDim $aResult[2 * UBound($aResult)]
$aResult[$iCount] = $iCount
$iCount += 1
Next
; abschließendes ReDim um Endgröße festzumachen:
Redim $aResult[$iCount]
; Zeitmessung + Ergebnisausgabe
$nDiff = TimerDiff($iTimer)
ConsoleWrite(StringFormat("% 19s: % 8.3f ms\n", "Verdopplung", $nDiff))
#endRegion
Alles anzeigen
Mal abgesehen davon, dass man dynamische Arrays nicht braucht, wenn man wie Velted schon schrieb, die Anzahl der Einträge auch einfach vorher abfragen kann.
Zu der eigentlichen Thematik hier will ich mich eigentlich nicht äußern, da ich das bei mir selbst so nicht testen kann.
Daher nur vielleicht mal als Gedankeneinwurf:
Oben im Skript werden erst alle Einträge von Lenovo_BiosSetting abgefragt und dann hinterher geschaut ob der Wert CurrentSetting leer ist.
Man kann jedoch, da es sich um WQL handelt, sich gleich bei der Abfrage nur die Elemente zurückgeben lassen, bei welchen CurrentSetting gesetzt ist:
$objWMIService.ExecQuery('SELECT * FROM Lenovo_BiosSetting WHERE CurrentSetting <> ""' ...