1. Dashboard
  2. Mitglieder
    1. Letzte Aktivitäten
    2. Benutzer online
    3. Team
    4. Mitgliedersuche
  3. Forenregeln
  4. Forum
    1. Unerledigte Themen
  • Anmelden
  • Registrieren
  • Suche
Alles
  • Alles
  • Artikel
  • Seiten
  • Forum
  • Erweiterte Suche
  1. AutoIt.de - Das deutschsprachige Forum.
  2. Mitglieder
  3. AspirinJunkie

Beiträge von AspirinJunkie

  • Letzten beiden Zeichen vom Computernamen auslesen?

    • AspirinJunkie
    • 17. März 2017 um 03:11

    Siehe Autoit-Hilfe: >>StringRight()<<

  • In Textdatei suchen

    • AspirinJunkie
    • 15. März 2017 um 13:21

    Alternativ hierzu wäre auch ein Dictionary möglich.
    Damit würde das Durchsuchen des Arrays entfallen um den gewünschten Wert zu ermitteln (außer natürlich bei der Methode wo die Zahl=ArrayIndex).
    Bsp:

    AutoIt
    $o_Marken = ObjCreate("Scripting.Dictionary")
    $o_Marken("11") = "Samsung"
    $o_Marken("12") = "DELL"
    $o_Marken("13") = "HP"
    
    
    $s_Zahl = String(12)
    
    
    MsgBox(0,"", $s_Zahl & " = " &  $o_Marken($s_Zahl))
  • In Textdatei suchen

    • AspirinJunkie
    • 15. März 2017 um 10:16

    _FileCountLines akzeptiert nur einen Pfad als String und kein bereits offenes Handle.
    Mal davon abgesehen iteriert man nicht durch eine Datei per Zeilenparameter sondern lässt die Funktion selbst immer weiter weiter springen.
    Es braucht dann auch kein _FileCountLines mehr vorher.
    Kurz: Der zweite Parameter von FileReadline ist böse wenn man alle Zeilen einer Datei durchgehen möchte.

    Unabhängig davon brauchst du es, wie ich oben schon schrieb im Grunde überhaupt nicht zeilenweise durchzugehen.

  • In Textdatei suchen

    • AspirinJunkie
    • 15. März 2017 um 09:15

    Da der Aufbau dem einer Ini-Datei entspricht, bieten sich die entsprechenden Funktionen hierfür an:

    AutoIt
    Global $s_IniPath = "Test.ini"
    
    
    Global $s_Benutzer = IniRead($s_IniPath, "Konfiguration", "Benutzer", '')
    
    
    MsgBox(0,"", "Benutzer: " & $s_Benutzer)
  • _DynArray-UDF - halbdynamische Arrays mit AutoIt

    • AspirinJunkie
    • 12. März 2017 um 21:05

    Hab die UDF neu heruntergeladen sowie die aktuelle AutoIt-Version.
    Habe dann das Beispiel unverändert ausgeführt.
    Die Fehlermeldung kann ich bei mir dabei nicht reproduzieren.
    Egal ob als x86 oder x64.

    Kann jemand anderes den Fehler eventuell reproduzieren?

    Mich wundert jedenfalls die Zeilennummer 596, denn die fragliche Zeile befindet sich in der UDF nämlich in der Zeile 615.

  • Dateien nach Alter/Bearbeitungszeit/Zugriffszeit auflisten.

    • AspirinJunkie
    • 10. Februar 2017 um 19:31

    Tja sieht erst einmal nach einer stinknormalen Datei aus.
    Keine Ahnung was das ist oder wo das her kommt.

  • Dateien nach Alter/Bearbeitungszeit/Zugriffszeit auflisten.

    • AspirinJunkie
    • 10. Februar 2017 um 18:16

    Könntest du eventuell mal das Ergebnis des folgenden Skriptes posten?:

    AutoIt
    $s_FilePath = "C:\Windows\System32\%TMP%"
    
    
    
    
    ConsoleWrite(FileGetSize($s_FilePath) & @CRLF & _
    		FileGetAttrib($s_FilePath) & @CRLF & _
    		FileGetTime($s_FilePath, 0, 1) & @CRLF & FileGetTime($s_FilePath, 1, 1) & @CRLF & FileGetTime($s_FilePath, 2, 1) & @CRLF & _
    		DllCall("kernel32.dll", "dword", "GetModuleHandleW", "wstr", $s_FilePath)[0])

    Bei mir ist die Datei nämlich nicht vorhanden.

  • Dateien nach Alter/Bearbeitungszeit/Zugriffszeit auflisten.

    • AspirinJunkie
    • 10. Februar 2017 um 17:17

    Das Problem ist nicht, dass die Variable nicht expandiert wird, sondern dass dort eine Datei aufgefunden wird welche anscheinend den Namen "%TMP%" trägt.
    Schau mal im Explorer ob es diese Datei dort wirklich gibt (auch mal bei versteckten Dateien schauen).
    Wenn es so wäre, wäre seitens des Skriptes alles in Ordnung.
    Zwar ist es möglich eine Datei so zu nennen aber wirklich Sinn macht es für mich nicht.
    Bei mir ist auch keine solche Datei zu finden.

  • Dateien nach Alter/Bearbeitungszeit/Zugriffszeit auflisten.

    • AspirinJunkie
    • 9. Februar 2017 um 22:00

    Witziger Effekt - kann ich bei mir bislang nicht reproduzieren.
    Sieht aus wie ein Link zu %TMP% innerhalb System32 aus - keine Ahnung was das soll.

    In deinem ersten Bild passt allerdings auch das abgebildete Skript nicht zur darunter stehenden Ausgabe.
    Die Ausgabe hätte entsprechend den darüber stehenden Skript mit "! $iDiff = " beginnen müssen.
    Die Konsole darunter enthält diesen Textteil jedoch nicht.
    Also irgendwie passt das Skript nicht ganz zur Ausgabe.

    Und die angesprochene "Reparatur" führt auch nicht wirklich zu einer Verbesserung des Ergebnisses.
    C:\Windows\System32\C:\Users\ghost\AppData\local\Temp ist ja kein gültiger Pfad.

    Kann es bei mir bislang nicht reproduzieren.
    Eventuell könnte ja noch jemand anderes mal schauen ob der Effekt reproduzierbar ist.

  • Dateien nach Alter/Bearbeitungszeit/Zugriffszeit auflisten.

    • AspirinJunkie
    • 9. Februar 2017 um 20:04
    Zitat von Bitnugger

    doch leider funktioniert dein Beispiel nicht.

    Nachdem ich "#include <Array.au3>" hinzugefügt hatte, lief es zwar, doch das Ergebnis-Array ist leer!

    Das vergessene Array.au3 hatte ich vergessen und später hinzugefügt.
    Bei dem leeren Array vermute ich, wie autoiter, dass keine Datei den Anforderungen entspricht.
    Einfach mal z.B. den Zeitraum auf z.B. 100 Tage verlängern.
    Hier auch mal mit der rekursiven Schwesterfunktion dazu:

    AutoIt
    #include <Array.au3>
    #include <Date.au3>
    
    
    ; Alle Dateien im Windows-Verzeichnis welche jünger als 14 Tage sind:
    $a_List = _listFilesFlexibleRec("C:\Windows\System32", cb_MyFunc, 1)
    _ArrayDisplay($a_List)
    
    
    
    
    ; Callback-Funktion welche True zurückgibt, wenn eine Datei den Anforderungen entspricht und False wenn nicht
    ; Konkrete Prüfung hier: Test ob Datei jünger als 100 Tage ist:
    Func cb_MyFunc(Const $s_Path)
    	Local Static $Now = _NowCalc()
    	Return _DateDiff("D", StringRegExpReplace(FileGetTime($s_Path, 0, 1), "(\d{4})(\d{2})(\d{2}).+", "$1/$2/$3"), $Now) < 100
    EndFunc   ;==>cb_MyFunc
    
    
    
    
    
    
    ; #FUNCTION# ====================================================================================================================
    ; Name...........: _listFilesFlexibleRec
    ; Description ...: Gibt ein Array mit Dateien bzw. Unterordnern im gesamten Verzeichnisbaum zurück
    ; Syntax.........: _listFilesFlexibleRec($sSD, [$sPat = '', [$iF = 0, [$flgSS = 2]])
    ; Parameters ....: $sSD   - Startverzeichnis (mehrere Verzeichnisse durch | trennen)
    ;                  $sPat  - Optional: Pattern zur Filterung mit regulären Ausdrücken oder Verweis auf Funktion für komplexeres Matching
    ;                  $iF    - Optional: Flag ob nur Dateien, Ordner oder beides gesucht werden sollen
    ;                      	|$iF=3(Default) Gibt beides zurück
    ;                  		|$iF=1 Gibt nur Dateien zurück
    ;                  		|$iF=2 Gibt nur Ordner zurück
    ;                  $flgSS - Art der Rückgabe (Siehe StringSplit()-Funktion)
    ;                  $bS    - interner Rekursionsparameter - nicht verändern!
    ; Return values .: @Error: 1 = Startverzeichnis existiert nicht.
    ;                  		|2 = ungültiger Wert für $iF
    ; Author ........: AspirinJunkie
    ; Modified.......: 05.07.2016
    ; Remarks .......:
    ; Related .......:
    ; Link ..........:
    ; Example .......: No
    ; Note ..........: basiert auf einem rekursiven Ansatz
    ; ===============================================================================================================================
    Func _listFilesFlexibleRec($sSD, Const $sPat = '', Const $iF = 3, Const $flgSS = 2, Const $bS = True)
    	; By AspirinJunkie
    	Local $FFFF, $FFNF, $aD
    	Local Static $sRet, $hDLL, $p_F
    	If $bS Then
    		$hDLL = DllOpen("kernel32.dll")
    		$p_F = DllCall($hDLL, "ptr", "GetProcAddress", "handle", DllCall($hDLL, "handle", "GetModuleHandleW", "wstr", "kernel32.dll")[0], "str", "GetFileAttributesW")[0] ; get the function address of GetModuleHandleW
    		If Not ($iF = 3 Or $iF = 1 Or $iF = 2) Then Return SetError(1, DllClose($hDLL), "")
    	EndIf
    	For $i In StringSplit($sSD, "|", 2)
    		If Not (StringRight($i, 1) == '\') Then $i &= "\"
    		If Not FileExists($i) Then ContinueLoop
    		$FFFF = FileFindFirstFile($i & '*')
    		If $FFFF <> -1 Then
    			If $sPat = "" Then  ; falls keine Filterung gewünscht auf schnelleres Matching ausweichen
    				Do
    					$FFNF = FileFindNextFile($FFFF)
    					If @error Then ExitLoop
    					If @extended Then
    						If BitAND($iF, 2) Then $sRet &= $i & $FFNF & "|"
    						If Not BitAND(DllCallAddress('dword', $p_F, 'wstr', $i & $FFNF)[0], 0x400) Then _listFilesFlexibleRec($i & $FFNF, $sPat, $iF, $flgSS, False)
    					ElseIf BitAND($iF, 1) Then
    						$sRet &= $i & $FFNF & '|'
    					EndIf
    				Until 0
    			Else
    				Do
    					$FFNF = FileFindNextFile($FFFF)
    					If @error Then ExitLoop
    					If @extended Then
    						If BitAND($iF, 2) Then
    							If IsFunc($sPat) Then
    								If $sPat($i & $FFNF) Then $sRet &= $i & $FFNF & "|"
    							ElseIf StringRegExp($FFNF, $sPat) Then
    								$sRet &= $i & $FFNF & "|"
    							EndIf
    						EndIf
    						If BitAND(DllCallAddress('dword', $p_F, 'wstr', $i & $FFNF)[0], 0x400) Then ContinueLoop
    						_listFilesFlexibleRec($i & $FFNF, $sPat, $iF, $flgSS, False)
    					ElseIf BitAND($iF, 1) Then
    						If IsFunc($sPat) Then
    							If $sPat($i & $FFNF) Then $sRet &= $i & $FFNF & '|'
    						ElseIf StringRegExp($FFNF, $sPat) Then
    							$sRet &= $i & $FFNF & '|'
    						EndIf
    					EndIf
    				Until 0
    			EndIf
    			FileClose($FFFF)
    		EndIf
    	Next
    	If $bS Then
    		DllClose($hDLL)
    		Local $aRet = StringSplit(StringTrimRight($sRet, 1), "|", $flgSS)
    		$sRet = ""
    		Return $aRet
    	EndIf
    EndFunc   ;==>_listFilesFlexibleRec
    Alles anzeigen
    Zitat von autoiter

    Auch schon wieder ein Funktionsaufruf in einer Variable. So etwas ist mir ewig nie aufgefallen

    Seit es das Feature gibt (kam erst relativ spät) nutze ich es exzessiv.
    Damit wird deutlich dynamischerer Code ermöglicht und daher gibt es eine Vielzahl von Einsatzzwecken hierfür.
    Schau z.B. mal in die DynArray-UDF - die ist voll von Anwendungsfällen für Funktionsvariablen.
    Auch für mathematische Kurvendiskussion lässt sich dies ziemlich sinnvoll einsetzen.

  • Easy Question about InetClose

    • AspirinJunkie
    • 9. Februar 2017 um 18:25

    Interessant - nö habe den Fehler nicht gehabt.
    Auch keine Ahnung wo der herkommt.
    Bei der von mir angegeben Datei oder hast du eine andere (vermeintlich größere?) eingetragen?

  • Dateien nach Alter/Bearbeitungszeit/Zugriffszeit auflisten.

    • AspirinJunkie
    • 9. Februar 2017 um 18:14

    Es ist natürlich ein Ansatz für jeden speziellen Suchfall eine spezielle Funktion zu schreiben.
    Eine Alternative hierzu wäre es wenn man die Dateisuche einmal komplett schreibt und die speziellen Suchkriterien derart flexibel gestaltet, dass der Nutzer den speziellen Teil selbst schreiben/austauschen kann.

    Hier mal als Beispiel wie ich das meine:

    AutoIt
    #include <Array.au3>
    #include <Date.au3>
    
    
    ; Alle Dateien im Windows-Verzeichnis welche jünger als 14 Tage sind:
    $a_List = _listFilesFlexible("C:\Windows\System32", cb_MyFunc, 1)
    _ArrayDisplay($a_List)
    
    
    
    
    ; Callback-Funktion welche True zurückgibt, wenn eine Datei den Anforderungen entspricht und False wenn nicht
    ; Konkrete Prüfung hier: Test ob Datei jünger als 14 Tage ist:
    Func cb_MyFunc(Const $s_Path)
    	Local Static $Now = _NowCalc()
    	Return _DateDiff("D", StringRegExpReplace(FileGetTime($s_Path, 0, 1), "(\d{4})(\d{2})(\d{2}).+", "$1/$2/$3"), $Now) < 14 _
    			 ? True : False
    EndFunc   ;==>cb_MyFunc
    
    
    
    
    
    
    
    
    ; #FUNCTION# ======================================================================================
    ; Name ..........: _listFilesFlexible()
    ; Description ...: Findet Dateien und/oder Ordner in einem Verzeichnisbaum
    ; Syntax ........: _listFilesFlexible($sSD, [Const $sPat = '', [Const $iF = 3, [Const $iSSFlag = 2]]])
    ; Parameters ....: $sSD           - Suchort (mehrere Suchorte durch | trennen)
    ;                 Const $sPat    - [optional] regulärer Ausdruck für zu findende Datei/Ordnernamen (default:'') oder Verweis auf Funktion für komplexeres Matching
    ;                  Const $iF      - [optional] 1=nur Dateien, 2=nur Ordner, 3=Dateien+Ordner (default:3)
    ;                  Const $iSSFlag - [optional] 0=Rückgabearray mit Anzahl Elemente in $Array0, 2=Rückgabearray ohne Anzahl Elemente
    ; Return values .: Success - Return Array with Matches
    ;                  Failure - Return "" and set @error
    ; Author ........: AspirinJunkie
    ; Remarks .......: Funktionsweise ist iterativ - nicht rekursiv
    ; Example .......: Yes
    ;                  #include <Array.au3>
    ;                  $aTmp = _listFilesFlexible(@WindowsDir & '|' & @ProgramFilesDir, "^Temp$", 2)
    ;                  _ArrayDisplay($aTmp)
    ; =================================================================================================
    Func _listFilesFlexible($sSD, Const $sPat = '', Const $iF = 3, Const $iSSFlag = 2)
    	;by AspirinJunkie
    	Local $sRet = "", $sSubD = ""
    	For $i In StringSplit($sSD, '|', 2)
    		If Not (StringRight($i, 1) == '\') Then $i &= "\"
    		If Not FileExists($i) Then Return SetError(2, 0, "")
    		$sSubD &= '|' & $i
    	Next
    	Local $FFFF, $FFNF, $sDir, $iC
    	Local $aD, $hDLL = DllOpen('kernel32.dll')
    	Local $p_F = DllCall($hDLL, "ptr", "GetProcAddress", "handle", DllCall($hDLL, "handle", "GetModuleHandleW", "wstr", "kernel32.dll")[0], "str", "GetFileAttributesW")[0] ; get the function address of GetModuleHandleW
    	If Not ($iF = 3 Or $iF = 1 Or $iF = 2) Then Return SetError(3, 0, "")
    
    
    	If $sPat = "" Then
    		Do
    			$iC = StringInStr($sSubD, '|', 2, -1)
    			If @error Or $iC = 0 Then ExitLoop
    			$iC = StringLen($sSubD) - $iC
    			$sDir = StringRight($sSubD, $iC)
    			$sSubD = StringTrimRight($sSubD, $iC + 1)
    			$FFFF = FileFindFirstFile($sDir & '*')
    			If $FFFF <> -1 Then
    				Do
    					$FFNF = FileFindNextFile($FFFF)
    					If @error Then ExitLoop
    					If @extended Then
    						If BitAND($iF, 2) Then $sRet &= $sDir & $FFNF & '|'
    						If Not BitAND(DllCallAddress('dword', $p_F, 'wstr', $sDir & $FFNF)[0], 0x400) Then $sSubD &= '|' & $sDir & $FFNF & "\"
    					ElseIf BitAND($iF, 1) Then
    						$sRet &= $sDir & $FFNF & '|'
    					EndIf
    				Until 0
    				FileClose($FFFF)
    			EndIf
    		Until 0
    	Else
    		Do
    			$iC = StringInStr($sSubD, '|', 2, -1)
    			If @error Or $iC = 0 Then ExitLoop
    			$iC = StringLen($sSubD) - $iC
    			$sDir = StringRight($sSubD, $iC)
    
    
    			$sSubD = StringTrimRight($sSubD, $iC + 1)
    			$FFFF = FileFindFirstFile($sDir & '*')
    			If $FFFF <> -1 Then
    				Do
    					$FFNF = FileFindNextFile($FFFF)
    					If @error Then ExitLoop
    					If @extended Then
    						If BitAND($iF, 2) Then
    							If IsFunc($sPat) Then
    								If $sPat($sDir & $FFNF) Then $sRet &= $sDir & $FFNF & '|'
    							ElseIf StringRegExp($FFNF, $sPat) Then
    								$sRet &= $sDir & $FFNF & '|'
    							EndIf
    						EndIf
    						If BitAND(DllCallAddress('dword', $p_F, 'wstr', $sDir & $FFNF)[0], 0x400) Then ContinueLoop
    						$sSubD &= '|' & $sDir & $FFNF & "\"
    					ElseIf BitAND($iF, 1) Then
    						If IsFunc($sPat) Then
    							If $sPat($sDir & $FFNF) Then $sRet &= $sDir & $FFNF & '|'
    						ElseIf StringRegExp($FFNF, $sPat) Then
    							$sRet &= $sDir & $FFNF & '|'
    						EndIf
    					EndIf
    				Until 0
    				FileClose($FFFF)
    			EndIf
    		Until 0
    	EndIf
    
    
    	DllClose($hDLL)
    	Return StringSplit(StringTrimRight($sRet, 1), '|', $iSSFlag)
    EndFunc   ;==>_listFilesFlexible
    Alles anzeigen

    Die Funktion ist so aufgebaut, dass eine benutzerdefinierte Funktion als Parameter übergeben werden kann welche dann jeweils alle gefundenen Dateien ganz nutzerspezifisch prüft.

  • Easy Question about InetClose

    • AspirinJunkie
    • 9. Februar 2017 um 17:56

    Nö - lässt sich leicht testen:

    AutoIt
    $s_URL = "https://autoit.de/onlinehilfe/index.htm"
    $s_Path = @DesktopDir & "\Temp.htm"
    
    
    For $i = 1 To 1000
    	$h_Inet = InetGet($s_URL, $s_Path, 0, 1)
    	Do
    		Sleep(10)
    	Until InetGetInfo($h_Inet, 2)
    	;InetClose($h_Inet)
    	FileDelete($s_Path)
    Next
    Alles anzeigen

    Einmal Skript ausführen mit und einmal ohne InetClose().
    Und während der Ausführung mal im Taskmanager den verwendeten Arbeitsspeicher des Skriptes beobachten.
    Mit InetClose ist die Auslastung relativ konstant, ohne InetClose steigt sie konstant an.
    Es werden also durchaus, wie in der Hilfe beschrieben, damit die Handles korrekt geschlossen.
    Nichts desto trotz kann man (wie es ebenfalls korrekt in der Hilfe steht) auch laufende Downloads hiermit abbrechen.

    Einzig dass immer False ausgegeben wird auch wenn das Skriptverhalten auf gegenteiliges hinweist könnte durchaus ein Bug sein.

  • Array - Anzahl der Elemente

    • AspirinJunkie
    • 23. Januar 2017 um 15:43

    Ubound()

  • Große Dateien einlesen? Alternative zu FileReadLine & FileReadToArray?

    • AspirinJunkie
    • 16. Januar 2017 um 12:43
    Zitat von MorsGER

    Das steht ja so in der Help-File von "FileReadLine". Drum schrieb ich, dass ich die Datei über den FileHandle einlese - war aber wohl etwas unverständlich formuliert.

    Das mit dem FileHandle ist ja nur ein Trick.
    Der andere (noch wichtigere) ist ohne Zeilennummerparameter zu arbeiten.
    Das ist die eigentliche Frage auf die Oscar hinaus wollte.

    Zeig am besten mal ein kleines Minimalskript wie du die Datei bei dir abarbeitest und dann können wir gemeinsam schauen ob und wo es da noch Flaschenhälse gibt bzw. was man wie verbessern könnte.

  • Autoit Random Funktion?

    • AspirinJunkie
    • 11. Januar 2017 um 18:47

    Lies dir mal die AutoIt-Hilfe zur Random-Funktion durch, insbesondere zum dritten Parameter.

    Vorschlag den du dir daraufhin dann anschauen kannst:

    AutoIt
    If Random(1, 10, 1) < 8 Then
    	_FFStart("wikipedia.de")
    Else
    	_FFStart("Google.de")
    EndIf
  • Shadows opensource Obfuscator

    • AspirinJunkie
    • 7. Januar 2017 um 09:14

    Der letzte Beitrag in diesem Thread ist Sieben Jahre alt.
    Die letzte Aktivität des Threaderstellers laut seinem Profil Vier Jahre her.

    Entweder das angesprochene Problem hat niemanden Sieben Jahre lang gestört oder (was ich für wahrscheinlicher halte) das Ding ist quasi tot und aufgrund der angesprochenen Zeiträume wäre eine Behebung seitens des Autors eher unwahrscheinlich.

  • C:\Windows\System32\Tasks auslesen

    • AspirinJunkie
    • 3. Januar 2017 um 12:11

    Ja mag sein dass es mal einer in die UDF eingefügt hat.
    Es ist zwar nicht exakt die selbe API-Funktion (einmal *enable* einmal *disable*) aber der Effekt sollte der gleiche sein.
    Die WinAPI-Dok schreibt dazu auch dass die Wow64EnableWow64FsRedirection nicht mehr verwendet werden sollte sondern stattdessen die Wow64DisableWow64FsRedirection weil es wohl Probleme mit verschachtelten Aufrufen geben soll (wobei ich mir da jetzt spontan keinen Fall vorstellen kann).

    Also laut WinApi-Dok sollte man wohl eher den manuellen DLLCall auf Wow64DisableWow64FsRedirection statt der _WinAPI_Wow64EnableWow64FsRedirection() verwenden.

  • C:\Windows\System32\Tasks auslesen

    • AspirinJunkie
    • 3. Januar 2017 um 12:04

    Nur zur Vollständigkeit:
    Folgendes an den Anfang des Skriptes und es funktioniert unabhängig davon ob es als x86 oder x64 kompiliert wurde:

    AutoIt
    ; Umleitung für x86-Programm abschalten:
    DllCall("kernel32.dll", "int", "Wow64DisableWow64FsRedirection", "int", 1)

    Admin-Rechte sollten für den Ordner auch nicht nötig sein.

  • Zeile für Zeile (geht das irgendwie schneller?)

    • AspirinJunkie
    • 28. November 2016 um 17:25

    Du musst auch nicht die ganze Datei in den Speicher hauen und dann dort zerlegen.
    Du kannst auch problemlos weiter die Datei Zeile für Zeile (speichersparend) abarbeiten.
    Nur halt nicht ganz so wie du es gemacht hast, denn dann wird es wirklich langsam.
    Wo lag der Fehler?
    Beim Benutzen des Zeilennummerparameter von FileReadLine.

    Was passiert wenn man eine Zeilennummer dort angibt?:

    • Die Datei wird geöffnet.
    • Es wird an den Anfang der Datei gesprungen.
    • Es wird die Datei von Anfang an durchgearbeitet bis die Anzahl an Zeilenumbrüchen erreicht wurde.
    • Diese Zeile wird dann zurückgegeben.
    • Die Datei wird geschlossen.

    Und warum ist das langsam? - Nun das wird bei jedem einzelnen Aufruf erneut gemacht.
    Aber wenn wir die erste Zeile schon haben wollen wir für die Zweite Zeile nur die nächste haben. Er soll nicht wieder an den Anfang springen.
    Und das erreicht man wenn man die Datei öffnet und die Datei mit FileReadLine durchgeht ohne den Zeilenparameter zu verwenden.

    Kurz - so sollte es bedeutend schneller vonstatten gehen:

    AutoIt
    Global $s_SourceFile = "C:\Users\testdatei.xyz"
    
    
    ; Datei zum Lesen öffnen
    Global $h_FileRead = FileOpen($s_SourceFile, 0)
    ; Datei zum Schreiben öffnen:
    Global $h_FileWrite = FileOpen("C:\Documents\Projekte\fertig_testdatei.xyz", 1)
    
    
    Global $s_Line
    
    
    ; Datei zeilenweise durchgehen
    Do
    	; nächste Zeile lesen
    	$s_Line = FileReadLine($h_FileRead)
    	If @error Then ExitLoop ; z.B. Ende der Datei erreicht
    
    
    	$X = StringTrimRight($s_Line, 19)
    	$Y = StringTrimLeft(StringTrimRight($s_Line, 8), 12)
    	$Z = StringTrimLeft($s_Line, 25)
    
    
    	FileWriteLine($h_FileWrite, $X & ";" & $Y & ";" & $Z)
    Until 0
    
    
    FileClose($h_FileRead)
    FileClose($h_FileWrite)
    Alles anzeigen

Spenden

Jeder Euro hilft uns, Euch zu helfen.

Download

AutoIt Tutorial
AutoIt Buch
Onlinehilfe
AutoIt Entwickler
  1. Datenschutzerklärung
  2. Impressum
  3. Shoutbox-Archiv
Community-Software: WoltLab Suite™