1. Dashboard
  2. Mitglieder
    1. Letzte Aktivitäten
    2. Benutzer online
    3. Team
    4. Mitgliedersuche
  3. Forenregeln
  4. Forum
    1. Unerledigte Themen
  • Anmelden
  • Registrieren
  • Suche
Alles
  • Alles
  • Artikel
  • Seiten
  • Forum
  • Erweiterte Suche
  1. AutoIt.de - Das deutschsprachige Forum.
  2. Mitglieder
  3. AspirinJunkie

Beiträge von AspirinJunkie

  • vgl. StringRegExp() StringReplace() StringInStr()

    • AspirinJunkie
    • 31. Mai 2015 um 20:28

    Bernds Ergebnisse decken sich weitgehend mit meinen.
    Auffällig ist lediglich das Verhalten von StringReplace bei Flag 2.
    Das hängt aber wahrscheinlich mit dem oben angesprochenen gefixtem Bug zusammen.

    Zitat von Andy

    in 2010, als dieses Script geschrieben wurde, war imho die 3.3.6 aktuell und nicht die 3.3.8.1, die gab es erst 2012!!

    Die Version 3.3.6.0 habe ich mal in meinen zweiten Vergleich mit hinzu genommen.
    Ergebnisse hier: >>Plot2.pdf<<

  • vgl. StringRegExp() StringReplace() StringInStr()

    • AspirinJunkie
    • 31. Mai 2015 um 17:28

    eine einzelmessung bringt uns nicht viel. Der Vergleich von verschiedenen autoit-versionen ist hier die Fragestellung.

  • vgl. StringRegExp() StringReplace() StringInStr()

    • AspirinJunkie
    • 31. Mai 2015 um 15:35

    Ich habe dein Skript mal abgewandelt und auf 3.3.12.0 und 3.3.8.1 laufen lassen:

    Spoiler anzeigen
    AutoIt
    #AutoIt3Wrapper_UseX64=n
    #include <array.au3>
    
    
    $post 		= "Die Vögel singen im Wald abcdefghijklmnopqrstuvwxyz"
    $Pattern 	= $post
    $pre 		= ""
    $string 	= ""
    
    
    $hFile = FileOpen("s.txt", 2)
    
    
    ConsoleWrite("   Stringlänge     StringInstr   StringRegExp    Stringreplace" & @CRLF)
    FileWriteLine($hFile, "   Stringlänge     StringInstr   StringRegExp    Stringreplace")
    For $i = 1 To 18
    
    
    	For $s = 1 To 100
    		$string &= Chr(Random(35, 127, 1))
    	Next
    	$string = StringReplace($string, $post, "") ; $post löschen
    	$string &= $string & $post				;string aufpumpen und den $post und ans ende bringen
    
    
    	$t = TimerInit()
    	$a2 = StringInStr($string, $Pattern)
    	$m2 = TimerDiff($t)
    
    
    	$t = TimerInit()
    	$a = StringRegExp($string, $Pattern)
    	$m4 = TimerDiff($t)
    
    
    	$t = TimerInit()
    	StringReplace($string, $Pattern, "", 0, 0)
    	if @extended then $x=true
    	$m5 = TimerDiff($t)
    
    
    	FileWriteLine($hFile, StringFormat("   %10.10s ", StringLen($string)) & _
    			StringFormat("      %5.10s       ", $m2) & _
    			StringFormat("      %5.10s       ", $m4) & _
    			StringFormat("      %5.10s       ", $m5))
    	ConsoleWrite(StringFormat("   %10.10s ", StringLen($string)) & _
    			StringFormat("      %5.10s       ", $m2) & _
    			StringFormat("      %5.10s       ", $m4) & _
    			StringFormat("      %5.10s       ", $m5) & @CRLF)
    Next
    FileClose($hFile)
    Alles anzeigen

    Beim StringReplace habe ich den Casesense-Parameter wieder auf 0 gestellt, da in der 3.3.8.1 noch ein Bug drin war (Ticket 2311).
    Ansonsten ist der Vergleich der Selbe.

    Im Ergebnis (>>Plot2.pdf<<) kann ich hier von 3.3.8.1 zu 3.3.12.0 bei mir keine Verschlechterung der StringInStr um den Faktor 2,5x und beim StringReplace um den Faktor 9x feststellen.
    Die StringInStr ist bei mir über die Versionen konstant und die die StringReplace gerade mal um den Faktor 1,1x langsamer geworden.

    Ich denke daher jemand Drittes müsste sich das Verhalten mal anschauen, da wir unsere Ergebnisse jeweils gegenüber nicht reproduzieren können.

    Hier daher mein Testskript für meinen ersten Test weiter oben:

    Spoiler anzeigen
    C
    #AutoIt3Wrapper_UseX64=n
    #include <array.au3>
    
    
    Global $s_Source = BinaryToString(InetRead("https://autoit.de/"), 4)
    
    
    Global $dX = 200 * StringLen($s_Source) ; relation between count of chars an loops
    Global $N, $NN, $s_String
    Global $x, $s_Search = "AutoIt"
    Global $a_Result[30][7] = [["N", "StringReplace-CS", "StringReplace-CI", "StringRegExp-CS", "StringRegExp-CI", "StringRegExpReplace-CS", "StringRegExpReplace-CI"]]
    
    
    
    
    For $y = 1 To UBound($a_Result) - 2
    	$s_String &= $s_Source
    	$NN = StringLen($s_String)
    	$N = Int($dX / $NN)
    
    
    	$a_Result[$y][0] = $NN
    
    
    	$iT = TimerInit()
    	For $i = 1 To $N
    		StringReplace($s_String, $s_Search, $s_Search, 0, 1)
    		$x = @extended
    	Next
    	$iT = TimerDiff($iT)
    	$a_Result[$y][1] = $iT / $N
    
    
    	$iT = TimerInit()
    	For $i = 1 To $N
    		StringReplace($s_String, $s_Search, $s_Search)
    		$x = @extended
    	Next
    	$iT = TimerDiff($iT)
    	$a_Result[$y][2] = $iT / $N
    
    
    	$iT = TimerInit()
    	For $i = 1 To $N
    		$x = UBound(StringRegExp($s_String, $s_Search, 3))
    	Next
    	$iT = TimerDiff($iT)
    	$a_Result[$y][3] = $iT / $N
    
    
    	$iT = TimerInit()
    	For $i = 1 To $N
    		$x = UBound(StringRegExp($s_String, "(?i)" & $s_Search, 3))
    	Next
    	$iT = TimerDiff($iT)
    	$a_Result[$y][4] = $iT / $N
    
    
    	$iT = TimerInit()
    	For $i = 1 To $N
    		StringRegExpReplace($s_String, $s_Search, "")
    		$x = @extended
    	Next
    	$iT = TimerDiff($iT)
    	$a_Result[$y][5] = $iT / $N
    
    
    	$iT = TimerInit()
    	For $i = 1 To $N
    		StringRegExpReplace($s_String, "(?i)" & $s_Search, "")
    		$x = @extended
    	Next
    	$iT = TimerDiff($iT)
    	$a_Result[$y][6] = $iT / $N
    Next
    
    
    _ArrayDisplay($a_Result)
    Alles anzeigen
  • vgl. StringRegExp() StringReplace() StringInStr()

    • AspirinJunkie
    • 31. Mai 2015 um 13:52

    Ich habs mal verglichen (Plot.pdf) für das Beispiel des Zählens eines Substrings.
    Im Vergleich zu 3.3.8.1 sind die RegEx-Funktionen tatsächlich auf einmal schneller geworden als StringReplace.
    Wenn man sich die Grafiken aber mal anschaut liegt das aber nicht daran, das StringReplace wesentlich langsamer geworden ist, sondern dararan dass die RegEx-Funktionen massiv an Performance hinzugewonnen haben.
    Der StringReplace-Graph bleibt nahezu konstant - nur die Regex-Graphen wandern nun nach unten.
    Tatsächlich ist StringReplace etwas langsamer geworden (ca. Faktor x1,2) - aber eine künstliche Verschlechterung wird kaum der Grund hierfür sein.

    Heißt zusammengefasst: Niemand hat hier die Standard-String-Funktionen künstlich verschlechtert weil er einer Verschwörung der progressiven Programmierertechniken gegenüber den "guten alten" Techniken angehört.
    Die Regex-Funktionen sind halt massiv schneller geworden (etwa um den Faktor x3) - nicht mehr und nicht weniger.
    Das schadet keinem einzigen AutoIt-User. Im Gegenteil - es profitieren alle davon.

    Der Fairness halber sollte man bei Zeitvergleichen bei RegEx-Funktionen dazu sagen, dass AutoIt einmal verwendete Pattern zwischenspeichert, so dass sie bei nochmaliger Verwendung nicht nochmal kompiliert werden müssen. Da der Zeitvergleich hier aber auf Mehrfachmessungen beruht, erscheinen die RegEx-Funktionen daher schneller als sie eigentlich sind.
    Ob dies bei 3.3.8.1 auch schon so war weiß ich nicht. Es könnte daher eine Ursache für den massiven Performancesprung sein.
    Ein anderer könnte der native 16Bit-Modus der PCRE-Engine sein, welcher in Version 3.3.10.0 aktiviert wurde.

    Was bleibt ist die Frage warum die "nativen" Stringfunktionen bisher nicht stark optimiert wurden.
    Auch wenn die PCRE-Engine wahnsinnig viel aus einem RegEx-Pattern rausholen kann, sollte eine vernünftig optimierte StringReplace diese dennoch schlagen können.
    Das ist bisher anscheinend versäumt wurden. Aber das war dann schon immer so und ist nicht erst seit den letzten Versionen künstlich verschlechtert worden.

  • Rückgabewert Return

    • AspirinJunkie
    • 29. Mai 2015 um 13:10
    Zitat von water

    MsgBox gibt Dir 1 zurück, da interne Funktionen von AutoIt immer den Wert 1 bei Erfolg zurückgeben.

    Wo hast du das denn her?
    Msgbox gibt nur 1 zurück wenn auf "OK" geklickt wurde.
    Wenn z.B. auf abbrechen gedrückt wird dann 2 usw. (siehe Hilfe).

  • Variablenname in for-Schleife hochzählen

    • AspirinJunkie
    • 29. Mai 2015 um 10:14

    Das geht zwar mit Eval() aber das solltest du trotzdem nicht machen.
    Was du stattdessen tun solltest ist aus $flabelnote ein 1D-Array und aus $STATION ein 2D-Array zu machen.
    Das was du dann hochzählst ist deren Index.

  • Struktur wird aus Pointer fehlerhaft befüllt

    • AspirinJunkie
    • 26. Mai 2015 um 14:38

    Yo das isses.

    Zur Lösung würde ich zu HeapAlloc raten.
    Musst halt nur sicherstellen, dass du den allokierten Speicher immer wieder selbst mit HeapFree freigeben musst um keine Speicherleichen zu produzieren.

    Mal als Beispiel:

    Spoiler anzeigen
    AutoIt
    Global Const $p_PROCHEAP = DllCall("kernel32.dll", "HANDLE", "GetProcessHeap")[0] ; Pointer zum Prozess-Heap
    
    
    $tRet = _SomeFunc()
    $tRetTime = DllStructCreate($tRet.tagTime, $tRet.Time)
    For $i = 1 To 6
    	ConsoleWrite('Return ' & $i & ': ' & DllStructGetData($tRetTime, $i) & @CRLF)
    Next
    
    
    ; dynamisch allozierten speicher wieder freigeben (wichtig!):
    DllCall("kernel32.dll", "BOOL", "HeapFree", "handle", $p_PROCHEAP, "DWORD", 1, "ptr", $tRet.Time)
    
    
    Func _SomeFunc()
    	Local $tagTime = 'char Year[4];char Month[2];char Day[2];char Hour[2];char Min[2];char Sec[2]'
    	Local $pMem = DllCall("kernel32.dll", "ptr", "HeapAlloc", "HANDLE", $p_PROCHEAP, "DWORD", 0x1, "ulong_ptr", DllStructGetSize(DllStructCreate($tagTime)))[0]  ; Speicher dynamisch im Heap allokieren
    	Local $tTime = DllStructCreate($tagTime, $pMem)
    	DllStructSetData($tTime, 'Year',  @YEAR)
    	DllStructSetData($tTime, 'Month', @MON)
    	DllStructSetData($tTime, 'Day',   @MDAY)
    	DllStructSetData($tTime, 'Hour',  @HOUR)
    	DllStructSetData($tTime, 'Min',   @MIN)
    	DllStructSetData($tTime, 'Sec',   @SEC)
    	Local $t = DllStructCreate('struct;ptr Time;char tagTime[75];endstruct')
    	DllStructSetData($t, 'Time', $pMem)
    	DllStructSetData($t, 'tagTime', $tagTime)
    
    
    	; prüfen ob Struktur gefüllt und auslesbar
    	Local $tCheck = DllStructCreate($t.tagTime, $t.Time)
    	For $i = 1 To 6
    		ConsoleWrite('Check Feld ' & $i & ': ' & DllStructGetData($tCheck, $i) & @CRLF)
    	Next
    
    
    	Return $t
    EndFunc
    Alles anzeigen
  • Struktur wird aus Pointer fehlerhaft befüllt

    • AspirinJunkie
    • 26. Mai 2015 um 13:51
    Zitat von BugFix

    Jedoch liefert dieselbe Überprüfung mit der zurückgegebenen Struktur fehlerhafte Werte.


    Was meinst du exakt mit "fehlerhafte Werte"?
    Die Ausgabe wirkt für mich nicht fehlerhaft:

    Ausgabe mit v.3.3.12.0 sowohl x64 als auch x86
    Code
    Check Feld 1: 2015
    Check Feld 2: 05
    Check Feld 3: 26
    Check Feld 4: 13
    Check Feld 5: 46
    Check Feld 6: 20
    Return 1: 2015
    Return 2: 05
    Return 3: 26
    Return 4: 13
    Return 5: 46
    Return 6: 20
    Alles anzeigen
  • Programmieranfänger needs help ;)

    • AspirinJunkie
    • 16. Mai 2015 um 10:20

    Lege in diesen Fällen konkret dar was du erreichen willst.
    Stell die Frage nicht als Imagesearch-Frage sondern wie du dein wirkliches Problem lösen kannst.

    In 95% aller Fälle wird die Lösung dann darin münden, dass du die Imagesearch gar nicht benötigst.

    Ein großes Problem in Foren wie dieser ist nämlich das sogenannte X-Y Problem:
    Das bedeutet ein Nutzer hat ein Problem X. Er glaubt die Lösung hierzu wäre der Weg über Y.
    Dort stößt er jedoch auf Probleme und postet seine Fragen zu Y hier im Forum ohne irgendetwas über sein eigentliches Problem X mitzuteilen.
    Nach langem hin und her kommt dann raus, dass Y gar nicht der sinnvolle Lösungsweg für X ist sondern irgendein anderer.

    Kurz: Wenn du Fragen zu ImageSearch stellst hast du die Frage eigentlich schon von vornherein falsch gestellt.
    Leg immer in erster Linie dein eigentliches Grundproblem dar und dann erst wie du es zu lösen versuchtest.

  • Website parsen - Klappe die tausendste..

    • AspirinJunkie
    • 15. Mai 2015 um 20:17
    Zitat von autoiter

    Leider für mich schwer nachvollziehbar, weil ich immer noch nicht mit RegExp gearbeitet habe,

    Wie kommst du auf RegExp?
    Das sind Css-Selektoren.

    Hier mal zwei Arrays: Das eine für die Titel, das andere für die Bild-Urls:

    Spoiler anzeigen
    AutoIt
    #include <array.au3>
    
    
    Local $Film = "Alien"
    Local $sHtml = BinaryToString(InetRead("http://www.filmstarts.de/suche/1/?q=" & _URIEncode($Film), 1), 4)
    
    
    Local $a_Elements = _CssSelectFromString($sHtml, "div.vmargin10t td[style~='top'] a")
    _ArrayDisplay($a_Elements)
    
    
    Local $a_Elements = _CssSelectFromString($sHtml, "div.vmargin10t td[style~='middle'] a")
    _ArrayDisplay($a_Elements)
    
    
    
    
    ; #FUNCTION# ======================================================================================
    ; Name ..........: _CssSelectFromString()
    ; Description ...: extract elements out of a html string with css-style selectors
    ; Syntax ........: _CssSelectFromString($s_String, $s_Selector, {Const $b_First = True})
    ; Parameters ....: $s_String      - the html string
    ;                  $s_Selector    - the css-style selector
    ;                  {$b_First}     - dont't touch! - for internal use only!
    ; Return values .: Success: Array[...][0] = element attributes string
    ;                           Array[...][1] = element content string
    ;                  Failure: ""
    ;                     @error = 1: no balanced elements found
    ; Remarks .......: The following CSS-Selector-Features are implemented:
    ;                  .class               - class of a element
    ;                  #ID                  - ID of a element
    ;                  [attribute]          - attribute exist
    ;                  [attribute="value"]  - elements with attribute=value
    ;                  [attribute^="value"] - elements where attribute starting with value
    ;                  [attribute~="value"] - elements where attribute containing value
    ;                  [attribute$="value"] - elements where attribute ending with value
    ; Known bugs ....: - no empty element type is allowed - you have to set a type
    ;                  - If Balancing is not correct in the string - the result is also not correct
    ;                  - If selector is too general - some result may get doubled - to solve this: be as exactly as possible
    ; Author ........: AspirinJunkie
    ; Version .......: 0.8
    ; =================================================================================================
    Func _CssSelectFromString($s_String, $s_Selector, Const $b_First = True)
    	Local $s_Type = ""
    	Local $a_RegEx, $b_Match, $ID, $i, $j, $a_Ret
    	Local Static $o_Result
    
    
    	If $b_First Then
    		$s_String = StringRegExpReplace($s_String, "(?s)(?x)(?:<!--.+?)(?R)?(?:-->)", "") ; Kommentare killen
    		$s_String = StringRegExpReplace($s_String, "(?s)(?x)(?:<script.+?)(?R)?(?:</script)", "") ; Script-Elemente killen (Inhalt könnte Probleme beim Parsen bringen)
    		$s_String = StringRegExpReplace($s_String, "(?s)^.+<body\b(.+?)</body>.+$", "$1") ; Nur Inhalt des Bodys verwenden
    		$o_Result = ObjCreate('Scripting.Dictionary')
    	EndIf
    
    
    	$s_Selector = StringStripWS($s_Selector, 7)
    	Local $s_CurrentSelector = StringRegExp($s_Selector, "^(\S+)", 3)[0]
    	Local $s_SelectorRest = StringStripWS(StringRegExpReplace($s_Selector, "^(\S+)", ""), 7)
    
    
    	; Get the element type:
    	$a_RegEx = StringRegExp($s_CurrentSelector, "^(\w*)", 3)
    	If @error Then Return SetError(1, @error, "")
    	$s_Type = $a_RegEx[0]
    
    
    	; Alle Typen durchgehen und auf Übereinstimmung mit weiteren KLassifikatoren prüfen
    	Local $a_Types = _HtmlElements($s_String, $s_Type)
    
    
    	Local $a_AttribOpt = StringRegExp($s_CurrentSelector, "\[(\w+)\s*([~\*|\^\$]?=)\s*['""](.+?)['""]\s*\]", 4)
    	If @error Then Local $a_AttribOpt[0]
    	Local $a_ClassesOpt = StringRegExp($s_CurrentSelector, "\.(\w+)", 3)
    	If @error Then Local $a_ClassesOpt[0]
    	Local $a_IDOpt = StringRegExp($s_CurrentSelector, "#(\w+)", 3)
    	If @error Then Local $a_IDOpt[0]
    
    
    	For $j = 0 To UBound($a_Types) - 1
    		$b_Match = True
    		; Check for ID:
    		For $ID In $a_IDOpt
    			If Not StringRegExp($a_Types[$j][0], "(?x)\bid=['""]\b" & $ID & "\b['""]") Then ContinueLoop 2
    		Next
    
    
    		; Check for class:
    		For $Class In $a_ClassesOpt
    			If Not StringRegExp($a_Types[$j][0], "(?x)\bclass=['""][^'"">]*?\b" & $Class & "\b[^'"">]*?['""](?x)") Then ContinueLoop 2
    		Next
    
    
    		; Check for attributes:
    		; check for exist:
    		$a_RegEx = StringRegExp($s_CurrentSelector, "\[(\w+)\s*\]", 3)
    		If Not @error Then
    			For $Attr In $a_RegEx
    				If Not StringRegExp($a_Types[$j][0], "(?x)\b" & $Attr & "\b[=\s$]") Then ContinueLoop 2
    			Next
    		EndIf
    		For $AttrVal In $a_AttribOpt
    			Switch $AttrVal[2]
    				Case "=" ; full match
    					If Not StringRegExp($a_Types[$j][0], "(?x)" & $AttrVal[1] & "=['""]" & $AttrVal[3] & "['""]") Then ContinueLoop 2
    				Case "~=", "*=" ; partial match
    					If Not StringRegExp($a_Types[$j][0], "(?x)" & $AttrVal[1] & "=['""][^'""]*" & $AttrVal[3] & "[^'""]*['""]") Then ContinueLoop 2
    				Case "|=", "^=" ; start match
    					If Not StringRegExp($a_Types[$j][0], "(?x)" & $AttrVal[1] & "=['""]" & $AttrVal[3] & "[^'""]*['""]") Then ContinueLoop 2
    				Case "$=" ; end match
    					If Not StringRegExp($a_Types[$j][0], "(?x)" & $AttrVal[1] & "=['""][^'""]*" & $AttrVal[3] & "['""]") Then ContinueLoop 2
    			EndSwitch
    		Next
    
    
    		; save result element
    		If $s_SelectorRest = "" Then
    			Local $a_T[2] = [$a_Types[$j][0], $a_Types[$j][1]]
    			$o_Result($o_Result.Count) = $a_T
    		Else
    			_CssSelectFromString($a_Types[$j][1], $s_SelectorRest, False)
    		EndIf
    
    
    		; check for ":first" selector
    		If StringInStr($s_CurrentSelector, ":first", 2) Then ExitLoop
    ;~ 		If StringInStr($s_CurrentSelector, ":nth-of-type(" & $d_RetCounter & ")", 2) Then
    	Next
    
    
    	If $b_First Then
    		Local $n = $o_Result.Count
    		Local $a_Return[$n][2]
    		Local $v = 0
    		For $i In $o_Result.Keys()
    			$a_Return[$v][0] = StringStripWS($o_Result($i)[0], 3)
    			$a_Return[$v][1] = StringStripWS($o_Result($i)[1], 3)
    			$v += 1
    		Next
    		Return $a_Return
    	EndIf
    EndFunc   ;==>_CssSelectFromString
    
    
    
    
    
    
    
    
    ; #FUNCTION# ======================================================================================
    ; Name ..........: _HtmlElements()
    ; Description ...: extract all elements of type $s_Type from a html string
    ; Syntax ........: _HtmlElements(ByRef $s_Html, Const $s_Type)
    ; Parameters ....: $s_Html        - the html string
    ;                  $s_Type        - the html element type which should to extract
    ; Return values .: Success: Array[...][0] = element attributes string
    ;                           Array[...][1] = element content string
    ;                  Failure: ""
    ;                     @error = 1: no balanced elements found
    ; Known bugs ....: If Balancing is not correct in the string - the result is also not correct
    ; Author ........: AspirinJunkie
    ; =================================================================================================
    Func _HtmlElements(ByRef $s_Html, Const $s_Type)
    	Local $d_Start, $d_End, $d_T, $d_Pos = 1, $x = 0, $a_Element
    	Local $s_Begin = "<" & $s_Type, $s_Ende = "</" & $s_Type
    
    
    	StringReplace($s_Html, $s_Begin, $s_Begin, 0, 2)
    	Local $n = @extended
    	StringReplace($s_Html, $s_Ende, $s_Ende, 0, 2)
    	Local $u = @extended
    
    
    	If $n = 0 Or $u = 0 Then Return SetError(1, 0, "")
    	Local $a_Starts[$n], $a_Ends[$u]
    
    
    	; Alle Tag-Anfänge ermitteln:
    	Do
    		$d_T = StringInStr($s_Html, $s_Begin, 2, 1, $d_Pos)
    		If $d_T = 0 Then ExitLoop
    
    
    		$a_Starts[$x] = $d_T
    		$d_Pos = $d_T + StringLen($s_Begin)
    		$x += 1
    	Until 0
    
    
    	; Alle Tag-Enden ermitteln:
    	$x = 0
    	$d_Pos = 1
    	Do
    		$d_T = StringInStr($s_Html, $s_Ende, 2, 1, $d_Pos)
    		If $d_T = 0 Then ExitLoop
    
    
    		$a_Ends[$x] = $d_T
    		$d_Pos = $d_T + StringLen($s_Ende)
    		$x += 1
    	Until 0
    
    
    	; Funde matchen
    	Local $dMax = UBound($a_Ends) > UBound($a_Starts) ? UBound($a_Starts) - 1 : UBound($a_Ends) - 1
    	Local $d_End
    	Local $a_Return[$dMax + 1][3]
    	For $i = 0 To $dMax
    		$d_End = $a_Ends[$i]
    		For $j = $dMax To 0 Step -1
    			$d_Start = $a_Starts[$j]
    			If $d_Start = 1000000000 Then ContinueLoop
    			If $d_Start < $d_End Then
    				$a_Element = StringRegExp(StringMid($s_Html, $d_Start, $d_End - $d_Start + StringLen($s_Ende)), "(?s)^<" & $s_Type & "\s?(.*?)>(.*)</" & $s_Type, 3)
    				If UBound($a_Element) < 2 Then ContinueLoop
    				$a_Return[$i][0] = $a_Element[0]
    				$a_Return[$i][1] = $a_Element[1]
    				$a_Return[$i][2] = $d_Start
    
    
    				$a_Starts[$j] = 1000000000
    				ContinueLoop 2
    			EndIf
    		Next
    	Next
    
    
    	Return $a_Return
    EndFunc   ;==>_HtmlElements
    
    
    Func _URIEncode($sData)
        ; Prog@ndy
        Local $aData = StringSplit(BinaryToString(StringToBinary($sData,4),1),"")
        Local $nChar
        $sData=""
        For $i = 1 To $aData[0]
            ; ConsoleWrite($aData[$i] & @CRLF)
            $nChar = Asc($aData[$i])
            Switch $nChar
                Case 45, 46, 48 To 57, 65 To 90, 95, 97 To 122, 126
                    $sData &= $aData[$i]
                Case 32
                    $sData &= "+"
                Case Else
                    $sData &= "%" & Hex($nChar,2)
            EndSwitch
        Next
        Return $sData
    EndFunc
    Alles anzeigen

    Die Funktion ist halt noch ziemlich rudimentär. Würde ich es mal auf volle CSS-Selector-Funktionalität ausbauen könnte man auch viel flexibler arbeiten.
    Aber für viele Fälle kann man schon sehr schnell wichtige Informationen filtern.

  • Website parsen - Klappe die tausendste..

    • AspirinJunkie
    • 15. Mai 2015 um 20:04

    Hatte mir mal für sowas einen kleinen rudimentären HTML-Parser auf Basis von CSS-Selektoren geschrieben.
    Um zum Beispiel an die Filmtitel zu gelangen würde man das z.B. so machen:

    Spoiler anzeigen
    AutoIt
    #include <array.au3>
    
    
    Local $Film = "Alien"
    Local $sHtml = BinaryToString(InetRead("http://www.filmstarts.de/suche/1/?q=" & _URIEncode($Film), 1), 4)
    
    
    Local $a_Elements = _CssSelectFromString($sHtml, "div.vmargin10t td[style~='top'] a")
    _ArrayDisplay($a_Elements)
    
    
    
    
    ; #FUNCTION# ======================================================================================
    ; Name ..........: _CssSelectFromString()
    ; Description ...: extract elements out of a html string with css-style selectors
    ; Syntax ........: _CssSelectFromString($s_String, $s_Selector, {Const $b_First = True})
    ; Parameters ....: $s_String      - the html string
    ;                  $s_Selector    - the css-style selector
    ;                  {$b_First}     - dont't touch! - for internal use only!
    ; Return values .: Success: Array[...][0] = element attributes string
    ;                           Array[...][1] = element content string
    ;                  Failure: ""
    ;                     @error = 1: no balanced elements found
    ; Remarks .......: The following CSS-Selector-Features are implemented:
    ;                  .class               - class of a element
    ;                  #ID                  - ID of a element
    ;                  [attribute]          - attribute exist
    ;                  [attribute="value"]  - elements with attribute=value
    ;                  [attribute^="value"] - elements where attribute starting with value
    ;                  [attribute~="value"] - elements where attribute containing value
    ;                  [attribute$="value"] - elements where attribute ending with value
    ; Known bugs ....: - no empty element type is allowed - you have to set a type
    ;                  - If Balancing is not correct in the string - the result is also not correct
    ;                  - If selector is too general - some result may get doubled - to solve this: be as exactly as possible
    ; Author ........: AspirinJunkie
    ; Version .......: 0.8
    ; =================================================================================================
    Func _CssSelectFromString($s_String, $s_Selector, Const $b_First = True)
    	Local $s_Type = ""
    	Local $a_RegEx, $b_Match, $ID, $i, $j, $a_Ret
    	Local Static $o_Result
    
    
    	If $b_First Then
    		$s_String = StringRegExpReplace($s_String, "(?s)(?x)(?:<!--.+?)(?R)?(?:-->)", "") ; Kommentare killen
    		$s_String = StringRegExpReplace($s_String, "(?s)(?x)(?:<script.+?)(?R)?(?:</script)", "") ; Script-Elemente killen (Inhalt könnte Probleme beim Parsen bringen)
    		$s_String = StringRegExpReplace($s_String, "(?s)^.+<body\b(.+?)</body>.+$", "$1") ; Nur Inhalt des Bodys verwenden
    		$o_Result = ObjCreate('Scripting.Dictionary')
    	EndIf
    
    
    	$s_Selector = StringStripWS($s_Selector, 7)
    	Local $s_CurrentSelector = StringRegExp($s_Selector, "^(\S+)", 3)[0]
    	Local $s_SelectorRest = StringStripWS(StringRegExpReplace($s_Selector, "^(\S+)", ""), 7)
    
    
    	; Get the element type:
    	$a_RegEx = StringRegExp($s_CurrentSelector, "^(\w*)", 3)
    	If @error Then Return SetError(1, @error, "")
    	$s_Type = $a_RegEx[0]
    
    
    	; Alle Typen durchgehen und auf Übereinstimmung mit weiteren KLassifikatoren prüfen
    	Local $a_Types = _HtmlElements($s_String, $s_Type)
    
    
    	Local $a_AttribOpt = StringRegExp($s_CurrentSelector, "\[(\w+)\s*([~\*|\^\$]?=)\s*['""](.+?)['""]\s*\]", 4)
    	If @error Then Local $a_AttribOpt[0]
    	Local $a_ClassesOpt = StringRegExp($s_CurrentSelector, "\.(\w+)", 3)
    	If @error Then Local $a_ClassesOpt[0]
    	Local $a_IDOpt = StringRegExp($s_CurrentSelector, "#(\w+)", 3)
    	If @error Then Local $a_IDOpt[0]
    
    
    	For $j = 0 To UBound($a_Types) - 1
    		$b_Match = True
    		; Check for ID:
    		For $ID In $a_IDOpt
    			If Not StringRegExp($a_Types[$j][0], "(?x)\bid=['""]\b" & $ID & "\b['""]") Then ContinueLoop 2
    		Next
    
    
    		; Check for class:
    		For $Class In $a_ClassesOpt
    			If Not StringRegExp($a_Types[$j][0], "(?x)\bclass=['""][^'"">]*?\b" & $Class & "\b[^'"">]*?['""](?x)") Then ContinueLoop 2
    		Next
    
    
    		; Check for attributes:
    		; check for exist:
    		$a_RegEx = StringRegExp($s_CurrentSelector, "\[(\w+)\s*\]", 3)
    		If Not @error Then
    			For $Attr In $a_RegEx
    				If Not StringRegExp($a_Types[$j][0], "(?x)\b" & $Attr & "\b[=\s$]") Then ContinueLoop 2
    			Next
    		EndIf
    		For $AttrVal In $a_AttribOpt
    			Switch $AttrVal[2]
    				Case "=" ; full match
    					If Not StringRegExp($a_Types[$j][0], "(?x)" & $AttrVal[1] & "=['""]" & $AttrVal[3] & "['""]") Then ContinueLoop 2
    				Case "~=", "*=" ; partial match
    					If Not StringRegExp($a_Types[$j][0], "(?x)" & $AttrVal[1] & "=['""][^'""]*" & $AttrVal[3] & "[^'""]*['""]") Then ContinueLoop 2
    				Case "|=", "^=" ; start match
    					If Not StringRegExp($a_Types[$j][0], "(?x)" & $AttrVal[1] & "=['""]" & $AttrVal[3] & "[^'""]*['""]") Then ContinueLoop 2
    				Case "$=" ; end match
    					If Not StringRegExp($a_Types[$j][0], "(?x)" & $AttrVal[1] & "=['""][^'""]*" & $AttrVal[3] & "['""]") Then ContinueLoop 2
    			EndSwitch
    		Next
    
    
    		; save result element
    		If $s_SelectorRest = "" Then
    			Local $a_T[2] = [$a_Types[$j][0], $a_Types[$j][1]]
    			$o_Result($o_Result.Count) = $a_T
    		Else
    			_CssSelectFromString($a_Types[$j][1], $s_SelectorRest, False)
    		EndIf
    
    
    		; check for ":first" selector
    		If StringInStr($s_CurrentSelector, ":first", 2) Then ExitLoop
    ;~ 		If StringInStr($s_CurrentSelector, ":nth-of-type(" & $d_RetCounter & ")", 2) Then
    	Next
    
    
    	If $b_First Then
    		Local $n = $o_Result.Count
    		Local $a_Return[$n][2]
    		Local $v = 0
    		For $i In $o_Result.Keys()
    			$a_Return[$v][0] = StringStripWS($o_Result($i)[0], 3)
    			$a_Return[$v][1] = StringStripWS($o_Result($i)[1], 3)
    			$v += 1
    		Next
    		Return $a_Return
    	EndIf
    EndFunc   ;==>_CssSelectFromString
    
    
    
    
    
    
    
    
    ; #FUNCTION# ======================================================================================
    ; Name ..........: _HtmlElements()
    ; Description ...: extract all elements of type $s_Type from a html string
    ; Syntax ........: _HtmlElements(ByRef $s_Html, Const $s_Type)
    ; Parameters ....: $s_Html        - the html string
    ;                  $s_Type        - the html element type which should to extract
    ; Return values .: Success: Array[...][0] = element attributes string
    ;                           Array[...][1] = element content string
    ;                  Failure: ""
    ;                     @error = 1: no balanced elements found
    ; Known bugs ....: If Balancing is not correct in the string - the result is also not correct
    ; Author ........: AspirinJunkie
    ; =================================================================================================
    Func _HtmlElements(ByRef $s_Html, Const $s_Type)
    	Local $d_Start, $d_End, $d_T, $d_Pos = 1, $x = 0, $a_Element
    	Local $s_Begin = "<" & $s_Type, $s_Ende = "</" & $s_Type
    
    
    	StringReplace($s_Html, $s_Begin, $s_Begin, 0, 2)
    	Local $n = @extended
    	StringReplace($s_Html, $s_Ende, $s_Ende, 0, 2)
    	Local $u = @extended
    
    
    	If $n = 0 Or $u = 0 Then Return SetError(1, 0, "")
    	Local $a_Starts[$n], $a_Ends[$u]
    
    
    	; Alle Tag-Anfänge ermitteln:
    	Do
    		$d_T = StringInStr($s_Html, $s_Begin, 2, 1, $d_Pos)
    		If $d_T = 0 Then ExitLoop
    
    
    		$a_Starts[$x] = $d_T
    		$d_Pos = $d_T + StringLen($s_Begin)
    		$x += 1
    	Until 0
    
    
    	; Alle Tag-Enden ermitteln:
    	$x = 0
    	$d_Pos = 1
    	Do
    		$d_T = StringInStr($s_Html, $s_Ende, 2, 1, $d_Pos)
    		If $d_T = 0 Then ExitLoop
    
    
    		$a_Ends[$x] = $d_T
    		$d_Pos = $d_T + StringLen($s_Ende)
    		$x += 1
    	Until 0
    
    
    	; Funde matchen
    	Local $dMax = UBound($a_Ends) > UBound($a_Starts) ? UBound($a_Starts) - 1 : UBound($a_Ends) - 1
    	Local $d_End
    	Local $a_Return[$dMax + 1][3]
    	For $i = 0 To $dMax
    		$d_End = $a_Ends[$i]
    		For $j = $dMax To 0 Step -1
    			$d_Start = $a_Starts[$j]
    			If $d_Start = 1000000000 Then ContinueLoop
    			If $d_Start < $d_End Then
    				$a_Element = StringRegExp(StringMid($s_Html, $d_Start, $d_End - $d_Start + StringLen($s_Ende)), "(?s)^<" & $s_Type & "\s?(.*?)>(.*)</" & $s_Type, 3)
    				If UBound($a_Element) < 2 Then ContinueLoop
    				$a_Return[$i][0] = $a_Element[0]
    				$a_Return[$i][1] = $a_Element[1]
    				$a_Return[$i][2] = $d_Start
    
    
    				$a_Starts[$j] = 1000000000
    				ContinueLoop 2
    			EndIf
    		Next
    	Next
    
    
    	Return $a_Return
    EndFunc   ;==>_HtmlElements
    
    
    Func _URIEncode($sData)
        ; Prog@ndy
        Local $aData = StringSplit(BinaryToString(StringToBinary($sData,4),1),"")
        Local $nChar
        $sData=""
        For $i = 1 To $aData[0]
            ; ConsoleWrite($aData[$i] & @CRLF)
            $nChar = Asc($aData[$i])
            Switch $nChar
                Case 45, 46, 48 To 57, 65 To 90, 95, 97 To 122, 126
                    $sData &= $aData[$i]
                Case 32
                    $sData &= "+"
                Case Else
                    $sData &= "%" & Hex($nChar,2)
            EndSwitch
        Next
        Return $sData
    EndFunc
    Alles anzeigen
  • Längste Collatz-Folge | Project Euler

    • AspirinJunkie
    • 13. Mai 2015 um 12:02
    Zitat von BugFix

    Längste Folge bei Zahl: 837799 = 556 Terme

    Ich komme hierbei auf 525 (bzw. 524 wenn man die erste Zahl nicht mitzählt).
    Der Online-Rechner übrigens auch.

    Hab meine rekursive Variante noch bisschen optimiert:

    Spoiler anzeigen
    AutoIt
    Global $NN = 1e6
    Global $A[$NN+1] = [0, 1, 2]
    Global $iMax, $dMax, $t
    
    
    For $i = 3 To $NN - 1
    	If $A[$i] Then ContinueLoop
    	$t = C($A, $i)
    	If $t > $dMax Then
    		$dMax = $t
    		$iMax = $i
    	EndIf
    Next
    
    
    MsgBox(0, "", "Längste Reihe: " & $iMax & " - " & $dMax & " Schritte")
    
    
    Func C(ByRef $A, Const $N)
    	Local $d, $c
    	Local Const $i = BitAND($N, 1) ? 3 * $N + 1 : $N / 2
    
    
    	If $N < $NN Then
    		If $i < $NN Then
    			$d = $A[$i]
    			If $d Then
    				$A[$N] = $d + 1
    				Return $d + 1
    			EndIf
    		EndIf
    		$c = C($A, $i) + 1
    		$A[$N] = $c
    		Return $c
    	EndIf
    
    
    	If $i < $NN Then
    		$d = $A[$i]
    		If $d Then
    			If $N < $NN Then $A[$N] = $d + 1
    			Return $d + 1
    		EndIf
    	EndIf
    
    
    	Return C($A, $i) + 1
    EndFunc
    Alles anzeigen
  • Längste Collatz-Folge | Project Euler

    • AspirinJunkie
    • 13. Mai 2015 um 08:34
    Zitat von Make-Grafik

    Ich selber lege eine Tabelle an wo ich einfach schon bereits berechnete Längen abspeichere. Ich gehe jede Zahl einzeln durch und speichere die Länge der Kette ab. Sollte ein Glied einer Kette noch keine Länge zugewiesen bekommen haben, wird dies direkt erledigt. Der Vorteil ist dann, dass ich nur noch die Länge der Kette bis zu einem bereits berechneten Glied bestimmen muss und eben nicht bis zur 1. Ich hoffe es ist verständlich wie ich das meine.


    So würde ich spontan auch rangehen.
    Allerdings braucht das dann bei mir keine 100s:

    Spoiler anzeigen
    [autoit]

    #include <Array.au3>
    Global $NN = 1e6
    Global $A[$NN+1] = [0, 1]

    [/autoit] [autoit][/autoit] [autoit]

    For $N = 1 To UBound($A) -1
    $i = $N
    $c = 0

    [/autoit] [autoit][/autoit] [autoit]

    While $i > 1
    $c += 1
    $i = (Mod($i,2) = 0) ? $i / 2 : 3*$i +1
    If $i > $NN Then ContinueLoop ; damit Array nicht überschritten wird

    [/autoit] [autoit][/autoit] [autoit]

    ; falls schon berechnet Wert aus Array übernehmen:
    $d = $A[$i]
    If $d <> 0 Then
    $c += $d - 1
    ExitLoop
    EndIf
    WEnd
    $A[$N] = $c + 1
    Next

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    $iMax = _ArrayMaxIndex($A)
    $dMax = $A[$iMax]
    MsgBox(0,"", "Längste Reihe: " & $iMax & " - " & $dMax & " Schritte")

    [/autoit]


    Allerdings sind die Zwischenergebnisse Zahlen welche man später noch einmal berechnen muss.
    Beispielsweise kommt bei der Berechnung für die 3er Reihe gleich die Zahl 10 vor. Diese berechnet man dann implizit auch aber man verwendet das Ergebnis nicht, sondern berechnet später die Zahl 10 komplett neu.
    Das wäre sicherlich ein Optimierungsansatz.

    Edit: Hab mal versucht, das Problem zu lösen, in dem ich rekursiv vorgehe, da ich dabei bei jedem Schritt gleich dessen Tiefe mit speichern kann.
    Allerdings wird es nicht wirklich schneller.
    Ob dies am Verwaltungsaufwand für die Funktionen liegt und vielleicht AutoIt-Spezifisch ist - keine Ahnung:

    rekursive Variante
    [autoit]

    #include <Array.au3>

    [/autoit] [autoit][/autoit] [autoit]

    Global $NN = 1e6
    Global $A[$NN] = [0, 1, 2]

    [/autoit] [autoit][/autoit] [autoit]

    For $i = 3 To $NN - 1
    Collard($A, $i)
    Next
    $iMax = _ArrayMaxIndex($A)
    $dMax = $A[$iMax]
    MsgBox(0,"", "Längste Reihe: " & $iMax & " - " & $dMax & " Schritte")

    [/autoit] [autoit][/autoit] [autoit]

    Func Collard(ByRef $A, Const $N)
    Local $i = (Mod($N, 2) = 0) ? $N / 2 : 3 * $N + 1

    [/autoit] [autoit][/autoit] [autoit]

    If $i < $NN Then
    Local $d = $A[$i]
    If $d <> 0 Then
    If $N < $NN Then $A[$N] = $d + 1
    Return $d + 1
    EndIf
    EndIf
    Local $c = Collard($A, $i) + 1
    If $N < $NN Then $A[$N] = $c
    Return $c
    EndFunc ;==>Collard

    [/autoit]

    Edit2: Hab die rekursive Variante noch bisschen optimiert:

    rekursive Variante 2
    [autoit]

    #include <Array.au3>

    [/autoit] [autoit][/autoit] [autoit]

    Global $NN = 1e6
    Global $A[$NN] = [0, 1, 2]

    [/autoit] [autoit][/autoit] [autoit]

    For $i = 3 To $NN - 1
    Collard($A, $i)
    Next
    $iMax = _ArrayMaxIndex($A)
    $dMax = $A[$iMax]
    MsgBox(0, "", "Längste Reihe: " & $iMax & " - " & $dMax & " Schritte")

    [/autoit] [autoit][/autoit] [autoit]

    Func Collard(ByRef $A, Const $N)
    Local $d, $c, $i
    If $N < $NN Then
    $d = $A[$N]
    If $d <> 0 Then Return $d
    $i = BitAND($N, 1) ? 3 * $N + 1 : $N / 2
    If $i < $NN Then
    $d = $A[$i]
    If $d <> 0 Then
    $A[$N] = $d + 1
    Return $d + 1
    EndIf
    EndIf
    $c = Collard($A, $i) + 1
    $A[$N] = $c
    Return $c
    EndIf

    [/autoit] [autoit][/autoit] [autoit]

    $i = BitAND($N, 1) ? 3 * $N + 1 : $N / 2
    If $i < $NN Then
    $d = $A[$i]
    If $d <> 0 Then
    If $N < $NN Then $A[$N] = $d + 1
    Return $d + 1
    EndIf
    EndIf

    [/autoit] [autoit][/autoit] [autoit]

    Return Collard($A, $i) + 1
    EndFunc ;==>Collard

    [/autoit]
  • _DynArray-UDF - halbdynamische Arrays mit AutoIt

    • AspirinJunkie
    • 12. Mai 2015 um 13:01

    Hab sie wieder dran gehangen.

  • Do-Funktion um Abbruchkriterium MaxTime erweitern

    • AspirinJunkie
    • 11. Mai 2015 um 14:36

    Um was für eine Datenbank handelt es sich denn?
    Wie greifst du auf diese zu?

    Der Aufbau per PixelSearch wirkt hierbei ziemlich skurril.
    Eine vernünftiger Direktzugriff von AutoIt aus, kann die TimeOut-Geschichte schon deutlich anders aussehen lassen.

    Also ein paar mehr Informationen hierzu wären sicherlich geeignet dir schon grundlegend mehr zu helfen, als dich weiter auf einem (vielleicht) falschem Ansatz weiter reiten zu lassen.

  • $CmdLine Fehler

    • AspirinJunkie
    • 7. Mai 2015 um 15:15

    Bei der Parameterübergabe an Programme trennt man einzelne Parameter per Leerzeichen.
    Wenn ein Parameter allerdings selbst ein Leerzeichen enthält schließt man ihn in Anführungszeichen ein, damit dessen Leerzeichen nicht als Parametertrennung interpretiert wird.

    Wenn du deinen Parameterstring folgendermaßen bastelst:

    [autoit]

    MsgBox(0,"", '"' & $Parameter[1][1] & '" "' & $Parameter[1][2] & '" "' & $Parameter[1][3] & '" "' & $Parameter[1][4] & '"')

    [/autoit]

    sollte das gewünschte Ergebnis kommen. Die Anführungszeichen sind dabei wie gesagt nur notwendig, wenn die Werte selbst Leerzeichen enthalten.

  • $CmdLine Fehler

    • AspirinJunkie
    • 7. Mai 2015 um 13:28
    Zitat von Silvermoon

    Das ist doch wohl logisch das man zuerst mit Msgbox bzw. Tooltip die Werte anschaut.

    Was du anscheinend aber dennoch unterlassen hast.

    wenn du mein kurzes Beispiel ausführst, erhälst du als Ergebnis:

    Code
    "Wert1Wert2Wert3Wert4"

    Und das macht dich überhaupt nicht stutzig?
    Damit übergibst du an das zweite Programm nur einen einzigen Parameter.
    Es gibt nichts (Leerzeichen...) an dem das zweite Programm erkennen könnte, dass es sich um mehrere einzelne Werte handelt.

  • $CmdLine Fehler

    • AspirinJunkie
    • 7. Mai 2015 um 11:18

    Zum Debugging gehört vor allem sich Inhalte von Variablen und zu übergebenden Werten mal auszugeben und auf Korrektheit zu prüfen.
    In deinem Fall würde man wohl sich mal den zu übergebenden Parameterstring genauer anschauen - z.B. so:

    [autoit]

    msgbox(0,"", '"'&$Parameter[1][1]&$Parameter[1][2]& $Parameter[1][3]& $Parameter[1][4]& '"')

    [/autoit]

    So sollte schnell klar werden wo das Problem liegt.

  • TimeDiff soll Dauer ausgeben

    • AspirinJunkie
    • 29. April 2015 um 13:43

    Das TimerInit gehört vor die Do-Until-Schleife

    Btw: DeziSekunden sind auch eine ziemlich seltene Einheit für die Ausgabe von Zeitangaben...
    Vor allem wenn trotzdem nur "s" als Einheit dahinter steht.

  • Hilfe

    • AspirinJunkie
    • 17. April 2015 um 12:30

    Sind wir mal ganz optimistisch und sagen, dass jeder einzelne Schleifendurchlauf nur 1ms benötigt.
    Dann ist deine Schleife schon in 2,8*10^64 Jahren fertig.
    Denk einfach mal ganz kurz über diese Zahl nach...

    Und zum Rest: Wenn es deine Seite ist, dann würdest du nicht nach einer IE-Lösung fragen, sondern wie man das per FTP-Zugriff macht.
    Denn mindestens den solltest du ja haben wenn es deine Seite ist. Oder sogar einen Remote-Zugriff.
    Ich gehe aber eh nicht davon aus, da es sich mit großer Wahrscheinlichkeit um directory.io handelt und diese gehört laut einer whois-Abfrage einem gewissen Arran Walker.
    Und auch dann solltest du vorher einfach mal hierzu googlen und wirst ziemlich schnell fündig, dass es sich hierbei um einen Hoax handelt (siehe z.B. den Ihre FAQ)

    Aber warum erzähle ich das überhaupt jemanden der eine Schleife von 1 bis 904625697166532776746648320380374280100293470930272690489102837043110636675 laufen lassen wollte...

Spenden

Jeder Euro hilft uns, Euch zu helfen.

Download

AutoIt Tutorial
AutoIt Buch
Onlinehilfe
AutoIt Entwickler
  1. Datenschutzerklärung
  2. Impressum
  3. Shoutbox-Archiv
Community-Software: WoltLab Suite™