1. Dashboard
  2. Mitglieder
    1. Letzte Aktivitäten
    2. Benutzer online
    3. Team
    4. Mitgliedersuche
  3. Forenregeln
  4. Forum
    1. Unerledigte Themen
  • Anmelden
  • Registrieren
  • Suche
Alles
  • Alles
  • Artikel
  • Seiten
  • Forum
  • Erweiterte Suche
  1. AutoIt.de - Das deutschsprachige Forum.
  2. Mitglieder
  3. AspirinJunkie

Beiträge von AspirinJunkie

  • SQLite prüfen ob Datensatz existiert

    • AspirinJunkie
    • 8. September 2014 um 20:03

    Natürlich kannst du auch direkt in Sqlite das Vorhandensein eines Datensatzes prüfen.
    Ist auch effizienter.

    Für deinen Fall würde die Query in Sqlite so aussehen:

    SQL
    SELECT EXISTS(SELECT * IN Leser WHERE Nummer = 1);

    Als Rückgabe erhält man bei Existenz eine 1, bei Nichtexistenz eine 0.

    Aber eigentlich willst du das scheinbar gar nicht wissen.
    Deine eigentliche Frage lautete wahrscheinlich eher (Siehe XY-Problem...): Wie kann ich in Sqlite einen Datensatz nur dann hinzufügen wenn er nicht schon existiert?
    Das geht auch ziemlich einfach in Sqlite.
    Hierzu musst du Sqlite erst einmal sagen, dass Nummer nur jeweils einmal vorkommen darf und wenn diese Bedingung verletzt wird der jeweilige Befehl ignoriert wird:

    SQL
    ALTER TABLE Leser ADD CONSTRAINT UQ_Nummer UNIQUE(Nummer) ON CONFLICT IGNORE;


    Wenn du das einmal gemacht hast kannst du dein Insert absofort folgendermaßen schreiben:

    SQL
    INSERT OR IGNORE INTO Leser (Nummer,...) VALUES (...)

    Der Datensatz wird hierbei nur dann eingefügt, wenn die Nummer noch nocht nicht existiert.

  • Prüfen ob lokaler Benutzer vorhanden ist

    • AspirinJunkie
    • 8. September 2014 um 08:38

    Im Forum werdeb doppelte Anführungszeichen mit \" escaped.
    Will man aber nun diese Reihenfolge aber geschrieben sehen muss man den Backslash wiederrum escapen.
    Also dann so: \\"
    Möchte man nun einen doppelten Backslash und dann ein Anführungszeichen muss man ergo vier Backslash schreiben: \\\\"

  • Probleme mit MustDeclareVars

    • AspirinJunkie
    • 5. September 2014 um 14:23
    Zitat von elcojon

    zu 1. ja okay hab ich nich ausprobiert aber in c ist das ja so...

    C verhält sich da genauso wie AutoIt auch.
    Folgendes kompiliert in C nicht (Fehlermeldung undeclared identifier müsste kommen):

    Spoiler anzeigen
    Code
    #include <stdio.h>
    
    
    void _EineFunktion(){	
    	int Answer=5;
    }
    
    
    int main(void)
    {
    	_EineFunktion();
    	Answer = 6;
    	printf("Answer: %2d\n", Answer);
    	return 0;
    }
    Alles anzeigen
    Zitat von elcojon

    zu 2. ja und genau das gleiche ist bei switch.. switch entscheidet welche "innere Funktion" aufgerufen wird (via wahrheitswert der mittels den cases festgelegt wird) bei select würde ich es ja noch verstehen weil dort mehrere zutreffen können und sie nacheinander abgearbeitet werden aber bei switch? naja.. problem ist jz auf jedenfall bekannt und man weiß jz woran man ist

    Wenn du etwas innerhalb von einem Case (egal ob in Switch/Select/If-Else-Endif) deklarierst, ist dessen Deklaration für folgende Codeteile nicht mehr gesichert. Es ist vollkommen logisch und korrekt, dass dabei der Fehler der nicht deklarierten Variable kommt.

    Edit: O.k. dein Vergleich mit C bezog sich auf die Lage der Funktionsdeklaration - das ist dort tatsächlich anders.

  • Probleme mit MustDeclareVars

    • AspirinJunkie
    • 5. September 2014 um 14:07

    Hier liegen gleich zwei Missverständnisse zu Grunde:

    • Die Deklaration und Definition einer Funktion bedeutet nicht die Ausführung dieser Funktion. Wenn man eine Funktion definiert wird Sie lediglich dem Interpreter namentlich bekannt gemacht und angegeben wo sie steht. Alles was in ihr ausgeführt werden soll wird schlicht erst einmal ignoriert. Erst wenn die Funktion explizit aufgerufen wird, kommt der Code in Ihr zur Ausführung. In AutoIt ist es sogar egal wo die Funktion deklariert wird. Ob vor oder nach einem Aufruf ist egal.
    • Local in einer Funktion bedeutet, dass die damit deklarierte Variable nur innerhalb der Funktion existiert und sichtbar ist. Außerhalb dieser Funktion ist die damit deklarierte Variable nicht sichtbar.


    Aus diesen beiden Gründen ist die Fehlermeldung von Au3Check also vollkommen korrekt.
    Du weist in Zeile 7 einer Variablen namens $Answer einen Wert zu welche in diesem Rahmen nie deklariert wurde.

  • Probleme mit MustDeclareVars

    • AspirinJunkie
    • 5. September 2014 um 13:52
    Zitat von elcojon

    stimmt fast... bestimme ich eine lokale in einer func. und code unter ihr weiter meckert mustdecare check auch rum... und sie ist theoretisch definiert... jedoch nicht zwingend (must) ...

    Kurzes Minimalbeispiel dazu?
    Weil was meinst du mit "Unter ihr"?

  • Probleme mit MustDeclareVars

    • AspirinJunkie
    • 5. September 2014 um 13:47
    Zitat von elcojon

    Es ligt dem ganzen wohl ein Fehler in der Struktur der Au3Check, bzw. was sich auch immer um das mustdeclar kümmert, vor.

    $a war weiter oben in einem anderes Case bereits deklariert.
    in case $6 aber noch nicht...

    Wenn $a lediglich in einem anderen Case deklariert wird, dann ist das kein Fehler von Au3Check sondern schlicht korrekt.
    Mit MustDeclareVars soll sichergestellt werden, dass Variablen erst nach einer expliziten Deklaration initialisiert werden dürfen.
    Wenn die Deklaration aber in einem Case steht ist die Deklaration in einem anderen Case nicht sichergestellt (weil das Case mit der Deklaration unter Umständen nie aufgerufen wird).
    Die Deklaration muss also außerhalb des Switchs passieren wenn eine Variable Case-Übergreifende verwendet wird. Oder in jedem Case wo sie verwendet wird einzeln.

    Für Fälle in denen die Struktur wirklich mal zu komplex für Au3Check ist, nimmt man hingegen #forceref.

    Zitat von elcojon

    ... und wegen minimal beispiel... wenn ICH code... kann es keiner lesen und jz den ganzen code aufräumen nur um iwas kleines zu fixen.. nää

    Tja dann ist die Wahrscheinlichkeit, dass dir jemand (wie hier) dabei helfen kann und möchte schlicht deutlich geringer.

  • Probleme mit MustDeclareVars

    • AspirinJunkie
    • 5. September 2014 um 13:19

    Ehrlich gesagt komme ich hier nicht mit, weil nie ein vollständiges Minimalbeispiel vorliegt bei dem man mal das Problem direkt nachvollziehen kann.

    Dennoch werfe ich mal einen Suchbegriff für die AutoIt-Hilfe in den Raum:

    [autoit]

    #forceref

    [/autoit]
  • Stimme zum Vorlesen von Texten

    • AspirinJunkie
    • 3. September 2014 um 18:25

    Dir ist schon die Komplexität dieses Unterfangens bewusst?
    Nicht nur die Sprachsynthese - für die es extra wissenschaftliche Institute gibt, die sich nur allein damit beschäftigen.
    Auch die automatische Silbentrennung ist alles andere als trivial.
    Der sehr gute Silbentrennungsalgorithmus von LaTeX z.B. wurde von Frankling Mark Liang entwickelt - er hat darüber seine Doktorarbeit geschrieben...

    Es gibt von diesem Algorithmus unter anderem auch eine Umsetzung in Python - diesen Code würde ich als Grundlage für einen AutoIt-Ansatz verwenden.
    Eventuell benötigst du noch deutsche Trennmuster hierfür. >>Dies<< wäre eine Quelle hierfür.

    Aber prinzipiell: Junge Junge - da hast du dir ja ganz schön was vorgenommen...

  • OnePlus One Invite

    • AspirinJunkie
    • 3. September 2014 um 14:14
    Zitat von xedoc

    Der Verkauf wäre bei einem subventionierten Handy möglich, da der Besitz schon auf dich übergegangen ist. Anders sieht bei Mietkauf-Geschäften aus (o2 my Handy, Base, etc). Da geht der Besitz erst nach dem Zahlen der letzten Rate auf dich über.


    [Klugscheißmodus]
    Der rechtliche Besitzer eines Smartphone wäre auch ein Dieb welcher das Smartphone gestohlen hat.
    Für die rechtliche Einordnung muss hingegen die Frage nach dem Eigentümer gestellt werden.
    [/Klugscheißmodus]

  • SQL Abfrage

    • AspirinJunkie
    • 3. September 2014 um 12:19
    Zitat von 20721

    Es zeigt mir wie gesagt nur den ersten Datensatz an den er findet, er sollte aber alle Datensätze anzeigen wo das Datum größer als der 02.09.2014 ist.
    Muss ich noch eine entsprechende Schleife einbauen ?

    Ja musst du.
    Das RecordSet-Objekt zeigt immer nur auf einen Datensatz.
    Willst du alle haben musst du durchiterieren.

    Grundsätzlich sollte folgender Aufbau hierfür funktionieren:

    [autoit]

    Do
    ; hier per z.b. .Fields den aktuellen Datensatz verarbeiten
    $rs.MoveNext()
    Until $rs.EOF

    [/autoit]
    Zitat von 20721

    Die Abfrage würde ich dann gerne in eine Textdatei schreiben lassen

    Viele DBMS können Ausgaben direkt in Dateien ausgeben.
    Bei einer Oracle DB wird das glaube ich über das Spool-Kommando erreicht.

    Zitat von 20721

    #include <sqlite.au3>
    #include <sqlite.dll.au3>
    #include <mysql.au3>

    Warum bindest du die SQLite- und Mysql-UDF ein wenn du sie nicht benutzt?

  • StringInString -> 4 stellige Zahl

    • AspirinJunkie
    • 2. September 2014 um 15:02

    Das heißt du willst nicht nur überprüfen ob eine vierstellige Nummer existiert sondern auch diese Nummer weiterverwenden?
    In dem Fall musst du das ganze noch bisschen anpassen:

    [autoit]

    $s_String = "Test2151dsdasd"
    $a_Ret = StringRegExp($s_String, "(?<!\d)(\d{4})(?!\d)", 3)
    If @error Then
    MsgBox(0,"", "vierstellige Zahl nicht gefunden.")
    Else
    MsgBox(0,"", "vierstellige Zahl im String gefunden: " & $a_Ret[0])
    EndIf

    [/autoit]
    Zitat von lumb

    Ich denke die Vorschläge bringen mich weiter, da die Laufzeit nahezu egal ist.

    Keine Angst - StringRegExp ist verdammt flott.

  • StringInString -> 4 stellige Zahl

    • AspirinJunkie
    • 2. September 2014 um 14:44

    Sowas kann man ganz gut mit regulären Ausdrücken regeln (in AutoIt über die Funktion StringRegexp).
    4 Zahlen zu finden ist damit recht einfach.
    Allerdings kommt es immer noch auf den konkreten Anwendungsfall an welche Sonderfälle mit beachtet werden müssen.
    Robust (aber nicht ganz trivial) ist folgende Variante:

    [autoit]

    $s_String = "Test21515dsdasd"
    If StringRegExp($s_String, "(?<!\d)\d{4}(?!\d)") Then
    MsgBox(0,"", "vierstellige Zahl im String gefunden")
    Else
    MsgBox(0,"", "vierstellige Zahl nicht gefunden.")
    EndIf

    [/autoit]


    Am besten ist jedoch du beschreibst mal den Anwendungsfall und gibst dazu ein paar Beispiele.

    name22
    Dein Pattern meldet auch true bei 5-stellige Zahlen (matcht nur die ersten 4 Ziffern der Zahl).

  • QueryPerformance

    • AspirinJunkie
    • 2. September 2014 um 13:51

    AutoIt nutzt intern durchaus die API-Dlls, greift aber für DLLCall nicht darauf zurück.
    Kannst du selbst testen:

    Spoiler anzeigen
    [autoit]

    Global Const $s_Dll = "kernel32.dll"
    Global Const $s_Proc = "QueryPerformanceCounter"
    Global Const $N = 1e5

    [/autoit] [autoit][/autoit] [autoit]

    ; Ohne DllOpen
    $iT = TimerInit()
    For $i = 1 To $N
    DllCall($s_Dll, "BOOL", $s_Proc, "Int64*", "")
    Next
    $iT = TimerDiff($iT)
    ConsoleWrite(StringFormat("% 25s: \t%7.4f ms\n", "ohne DLLOpen()", $iT / $N))

    [/autoit] [autoit][/autoit] [autoit]

    ; Ohne DllOpen + Ordinal number
    $iT = TimerInit()
    $ord = DllGetProcOrdinal($s_Dll, $s_Proc)
    For $i = 1 To $N
    DllCall($s_Dll, "BOOL", $ord, "Int64*", "")
    Next
    $iT = TimerDiff($iT)
    ConsoleWrite(StringFormat("% 25s: \t%7.4f ms\n", "ohne DLLOpen() + Ord", $iT / $N))

    [/autoit] [autoit][/autoit] [autoit]

    ; Mit DllOpen
    $iT = TimerInit()
    $h_DLL = DllOpen($s_Dll)
    For $i = 1 To $N
    DllCall($h_DLL, "BOOL", $s_Proc, "Int64*", "")
    Next
    DllClose($h_DLL)
    $iT = TimerDiff($iT)
    ConsoleWrite(StringFormat("% 25s: \t%7.4f ms\n", "mit DLLOpen()", $iT / $N))

    [/autoit] [autoit][/autoit] [autoit]

    ; Mit DllOpen + OrdinalNumber
    $iT = TimerInit()
    $ord = DllGetProcOrdinal($s_Dll, $s_Proc)
    $h_DLL = DllOpen($s_Dll)
    For $i = 1 To $N
    DllCall($h_DLL, "BOOL", $ord, "Int64*", "")
    Next
    DllClose($h_DLL)
    $iT = TimerDiff($iT)
    ConsoleWrite(StringFormat("% 25s: \t%7.4f ms\n", "mit DLLOpen() + Ord", $iT / $N))

    [/autoit] [autoit][/autoit] [autoit]

    ; Mit DllCallAddress
    $iT = TimerInit()
    $h_KRNL32 = DllOpen("kernel32.dll")
    $h_Dll = DllCall($h_KRNL32, "handle", "GetModuleHandleW", "wstr", $s_Dll)[0] ; die Startadresse der Dll im Speicher (falls bereits geladen - ansonsten LoadLibraryW)
    If $h_Dll = 0 Then $h_Dll = DllCall($h_KRNL32, "handle", "LoadLibraryW", "wstr", $s_Dll)[0] ; falls GetModuleHandle nix findet (eigentlich nur bei externen dlls welche noch extra geladen werden müssen)
    $p_Proc = DllCall($h_KRNL32, "ptr", "GetProcAddress", "handle", $h_Dll, "str", $s_Proc)[0] ; Die Adresse des Beginns der Prozedur im Speicher
    For $i = 1 To $N
    DllCallAddress("BOOL", $p_Proc, "Int64*", "")
    Next
    DllCall($h_KRNL32, "BOOL", "FreeLibrary", "HANDLE", $h_Dll) ; Handle zur dll wieder schließen
    DllClose($h_KRNL32)
    $iT = TimerDiff($iT)
    ConsoleWrite(StringFormat("% 25s: \t%7.4f ms\n", "mit DllCallAddress()", $iT / $N))

    [/autoit] [autoit][/autoit] [autoit]

    ; #FUNCTION# ======================================================================================
    ; Name ..........: DllGetProcOrdinal()
    ; Description ...: returns the procedure's ordinal number in it's dll-file
    ; Syntax ........: DllGetProcOrdinal(Const $s_Module, Const $s_Procedure)
    ; Parameters ....: $s_Module - the dll filename
    ; $s_Procedure - the name of the procedure
    ; Return values .: Success: the ordinal value of $s_Procedure
    ; Failure: -1
    ; @error = 1: procedure not found inside the dll
    ; 2: couldn't open the dll-file
    ; 3: couldn't find the procedure in the dll by it's procedure name
    ; Author ........: AspirinJunkie
    ; =================================================================================================
    Func DllGetProcOrdinal(Const $s_Module, Const $s_Procedure)
    Local Const $h_KRNL32 = DllOpen("kernel32.dll")

    [/autoit] [autoit][/autoit] [autoit]

    ; Open the dll:
    Local $h_Module = DllCall($h_KRNL32, "handle", "GetModuleHandleW", "wstr", $s_Module)[0]
    If $h_Module = 0 Then
    $h_Module = DllCall($h_KRNL32, "handle", "LoadLibraryW", "wstr", $s_Module)[0]
    If $h_Module = 0 Then Return SetError(2, 0, -1)
    EndIf

    [/autoit] [autoit][/autoit] [autoit]

    ; Get address of the procedure
    Local $p_Procedure = DllCall($h_KRNL32, "ptr", "GetProcAddress", "handle", $h_Module, "str", $s_Procedure)[0]
    If $p_Procedure = 0 Then Return SetError(3, 0, -1)

    [/autoit] [autoit][/autoit] [autoit]

    ; Iterate over the ordinal values and compare with the procedure address
    Local $ord = 1, $p_Proc
    Do
    $p_Proc = DllCall($h_KRNL32, "ptr", "GetProcAddress", "handle", $h_Module, "INT", $ord)[0]
    If $p_Proc = $p_Procedure Then
    DllCall($h_KRNL32, "BOOL", "FreeLibrary", "HANDLE", $h_Module)
    DllClose($h_KRNL32)
    Return $ord
    EndIf
    $ord += 1
    Until $p_Proc = 0
    DllCall($h_KRNL32, "BOOL", "FreeLibrary", "HANDLE", $h_Module)
    DllClose($h_KRNL32)
    Return SetError(1, 0, -1)
    EndFunc ;==>DllGetProcOrdinal

    [/autoit]
  • _DynArray-UDF - halbdynamische Arrays mit AutoIt

    • AspirinJunkie
    • 2. September 2014 um 13:43

    Danke dir fürs Feedback.
    Der Performance-Unterschied hängt direkt von der Anzahl der Elemente ab.
    Wenn du weniger Elemente hast, ist der Unterschied geringer.
    Wenn mehr Elemente hinzugefügt werden ist der Unterschied größer.

  • QueryPerformance

    • AspirinJunkie
    • 2. September 2014 um 13:08

    Wenn du die Funktion weiter optimieren willst dann solltest du dir mal die Funktion DllOpen() anschauen.
    Momentan wird bei jedem einzelnen DllCall die kernel32.dll erneut geöffnet, die Funktion ausgeführt und dann gleich wieder geschlossen - das muss nicht sein.

  • _DynArray-UDF - halbdynamische Arrays mit AutoIt

    • AspirinJunkie
    • 2. September 2014 um 10:17

    Die Ansätze von >>hier<< habe ich mal zu einer ausgewachsenen UDF ausgebaut (Siehe Anhang).
    Worum geht es?: Arrays sind verdammt fix beim direkten Zugriff auf einzelne ihrer Elemente. Sobald aber Werte hinzugefügt oder gelöscht werden sollen sind diese Vorgänge (über ReDim) unglaublich träge.
    Je größer die Arrays werden umso schlimmer wird das dann. Arrays eignen sich daher für eine Vielzahl an Anwendungsfällen nicht.
    Ein gebräuchlicher Lösungsansatz ist jedoch nur Zweierpotenzen als Arraygröße zuzulassen. Das verschafft Luft für neue Elemente und Arrays können von nun an auch dynamisch verwendet werden. Nun kann man ein Array auch sinnvoll wie ein Stack oder eine Queue verwenden.

    Auf dieser Idee aufbauend habe ich eine UDF erstellt welche die Nutzung dieses Prinzips für 1D-Arrays genauso einfach machen soll wie die bisherigen _Array-Funktionen in AutoIt und im Grunde als ihr Ersatz dienen soll.
    Als zusätzliches Schmankerl habe ich dann noch die von Python bekannten Map-, Reduce- und Filter-Funktionen für AutoIt umgesetzt.

    Die UDF enthält somit folgende Funktionen:

    Code
    --------------- Funktionen für dynamische Arrays -----------------------------------
    _DynArrayPush          - neuen Wert ans Ende anhängen (vgl. Stack)
    _DynArrayPop           - letzten Wert zurückgeben und aus dem Array entfernen (vgl. Stack)
    _DynArrayEnqueue       - Wert ans Ende des Arrays hinzufügen (vgl. Queue)
    _DynArrayDequeue       - ersten Wert des Arrays entfernen und zurückgeben (vgl. Queue)
    _DynArrayInsert        - einen oder mehrere Werte innerhalb des Arrays einfügen
    _DynArrayDelete        - einen oder mehrere Werte innerhalb des Arrays entfernen
    
    _DynArrayFromArray     - Konvertiert ein normales Array in ein dynamisches Array
    _DynArrayToArray       - Konvertiert ein dynamisches Array in ein normales Array
    _DynArrayFromString    - Erzeugt ein dynamisches Array aus einem String
    _DynArrayToString      - Konvertiert ein dynamisches Array in einen String, getrennt durch ein Trennzeichen
    
    _DynArraySearch        - Werte in einem unsortierten Array finden
    _DynArrayBinarySearch  - Werte in einem sortierten Array finden
    _DynArraySort          - Array sortieren
    _DynArrayIsSorted      - prüft ob ein dynamisches Array bereits nach einer freien Sortierfunktion sortiert wurde
    _DynArrayUnique        - entfernt doppelte Einträge aus einem dynamischen Array
    
    _DynArrayMap           - Wendet eine Funktion auf alle Elemente eines dynamischen Arrays an
    _DynArrayFilter        - Filtert die Werte eines dynamischen Arrays anhand einer externen Funktion
    _DynArrayReduce        - Reduziert die Elemente eines dynamischen Arrays auf einen Wert mit Hilfe einer externen Funktion
    
    _DynArrayFileList      - Dateiauflistung in Ordnern+Unterordnern mit frei individualisierbarer Filterfunktion
    
    ----------- Hilfsfunktionen und allgemein verwendbare Funktionen --------------------------
    _ArrayMap              - Wendet eine Funktion auf alle Elemente eines Arrays an
    _ArrayFilter           - Filtert die Werte eines Arrays anhand einer externen Funktion
    _ArrayReduce           - Reduziert die Elemente eines Arrays auf einen Wert mit Hilfe einer externen Funktion
    __DynArrayIsValid      - Prüft ob ein Array einem korrekten dynamischen Array entspricht
    __DynArrayRepair       - versucht ein korrumpiertes dynamisches Array zu reparieren
    __DynArrayIsPowerOfTwo - Prüft ob eine Zahl eine Zweierpotenz ist
    __DynArrayGetNextPowerOfTwo - gibt die nächste aufgerundete Zweierpotenz zu einer Zahl zurück
    __DynArrayGetPreviousPowerOfTwo - gibt die vorhergehende abgerundete Zweierpotenz zu einer Zahl zurück
    _ArraySortFlexible     - Sortiert ein Array mit einer beliebigen Vergleichsfunktion
    _ArraySortInsertion    - Sortiert ein Array mit einer beliebigen Vergleichsfunktion per Insertion-Sort
    _ArrayHeapSortBinary   - Sortiert ein Array mit einer beliebigen Vergleichsfunktion per Binary-Min-Heap-Sort
    _ArrayHeapSortTernary  - Sortiert ein Array mit einer beliebigen Vergleichsfunktion per Ternary-Min-Heap-Sort
    __ArrayDualPivotQuicksort - Sortiert ein Array mit einer beliebigen Vergleichsfunktion per Dual-Pivot-Quicksort
    _ArraySortWithList     - Sortiert ein Array über die Sortierfunktion des Arraylist-COM-Objektes
    _ArrayGetNthBiggestElement - gibt das n-größte Element in einem unsortierten Array ohne es zu sortieren (z.B. für Median)
    _ArrayAinATo2d         - konvertiert ein "Arrays in Array"-Konstrukt in ein 2D-Array
    _Array2dToAinA         - konvertiert ein 2D-Array in ein "Arrays-in-Array"-Konstrukt
    _ArrayGetMax           - ermittelt den Maximalwert in einem Array (auch mit eigener Vergleichsfunktion möglich)
    _ArrayGetMin           - ermittelt den Minimalwert in einem Array (auch mit eigener Vergleichsfunktion möglich)
    _ArrayBinarySearchFlex - führt eine binäre Suche in einem Array mit Hilfe einer eigenen Vergleichsfunktion durch
    _ArrayIsSorted         - prüft ob ein Array bereits nach einer freien Sortierfunktion sortiert wurde
    Alles anzeigen

    Um die Möglichkeiten der UDF zu demonstrieren gehen wir mal anhand von Beispielen durch:

    AutoIt: Ein dynamisches Array erstellen und befüllen
    #include "DynArray.au3"; dynamisches Array aus bestehendem konventionellem Array erstellen:
    
    
    Global $a_Array[] = [1,2,3,4,5]
    _DynArrayFromArray($a_Array) ; Array konvertieren
    _ArrayDisplay($a_Array, "das erzeugte dynamische Array")
    
    
    ; Neues dynamisches Array erstellen und dynamisch befüllen:
    
    
    Global $a_Array[] = [0] ; neues leeres dynamisches Array
    For $i = 1 To 25
        _DynArrayPush($a_Array, "Wert " & $i)
    Next
    _ArrayDisplay($a_Array, "das dynamisch erzeugte dynamische Array")
    
    
    ; dynamisches Array aus String erstellen mit Integer als Elementdatentypen:
    Global $a_Array = _DynArrayFromString("20|3|15|7Test|Test7|62", "|", Int)
    _ArrayDisplay($a_Array, "das aus einem String erzeugte Integerarray")
    Alles anzeigen
    AutoIt: Einfügen einzelner oder mehrerer Werte innerhalb des Arrays
    #include "DynArray.au3"
    
    
    Global $a_Array[] = [0] ; neues leeres dynamisches Array
    
    
    ; Dem Array dynamisch Elemente hinzufügen
    For $i = 1 To 25
        _DynArrayPush($a_Array, "Test " & $i)
    Next
    _ArrayDisplay($a_Array, "Das Array vor dem Einfügen")
    
    
    ; Einzelne Elemente innerhalb des Arrays einfügen:
    _DynArrayInsert($a_Array, "Insert 1", 4)
    _DynArrayInsert($a_Array, "Insert 2", 5)
    ; Mehrere Elemente auf einmal einfügen:
    Local $a_Temp[] = ["Insert 3", "Insert 4", "Insert 5",  "Insert 6"]
    _DynArrayInsert($a_Array, $a_Temp, 6)
    
    
    _ArrayDisplay($a_Array, "Das Array nach _DynArrayInsert")
    Alles anzeigen
    AutoIt: Elemente innerhalb des Arrays löschen
    #include "DynArray.au3"
    
    
    Global $a_Array[] = [1,2,3,4,5,7,8,9,10]
    _DynArrayFromArray($a_Array) ; Array konvertieren
    
    
    _ArrayDisplay($a_Array, "Array vor dem Löschen")
    
    
    ; Elemente löschen:
    _DynArrayDelete($a_Array, 4, 3)
    _ArrayDisplay($a_Array, "Das Array nach _DynArrayDelete")
    Alles anzeigen
    AutoIt: Verwendung als Stack
    #include "DynArray.au3"
    
    
    Global $a_Array[] = [0] ; neuer leerer Stack
    ; dynamisch Elemente hinzufügen
    For $i = 1 To 50
        _DynArrayPush($a_Array, "Test " & $i)
    Next
    _ArrayDisplay($a_Array, "Gefüllter Stack")
    
    
    ; Elemente abbauen bis Stack leer ist
    While $a_Array[0] > 0
        ConsoleWrite(_DynArrayPop($a_Array) & @CRLF)
    WEnd
    Alles anzeigen
    AutoIt: Verwendung als Queue
    #include "DynArray.au3"
    
    
    Global $a_Array[] = [0] ; neue leere Queue
    ; dynamisch Elemente hinzufügen
    For $i = 1 To 50
        _DynArrayEnqueue($a_Array, "Test " & $i)
    Next
    _ArrayDisplay($a_Array, "Gefüllte Queue")
    
    
    ; Elemente abarbeiten bis Queue leer ist
    Do
        ConsoleWrite(_DynArrayDequeue($a_Array) & @CRLF)
    Until $a_Array[0] = 0
    Alles anzeigen
    AutoIt: Array sortieren und durchsuchen
    #include "DynArray.au3"
    
    
    Global $a_Array[] = [0] ; neues leeres dynamisches Array
    
    
    ; Dem Array dynamisch Elemente hinzufügen
    For $i = 1 To 120 ; Array mit zufälligen Werten befüllen
        _DynArrayPush($a_Array, Random(1, 50, 1))
    Next
    _ArrayDisplay($a_Array, "das unsortierte Array")
    
    
    ; Wert in einem unsortierten Array suchen:
    $d_Found = _DynArraySearch($a_Array, 10)
    If Not @error Then MsgBox(0,"Gefunden", 'Wert "10" am Index ' & $d_Found & ' gefunden.')
    
    
    ; Array sortieren:
    _DynArraySort($a_Array)
    _ArrayDisplay($a_Array, "Das sortierte Array")
    
    
    ; Wert in einem sortierten Array suchen:
    $d_Found = _DynArrayBinarySearch($a_Array, 20)
    If Not @error Then MsgBox(0,"Gefunden", 'Wert "20" am Index ' & $d_Found & ' gefunden.')
    Alles anzeigen
    AutoIt: Array mit eigener Sortiervorschrift sortieren
    #include "DynArray.au3"
    
    
    ; dynamisches Array aus String erstellen:
    $a_Array = _DynArrayFromString("image20.jpg;image1.jpg;image11.jpg;image2.jpg;image3.jpg;image10.jpg;image12.jpg;image21.jpg;image22.jpg;image23.jpg", ";")
    _ArrayDisplay($a_Array, "das unsortierte Array")
    
    
    ; Array normal sortieren:
    _DynArraySort($a_Array)
    _ArrayDisplay($a_Array, "Das normal sortierte Array")
    
    
    ; Array wie im Explorer (natürlich) sortieren:
    _DynArraySort($a_Array, __MyNaturalCompare)
    _ArrayDisplay($a_Array, "Das natürlich sortierte Array")
    
    
    ; Prüfen ob Array wirklich natürlich sortiert wurde:
    MsgBox(0, "Prüfung", "Sortiert: " & _DynArrayIsSorted($a_Array, __MyNaturalCompare))
    
    
    
    
    
    
    ; Vergleichsfunktion als Wrapper für StrCmpLogicalW welche wie der Explorer intuitiver sortiert falls Zahlenwerte in den Strings vorkommen
    Func __MyNaturalCompare(Const ByRef $A, Const ByRef $B)
        Local Static $h_DLL_Shlwapi = DllOpen("Shlwapi.dll")
        Local $a_Ret = DllCall($h_DLL_Shlwapi, "int", "StrCmpLogicalW", "wstr", $A, "wstr", $B)
        If @error Then Return SetError(1, @error, 0)
        If Not IsString($A) Or Not IsString($B) Then Return $A > $B ? 1 : $A < $B ? -1 : 0
        Return $a_Ret[0]
    EndFunc   ;==>MyCompare
    Alles anzeigen
    AutoIt: 2D-Array mit komplexer Sortiervorschrift sortieren
    #include "DynArray.au3"
    
    
    ; 2D-Array erstellen
    Global $Array[1000][10]
    For $i = 0 To 999
        For $j = 0 To 9
            $Array[$i][$j] = Chr(Random(65, 90, 1))
        Next
    Next
    _ArrayDisplay($Array, "Das unsortierte Array")
    
    
    ; 2D-Array sortieren
    _ArraySortFlexible($Array, _SortByColumns)
    _ArrayDisplay($Array, "Das sortierte Array")
    
    
    
    
    ; eigene Vergleichsfunktion welche Schrittweise alle Spalten vergleicht
    Func _SortByColumns(ByRef $A, ByRef $B)
        For $i = 0 To UBound($A) -1
            If $A[$i] > $B[$i] Then Return 1
            If $A[$i] < $B[$i] Then Return -1
        Next
        Return 0
    EndFunc
    Alles anzeigen
    AutoIt: Funktionen auf Array mappen
    #include "DynArray.au3"
    
    
    ; dynamisches Array mit den Werten 1-10 erstellen:
    Global $a_Array[] = [1, 2, 3, 4, 5, 7, 8, 9, 10, 11, 12, 13, 14, 15]
    _DynArrayFromArray($a_Array) ; Array konvertieren
    _ArrayDisplay($a_Array, "Ausgangswerte")
    
    
    ; Funktion auf Array mappen:
    _DynArrayMap($a_Array, Square)
    _ArrayDisplay($a_Array, "Quadrierte Werte")
    
    
    ;Wurzel ziehen:
    _DynArrayMap($a_Array, Sqrt)
    _ArrayDisplay($a_Array, "Wurzel der quadrierten Werte")
    
    
    ; Funktion welche das Quadrat von $value zurückgibt
    Func Square(Const $value)
        Return $value * $value
    EndFunc   ;==>Square
    Alles anzeigen
    AutoIt: Werte aus einem Array filtern
    #include "DynArray.au3"
    
    
    ; Array mit Zahlen bis 100 erstellen:
    Global $a_Array[100]
    For $i = 0 To 99
        $a_Array[$i] = $i +1
    Next
    _DynArrayFromArray($a_Array)
    _ArrayDisplay($a_Array, "Array mit allen Zahlen")
    
    
    ; Nur Primzahlen behalten:
    _DynArrayFilter($a_Array, IsPrime)
    _ArrayDisplay($a_Array, "Array nur mit Primzahlen")
    
    
    ; Funktion welche prüft ob eine Zahl eine Primzahl ist
    Func IsPrime($io_number)
        Local $Num = Abs($io_number)
        If $Num < 2 And $Num > -2 Then Return 1
        If Mod($Num, 2) = 0 Then Return 0
        For $a = 3 To Int(($Num / 2) + 1) Step 2
            If Mod($Num, $a) = 0 Then Return 0
        Next
        Return 1
    EndFunc   ;==>IsPrime
    Alles anzeigen
    AutoIt: Ein Array auf einen skalaren Wert reduzieren
    #include "DynArray.au3"
    
    
    ; Array mit Zahlen bis 99 erstellen (hier mal mit _ArrayMap):
    Global $a_Array[100] = []
    _ArrayMap($a_Array, Index, False, True, True)
    _DynArrayFromArray($a_Array, True, True)
    _ArrayDisplay($a_Array, "Array mit Zahlen von 1-99")
    
    
    ; Die Quadratsumme der Werte des Arrays berechnen:
    MsgBox(0,"_DynArrayReduce", "Quadratsumme: " & _DynArrayReduce($a_Array, Squaresum))
    
    
    ; Reduce-Funktion zur Bildung der Quadratsumme:
    Func Squaresum(ByRef $x, Const $y)
        $x += $y * $y
    EndFunc   ;==>Sqaresum
    
    
    ; Mapfunktion welche als Wert den Index des Elementes zurückgibt
    Func Index(Const $value, Const $Index)
        Return $Index
    EndFunc   ;==>Index
    Alles anzeigen
    AutoIt: Dateien/Ordner in einem Verzeichnisbaum auflisten mit umfangreichen Filtermöglichkeiten
    #include "DynArray.au3"
    #include <Date.au3>
    
    
    ; Alle dll-Dateien in System32 die "win" im Dateinamen tragen
    $a_List = _DynArrayFileList("C:\Windows\System32", "win.*\.dll$", 1)
    _ArrayDisplay($a_List)
    
    
    ; Alle dll-Dateien in System32 und SysWOW64 die mit "win" anfangen und die innerhalb des letzten Jahres geändert wurden:
    $a_List = _DynArrayFileList("C:\Windows\System32|C:\Windows\SysWOW64", cb_MyFunc, 1)
    _ArrayDisplay($a_List)
    
    
    ; Callback-Funktion welche True zurückgibt, wenn eine Datei den Anforderungen entspricht und False wenn nicht
    Func cb_MyFunc(Const $s_Path)
        Local Static $Now = _NowCalc()
        If StringRegExp($s_Path, "\\win[^\\]*\.dll$") Then
            If _DateDiff("Y", StringRegExpReplace(FileGetTime($s_Path, 0, 1), "(\d{4})(\d{2})(\d{2}).+", "$1/$2/$3"), $Now) < 1.0 Then Return True
        EndIf
        Return False
    EndFunc   ;==>cb_MyFunc
    Alles anzeigen


    Wer mal wissen möchte, was das ganze für einen Unterschied beim dynamischen Hinzufügen von Werten macht kann folgendes kleines Testskript ausführen:

    AutoIt
    #include "DynArray.au3"
    
    Global $N = 1e4
    
    $iT = TimerInit()
    Global $a_Array[1] = [0]
    For $i = 1 To $N
        _DynArrayPush($a_Array, "Test " & $i)
    Next
    $iT = TimerDiff($iT)
    ConsoleWrite(StringFormat("% 15s: \t%7.1f ms\n", "_DynArrayPush()", $iT))
    _ArrayDisplay($a_Array)
    
    $iT = TimerInit()
    Global $a_Array[] = []
    For $i = 1 To $N
        _ArrayAdd($a_Array, "Test " & $i)
    Next
    $iT = TimerDiff($iT)
    ConsoleWrite(StringFormat("% 15s: \t%7.1f ms\n", "_ArrayAdd()", $iT))
    _ArrayDisplay($a_Array)
    Alles anzeigen

    Bei mir war _DynArrayPush dabei um den Faktor 20 schneller. Dieser Vorteil steigt weiter mit der Elementanzahl.

    Changelog:

    2020/06/16
    • __ArrayDualPivotQuicksort (und alle die diese verwenden wie z.B. _ArraySortFlexible): Fehlerhafte Bestimmung der beiden Pivotelemente - führte entweder zu langsamer Sortierung oder zu Abstürzen
    • unbenutzte aber deklarierte Variablen entfernt.

    Dateien

    DynArray.au3 114,89 kB – 617 Downloads
  • Netzwerkadapter de & aktivieren

    • AspirinJunkie
    • 1. September 2014 um 18:58

    Wobei die gepostete WMI-Variante bei mir ebenfalls funktioniert.
    Es fehlen allerdings zwei Backslashs.

    Hier mal die bereinigte Variante:

    Spoiler anzeigen
    [autoit]

    #RequireAdmin
    _WinWMI_NetworkAdapter_SetState("WiFi", "Disable")
    If @error Then MsgBox(48, "Fehler", "Fehler-Code: " & @error)

    [/autoit] [autoit][/autoit] [autoit]

    Func _WinWMI_NetworkAdapter_SetState(Const $sAdapterName, Const $sSetState, Const $sComputer = "127.0.0.1")
    Local $oWMI = ObjGet("winmgmts:{impersonationLevel=impersonate}!\\\" & $sComputer & "\root\CIMV2")
    If Not IsObj($oWMI) Then Return SetError(-1, @error, 0)
    $oList = $oWMI.ExecQuery("SELECT * FROM Win32_NetworkAdapter WHERE NetConnectionID = '" & $sAdapterName & "'", "WQL", 48)
    If (Not IsObj($oList)) Or (Not IsAdmin()) Then Return SetError(-2, @error, 0)
    For $oItem In $oList
    Local $errorlevel = 1
    If $sSetState = "Disable" Then $errorlevel = $oItem.Disable()
    If $sSetState = "Enable" Then $errorlevel = $oItem.Enable()
    If $errorlevel <> 0 Then Return SetError(-3, $errorlevel, 0)
    Next
    Return 1
    EndFunc

    [/autoit]
  • _StringBetween @error - Stack Overflow - Funktion in Funktion

    • AspirinJunkie
    • 31. August 2014 um 10:09
    Zitat von misterspeed

    Ohne [...] ungekürzten Quellcode [...] wird hier kaum jemand helfen können.

    Oh doch bitte bitte gekürzt.
    Das sehe ich hier ja leider so oft - Problem tritt auf und 5000 Zeilen unübersichtlicher Quellcode wird gepostet - wenn überhaupt jemand Lust hat zu helfen wird es demjenigen damit verdammt schwer gemacht.
    Wenn man wirklich Hilfe will ist das wichtigste ein Minimalskript.
    Also ein Skript welches:

    • den beschriebenen Fehler reproduziert.
    • so klein wie möglich ist.
    • bei dem alles was nichts mit der Reproduzierung des Fehlers zu tun hat entfernt wurde.
    • direkt bei jedem ohne weitere Anpassung lauffähig ist damit das Skript von Helfenden auch getestet werden kann.


    Neben dem Vorteil, dass man damit deutlich mehr Helfende erreicht (da sie ja nicht mehr vom riesigen Codewust abgeschreckt werden) und Helfende schneller den Fehler finden können (wegen dem Fokus auf das Wesentliche) ist der zweite Vorteil, dass man in 80% der Fälle beim Kürzen des Quellcodes selbst auf die Lösung stößt.
    Denn so geht man ja beim Fehler suchen vor: Man grenzt ihn schrittweise ein.

    Aber ich verstehe natürlich was du eigentlich sagen wolltest. Hier hat der TS ja nur unzusammenhängende nicht lauffähige Codefetzen gepostet - das ist natürlich der absolute Worst-Case wenn man Hilfe möchte.

  • Mit mehreren Arrays gleichen Case/Funktion etc. auslösen

    • AspirinJunkie
    • 28. August 2014 um 15:39

    Na was stehen denn für Werte im Array drin?
    Die Frage musst du dir stellen - ob das nun ein 2D-Array ist. ist schlicht wurscht.

    Du kannst mit Case Fälle in Bereiche von Ganzzahlen zusammenfassen.
    Nicht mehr und nicht weniger.

  • Mit mehreren Arrays gleichen Case/Funktion etc. auslösen

    • AspirinJunkie
    • 28. August 2014 um 15:05

    Das hat mit Arrays nichts zu tun sondern lediglich mit den Werten die du dort angibst.

    Ein Case 1 To 5 deckt z.B. die Fälle 1,2,3,4,5 ab.
    Blume nutzt in seinem Beispiel aus, dass die Control-IDs Ganzzahlen sind und nacheinander aufsteigend, nach dem Zeitpunkt ihrer Erstellung, sortiert sind.
    Wenn $MA[0] z.b. den Wert 3 bekommen hat, dann hat $MA[1] den Wert 4 bekommen und $MA[2] den Wert 5.

    Es kommt also nicht darauf an ob du die beiden Grenzwert für Case aus einem 1D oder 2D-Array holst, sondern schlicht nur welchen Wert sie besitzen.

Spenden

Jeder Euro hilft uns, Euch zu helfen.

Download

AutoIt Tutorial
AutoIt Buch
Onlinehilfe
AutoIt Entwickler
  1. Datenschutzerklärung
  2. Impressum
  3. Shoutbox-Archiv
Community-Software: WoltLab Suite™