Beiträge von BugFix

#include "GuiCtrlBusy.au3"

#Region
; Creates an Busy control.
; _GuiCtrlBusy_Create      ([$_sTitle = ''[, $_sText = ''[, $_iAlign=2[, $_iX = -1[, $_iY = -1[, $_iTimeout = -1[, $_iTimeCounter = -1[, $_BGRtitle = -1[, $_BGRtext = -1
;                           [, $_RGBtopleft = -1[, $_RGBbottomright = -1[, $_bRotate = False]]]]]]]]]]]])
; Close one/all controls.
; _GuiCtrlBusy_Close       ([$_hWnd = -1])

; Für die Manipulation von Ctrl gilt einheitlich:
; optionale Parameter --> "Leerstring"="Wert wird beibehalten", "-1"="USER_DEFAULT" oder der übergebene Wert

; Sets for title line: title, show:nothing(0)/countdown(1)/clocktime(2), timeout, color.
; _GuiCtrlBusy_SetTitle    ($_hWnd, $_sTitle = ''[, $_iTimeCounter = ''[, $_iTimeout = ''[, $_BGRtitle = ''[, $_bSetOnTop = '']]]])

; Sets icon from any *.dll/*.ico file.
; _GuiCtrlBusy_SetIcon     ($_hWnd, $_sIconFile=''[, $_iIconID])

; Sets text /~color /~size /~style /~font.
; _GuiCtrlBusy_SetText     ($_hWnd, $_sText = ''[, $_BGRtext = ''[, $_iSize=''[, $_iStyle=''[, $_sFontname=''[, $_bSetOnTop = '']]]]])

; Sets an individual callback interval, opt. stops recalculation of ctrl size.
; _GuiCtrlBusy_SetCBInterval($_hWnd[, $_iInterval=$GCB_U_CALLBACK_INTERVAL[, $_bNoReCalc=False]])

; Stops (or allows) recalculation of control size while text or title is changed.
; _GuiCtrlBusy_StopRecalc  ($_hWnd[, $_bNoReCalc=True])

;Sets title/text/gradient colors.
; _GuiCtrlBusy_SetColors   ($_hWnd, $_BGRtitle = ''[, $_BGRtext = ''[, $_RGBtopleft = ''[, $_RGBbottomright = '']]])

; Sets gradient colors and direction.
; _GuiCtrlBusy_SetGradient ($_hWnd, $_RGBtopleft = ''[, $_RGBbottomright = ''[, $_bRotate = '']])

; Sets color-scheme/gradient-direction/optional ontop.
; _GuiCtrlBusy_SetScheme   ($_hWnd[, $_sScheme = ''[, $_bRotate = ''[, $_bSetOnTop = '']]])

; Gets array of one or all color schemes.
; _GuiCtrlBusy_GetScheme   ($_sScheme='')

; Adds a new color scheme, only valid at runtime.
; _GuiCtrlBusy_AddScheme   ($_sScheme, $_RGBtopleft, $_RGBbottomright, $_BGRtitle, $_BGRtext)

; Moves the control to x/y position, optional set ontop.
; _GuiCtrlBusy_SetPos      ($_hWnd, $_iX = ''[, $_iY = ''[, $_bSetOnTop = '']])

; Sets/Stops the control timeout.
; _GuiCtrlBusy_SetTimeout  ($_hWnd, $_iTimeout, $_iTimeCounter)

; Sets one (default: all) control on top.
; _GuiCtrlBusy_SetOnTop    ([$_hWnd = -1])

; Changes the default values for control creation.
; _GuiCtrlBusy_UserDefaults($_sParamValue[, $_sDelim = '|'])

; Gets a Dummy-ID, that will fired by closing ctrl. Use "GuiCtrlRead(Dummy)" to get Ctrl-hWnd.
; _GuiCtrlBusy_GetClosed   ()
#endregion

Opt('GUIOnEventMode', 1)

Global $gClicked = False

$hGui = GUICreate('Test', 300, 250, 100, 100)
GUISetOnEvent(-3, '_close')
GUICtrlCreateLabel('Mit Schliessen dieses Fensters' & @LF &  @LF & 'werden alle BusyCtrl beendet.', 30, 30)
$bt1 = GUICtrlCreateButton('Intervall Nr 6', 10, 100, 120, 20)
GUICtrlSetOnEvent(-1, '_onButton')
$bt2 = GUICtrlCreateButton('Font/Style Nr 7', 10, 130, 120, 20)
GUICtrlSetOnEvent(-1, '_onButton')
$bt3 = GUICtrlCreateButton('Countdown Nr 6', 10, 160, 120, 20)
GUICtrlSetOnEvent(-1, '_onButton')
$bt4 = GUICtrlCreateButton('New Scheme Nr 7', 10, 190, 120, 20)
GUICtrlSetOnEvent(-1, '_onButton')
GUISetState()


; Icon List: http://help4windows.com/windows_7_shell32_dll.shtml

$hBusy0 = _GuiCtrlBusy_Create()                                                                                                  ; all params as default
$hBusy1 = _GuiCtrlBusy_Create('Nr 1 und der Titel muss jetzt lang sein', 'Titel && Countdown: %C%\nScheme: Clouds', 2, 420,  50, 50, 0)  ; the default color scheme
$hBusy2 = _GuiCtrlBusy_Create('Nr 2', 'Titel && Countdown\nCountdown: %C%\nScheme: Coffee',                         2, 800,  50, 10, -1, 'coffee')
$hBusy3 = _GuiCtrlBusy_Create('Nr 3', 'Titel && Zeit\nMal etwas in die Breite gezogen Scheme: Darkness',            2, 420, 200,  0,  2, 'darkness', True)
$hBusy4 = _GuiCtrlBusy_Create('Der Titel ist mal deutlich länger und länger', 'Nur Titel\nScheme: Silver\nlinks',   0, 800, 200,  0,  0, 'silver', True)

$hBusy5 = _GuiCtrlBusy_Create('Nr 5', 'Titel && Zeit\nScheme: Fire\nrechts\nIntervall 2s',                          1, 100, 400,  0,  2, 'fire')
_GuiCtrlBusy_SetCBInterval($hBusy5, 2000) ; alle 2s aktualisieren
_GuiCtrlBusy_SetIcon($hBusy5, 'moricons.dll', 7)

$hBusy6 = _GuiCtrlBusy_Create('Nr 6', 'Titel && Zeit\nScheme: Sys_invers\nmitte\nIntervall 3s',                     2, 420, 400,  0,  2, 'sys_invers')
_GuiCtrlBusy_SetCBInterval($hBusy6, 3000) ; alle 3s aktualisieren
_GuiCtrlBusy_StopRecalc($hBusy6)

$hBusy7 = _GuiCtrlBusy_Create('Nr 7', 'Titel && Zeit\nScheme: Orange\nund eine Zeile #3\nund auch noch eine Zeile #4',-1, 100, 550,  0,  2, 'orange', True)


; Dummy-Ctrl, das befeuert wird wenn ein Busy-Ctrl geschlossen wird. Das Ctrl-Handle ist mit "GuiCtrlRead(Dummy)" auslesbar
$cClosed = _GuiCtrlBusy_GetClosed()
GUICtrlSetOnEvent(-1, '_onButton')



While 1
    Sleep(50)
WEnd

Func _onButton()
    Switch @GUI_CtrlId
        Case $bt1 ; $_hWnd, $_sTitle='', $_iTimeCounter='', $_iTimeout='', $_BGRtitle='', $_bSetOnTop=''
            _GuiCtrlBusy_SetCBInterval($hBusy6, 1000)
            _GuiCtrlBusy_SetText ($hBusy6, 'Intervall geändert\n1 Sekunde')
        Case $bt2 ; $_hWnd, $_sText='', $_BGRtext='', $_iSize='', $_iStyle='', $_sFontname='', $_bSetOnTop=''
            _GuiCtrlBusy_SetText ($hBusy7, '', '', 16, 1+4, 'Comic Sans MS')
        Case $bt3 ; $_hWnd, $_iTimeout, $_iTimeCounter=1
            If $gClicked Then
                _GuiCtrlBusy_SetTimeout($hBusy6, 0, 2)
                GUICtrlSetData($bt3, 'Countdown Nr 6')
            Else
                _GuiCtrlBusy_SetTimeout($hBusy6, 20, 1)
                GUICtrlSetData($bt3, 'Stop Countdown 6')
            EndIf
            $gClicked = Not $gClicked

        Case $bt4 ; $_hWnd, $_sScheme='', $_bRotate='', $_bSetOnTop=''
            _GuiCtrlBusy_SetScheme($hBusy7, 'forest')
            _GuiCtrlBusy_SetText($hBusy7, 'New Scheme\n"Forest"')
        Case $cClosed
            Switch GUICtrlRead($cClosed)
                Case $hBusy0
                    ConsoleWrite('Busy-Ctrl "$hBusy0" beendet' & @CRLF)
                Case $hBusy1
                    ConsoleWrite('Busy-Ctrl "$hBusy1" beendet' & @CRLF)
                Case $hBusy2
                    ConsoleWrite('Busy-Ctrl "$hBusy2" beendet' & @CRLF)
                Case $hBusy6
                    ConsoleWrite('Busy-Ctrl "$hBusy6" beendet' & @CRLF)
            EndSwitch
    EndSwitch
EndFunc

Func _close()
    Exit
EndFunc

;-- TIME_STAMP   2017-09-18 09:11:27
#include <GUIConstantsEx.au3>
#include <SendMessage.au3>
#include <StaticConstants.au3>
#include <WinAPI.au3>
#include <WinAPIGdi.au3>
#include <WinAPIInternals.au3>
#include <WindowsConstants.au3>

GUICreate('Test')

Global $aIDBtn1 = _DrawGradientButton('Button-1', 0xFFFFFF, 10, 10, 100, 24, 0xFFFFFF, 0x000080, True)
Global $aIDBtn2 = _DrawGradientButton('Button-2', -1, 10, 50, 100, 24, 0xFFFFFF, 0x005FF0)
Global $aIDBtn3 = _DrawGradientButton('Button-3', 0x003380, 10, 90, 100, 24, 0xFFFFFF, 0x00FF00)
Global $aIDBtn4 = _DrawGradientButton('Button-4', 0x003380, 10, 130, 100, 24, 0xFF0000, 0xFFFFFF, True)

GUISetState(@SW_SHOW)

While True
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $aIDBtn1[0]
            ConsoleWrite('Click Button-1' & @CRLF)
            GUICtrlSetData($aIDBtn1[1], GUICtrlRead($aIDBtn1[1]) = 'Button-1' ? 'Button-1_NEU' : 'Button-1')
        Case $aIDBtn2[0]
            ConsoleWrite('Click Button-2' & @CRLF)
            GUICtrlSetData($aIDBtn2[1], GUICtrlRead($aIDBtn2[1]) = 'Button-2' ? 'Button-2_NEU' : 'Button-2')
        Case $aIDBtn3[0]
            ConsoleWrite('Click Button-3' & @CRLF)
            GUICtrlSetData($aIDBtn3[1], GUICtrlRead($aIDBtn3[1]) = 'Button-3' ? 'Button-3_NEU' : 'Button-3')
        Case $aIDBtn4[0]
            ConsoleWrite('Click Button-4' & @CRLF)
            GUICtrlSetData($aIDBtn4[1], GUICtrlRead($aIDBtn4[1]) = 'Button-4' ? 'Button-4_NEU' : 'Button-4')
    EndSwitch
WEnd

; #FUNCTION# ====================================================================================================================
; Name ..........: _DrawGradientButton
; Description ...: Draws a button with gradient color, from top to bottom (default) or from left to right
; Syntax ........: _DrawGradientButton($_sText, $_iTextColor, $_iLeft, $_iTop, $_iWidth, $_iHeight, $_iColTop_Left,
; ...............: $_iColBottom_Right[, $_bHorizontal = False])
; Parameters ....: $_sText              - The button text, horizontal and vertical centered.
; ...............: $_iTextColor         - The button text color. -1 = system color.
; ...............: $_iLeft              - The buttons x position.
; ...............: $_iTop               - The buttons y position.
; ...............: $_iWidth             - The buttons width.
; ...............: $_iHeight            - The buttons height.
; ...............: $_iColTop_Left       - The gradient start color (top or left).
; ...............: $_iColBottom_Right   - The gradient end color (bottom or right).
; ...............: $_bHorizontal        - [optional] "True" draws the gradient from left to right (default=False).
; Return values .: Array with [Button-ID,Label-ID]
; Note ..........: To read or change buttons text, use the Label-ID
; Author ........: BugFix
; ===============================================================================================================================
Func _DrawGradientButton($_sText, $_iTextColor, $_iLeft, $_iTop, $_iWidth, $_iHeight, $_iColTop_Left, $_iColBottom_Right, $_bHorizontal=False)
    Local $idPic = GUICtrlCreatePic('', $_iLeft, $_iTop, $_iWidth, $_iHeight)
    Local $hCtrl = GUICtrlGetHandle($idPic)
    Local $hDC = _WinAPI_GetDC($hCtrl)
    ; zum vertikalen Zentrieren von Text auf Button: Texthöhe messen und Label zeichnen
    Local $iTextHeight = DrawTextCalc($hDC, $_sText, $_iLeft, $_iTop, $_iWidth, $_iHeight)[1]
    Local $idLabel = GUICtrlCreateLabel($_sText, $_iLeft, $_iTop+Ceiling(($_iHeight-$iTextHeight)/2), $_iWidth, $_iHeight, $SS_CENTER)
    GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
    If $_iTextColor <> -1 Then GUICtrlSetColor(-1, $_iTextColor)
    Local $hMemDC = _WinAPI_CreateCompatibleDC($hDC)
    Local $hBitmap = _WinAPI_CreateCompatibleBitmapEx($hDC, $_iWidth, $_iHeight, _WinAPI_SwitchColor(_WinAPI_GetSysColor($COLOR_3DFACE)))
    Local $hMemSv = _WinAPI_SelectObject($hMemDC, $hBitmap)
    Local $aVertex[2][3] = [[0, 0, $_iColTop_Left], [$_iWidth, $_iHeight, $_iColBottom_Right]]
    _WinAPI_GradientFill($hMemDC, $aVertex, 0, -1, $_bHorizontal)
    _WinAPI_ReleaseDC($hCtrl, $hDC)
    _WinAPI_SelectObject($hMemDC, $hMemSv)
    _WinAPI_DeleteDC($hMemDC)
    _SendMessage($hCtrl, $STM_SETIMAGE, 0, $hBitmap)
    Local $hObj = _SendMessage($hCtrl, $STM_GETIMAGE)
    If $hObj <> $hBitmap Then _WinAPI_DeleteObject($hBitmap)
    Local $aID[2] = [$idPic,$idLabel]
    Return $aID
EndFunc  ;==>_DrawGradientButton


; #FUNCTION# ====================================================================================================================
; Name ..........: DrawTextCalc
; Description ...: Calculates the used width and heigth for text in a given context.
; Syntax ........: DrawTextCalc($_hDC, $_sText, $_iLeft, $_iTop, $_iWidth, $_iHeight)
; Parameters ....: $_hDC      Handle of Device Context.
; ...............: $_sText    The text.
; ...............: $_iLeft    Control x position.
; ...............: $_iTop     Control y position.
; ...............: $_iWidth   Control width.
; ...............: $_iHeight  Control heigth.
; Return values .: Array with [width,height]
; Author ........: BugFix
; ===============================================================================================================================
Func DrawTextCalc($_hDC, $_sText, $_iLeft, $_iTop, $_iWidth, $_iHeight)
    Local $iLen = StringLen($_sText)
    Local $tRect = _WinAPI_CreateRectEx($_iLeft, $_iTop, $_iWidth, $_iHeight)
    Local $tText = DllStructCreate("char[" & $iLen & "]")
    DllStructSetData($tText, 1, $_sText)
    Local $aRet = DllCall("user32.dll", "int", "DrawText", "hwnd", $_hDC, "ptr", DllStructGetPtr($tText), "int", $iLen, _
        "ptr", DllStructGetPtr($tRect), "int", BitOr(256,1,16,1024)) ; $DT_NOCLIP,$DT_CENTER,$DT_WORDBREAK,$DT_CALCRECT
    Local $aTextMeasure[2] = [DllStructGetData($tRect, 3)-DllStructGetData($tRect, 1), $aRet[0]] ; [width,height]
    $tRect = 0
    $tText    = 0
    Return $aTextMeasure
EndFunc  ;==>DrawTextCalc