Beiträge von BugFix

#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>
#include <GuiStatusBar.au3>
#include <GuiRichEdit.au3>


Global $g_hRichEdit


Example()


Func Example()
    Local $hGUI, $idInputUrl, $idSetUrl, $hStatus, $sRead
    Local $aParts[3] = [80, 160, -1]


    ; Create GUI
    $hGUI = GUICreate("StatusBar Embed Control", 400, 300)
	$idInputUrl = GUICtrlCreateInput('', 10, 10, 345, 20)
	GUICtrlSendMsg($idInputUrl, 0x1501, 1, 'Url hier eintragen')
	$idSetUrl = GUICtrlCreateButton('Set', 360, 10, 30, 20)


    ; defaults to 1 part, no text
    $hStatus = _GUICtrlStatusBar_Create($hGUI)
    _GUICtrlStatusBar_SetMinHeight($hStatus, 20)


    GUISetState(@SW_SHOW)


    ; Initialize parts
    _GUICtrlStatusBar_SetParts($hStatus, $aParts)
    _GUICtrlStatusBar_SetText($hStatus, "Part 1")
    _GUICtrlStatusBar_SetText($hStatus, "Part 2", 1)


    ; Embed a Richedit
	$g_hRichEdit = _GUICtrlRichEdit_Create($hGui, '', 0, 0, -1, -1)
	_GUICtrlRichEdit_SetParaAlignment($g_hRichEdit, 'c')
	GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")
	_GUICtrlRichEdit_SetEventMask($g_hRichEdit, $ENM_LINK)
	_GUICtrlRichEdit_AutoDetectURL($g_hRichEdit, True)
	_GUICtrlStatusBar_EmbedControl($hStatus, 2, $g_hRichEdit)




    ; Loop until the user exits.
    While 1
		Switch GUIGetMsg()
			Case -3
				ExitLoop
			Case $idSetUrl
				$sRead = GUICtrlRead($idInputUrl)
				If $sRead <> '' Then
					_GUICtrlRichEdit_SetText($g_hRichEdit, $sRead)
				EndIf
		EndSwitch
    WEnd
    GUIDelete()
EndFunc   ;==>Example


Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $wParam
    Local $hWndFrom, $iCode, $tNMHDR, $tEnLink, $iCpMin, $iCpMax, $tMsgFilter
    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iCode = DllStructGetData($tNMHDR, "Code")
    Switch $hWndFrom
        Case $g_hRichEdit
            Select
                Case $iCode = $EN_LINK
                    $tMsgFilter = DllStructCreate($tagMSGFILTER, $lParam)
                    If DllStructGetData($tMsgFilter, "msg") = $WM_LBUTTONUP Then
                        $tEnLink = DllStructCreate($tagENLINK, $lParam)
                        $iCpMin = DllStructGetData($tEnLink, "cpMin")
                        $iCpMax = DllStructGetData($tEnLink, "cpMax")
                        ShellExecute(_GUICtrlRichEdit_GetTextInRange($g_hRichEdit, $iCpMin, $iCpMax))
                    EndIf
            EndSelect
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

While 1
	Switch GUIGetMsg()
		Case -3
			Exit
		Case $idListview
			_AgreeLicense()
		Case ... Button 'Prüfen auf Updates'
			$oUpdates = _CheckAvailableUpdates()
			If @error Then 
				MsgBox(0, 'Error', 'No updates available.')
			Else
				_ShowUpdatesInListview($idListview, $oUpdates)
			EndIf
		Case ... Button 'Updates durchführen'
			$oToUpdate = _CollectUpdates($oUpdates)
			If Not @error Then _RunUpdates($oToUpdate)	
	EndSwitch
WEnd

; === In dein GUI einbauen
; === Listview erstellen, mit Spalte Lizenz-Akzeptieren
Global $idListview = GuiCtrlCreateListView('UPDATE-TITLE|LICENSE-AGREE', ....)
Global $hListview = GUICtrlGetHandle($idListview) ; Handle für UDF


Global $updateSession, $oUpdates, $oToUpdate


; mach einen Button zum 'Prüfen auf Updates':
	$oUpdates = _CheckAvailableUpdates()
	If @error Then 
		MsgBox(0, 'Error', 'No updates available.')
	Else
		_ShowUpdatesInListview($idListview, $oUpdates)
	EndIf
; ein Button für 'Updaten':
	$oToUpdate = _CollectUpdates($oUpdates)
	If Not @error Then _RunUpdates($oToUpdate)
; bei Event Listview:
	_AgreeLicense()


Func _CheckAvailableUpdates()
	$updateSession = ObjCreate("Microsoft.Update.Session")
	$updateSession.ClientApplicationID = "MSDN Sample Script"
	Local $updateSearcher = $updateSession.CreateUpdateSearcher()
	ConsoleWrite('Searching for updates...' & @CRLF)
	Local $searchResult = $updateSearcher.Search("IsInstalled=0 and Type='Software' and IsHidden=0")
	ConsoleWrite('List of applicable items on the machine:' & @CRLF)
	Local $update
	For $i = 0 To $searchResult.Updates.Count-1
		$update = $searchResult.Updates.Item($i)
		ConsoleWrite($i + 1 & "> " & $update.Title & @CRLF)
	Next
	If $searchResult.Updates.Count = 0 Then 
		ConsoleWrite('There are no applicable updates.' & @CRLF)
		Return SetError(1,0,0)
	Else
		Return $searchResult
	EndIf
EndFunc


Func _ShowUpdatesInListview($idLV, $searchResult)
	Local $sItem, $update, $addThisUpdate
	For $i = 0 To $searchResult.Updates.Count-1
		$update = $searchResult.Updates.Item($i)
		If $update.InstallationBehavior.CanRequestUserInput = True Then
			$sItem = $update.Title & '|requires user input'
		Else
			$sItem = $update.Title
			If $update.EulaAccepted = False Then
				$sItem &= '|click to agree'
			Else
				$sItem &= '| --'
			EndIf
		EndIf
		; Item in Listview eintragen
		GUICtrlCreateListViewItem($sItem, $idLV)
	Next
EndFunc


Func _AgreeLicense($searchResult)
	Local $update, $aIndex = _GUICtrlListView_GetSelectedIndices($hListview, True)
	If $aIndex[0] = 0 Then Return
	For $i = 1 To $aIndex[0]
		If _GUICtrlListView_GetItemText($hListview, $aIndex[$i], 1) = 'click to agree' Then
			$update = $searchResult.Updates.Item($i-1)
			If MsgBox(36, 'License Agree', $update.EulaText) = 6 Then  
				_GUICtrlListView_SetItemText($hListview, $aIndex[$i], 'agree', 1)
				_WinAPI_RedrawWindow($hListview)
			EndIf
		EndIf
	Next
EndFunc


Func _CollectUpdates($searchResult)
	Local $updatesToDownload = ObjCreate("Microsoft.Update.UpdateColl")
	Local $sText, $iCount = _GUICtrlListView_GetItemCount($hListview)
	If $iCount = 0 Then Return
	For $i = 0 To $iCount -1
		$sText = _GUICtrlListView_GetItemText($hListview, $i, 1)
		If $sText = 'agree' Or $sText = ' --' Then $updatesToDownload.Add($searchResult.Updates.Item($i))
	Next	
	If $updatesToDownload.Count = 0 Then 
		Return SetError(1,0,0)
	Else
		Return $updatesToDownload
	EndIf
EndFunc




Func _RunUpdates($updatesToDownload)
	Local $downloader = $updateSession.CreateUpdateDownloader()
	$downloader.Updates = $updatesToDownload
	$downloader.Download()


	Local $updatesToInstall = ObjCreate("Microsoft.Update.UpdateColl")
	Local $update, $rebootMayBeRequired = false
;~ 	ConsoleWrite("Successfully downloaded updates:" & @CRLF)
	For $i = 0 To $searchResult.Updates.Count-1
		$update = $searchResult.Updates.Item($i)
		If $update.IsDownloaded = true Then
;~ 			ConsoleWrite($i + 1 & "> " & $update.Title & @CRLF)
			$updatesToInstall.Add($update)
			If $update.InstallationBehavior.RebootBehavior > 0 Then $rebootMayBeRequired = true
		EndIf
	Next


	If $updatesToInstall.Count = 0 Then Return MsgBox(48, 'Update', "No updates were successfully downloaded.")
	If $rebootMayBeRequired = true Then MsgBox(64,"Reboot", "Minimum one update requires a reboot.")


	If MsgBox(262180,"Install","Would you like to install updates now?") = 6 Then ; 'Ja'
;~ 		ConsoleWrite("Installing updates..." & @CRLF)
		Local $installer = $updateSession.CreateUpdateInstaller()
		$installer.Updates = $updatesToInstall
		$installationResult = $installer.Install()
		; Output results of install ---> würde ich in ein Log schreiben
		ConsoleWrite("Installation Result: " & $installationResult.ResultCode & @CRLF)
		ConsoleWrite("Reboot Required: " & $installationResult.RebootRequired & @CRLF)
		ConsoleWrite("Listing of updates installed and individual installation results:" & @CRLF)
		For $i = 0 to $updatesToInstall.Count - 1
			ConsoleWrite($i + 1 & "> " & $updatesToInstall.Item($i).Title & ": " & $installationResult.GetUpdateResult($i).ResultCode & @CRLF)
		Next
	EndIf
EndFunc

$updateSession = ObjCreate("Microsoft.Update.Session")
$updateSession.ClientApplicationID = "MSDN Sample Script"


$updateSearcher = $updateSession.CreateUpdateSearcher()


ConsoleWrite('Searching for updates...' & @CRLF)


$searchResult = $updateSearcher.Search("IsInstalled=0 and Type='Software' and IsHidden=0")


ConsoleWrite('List of applicable items on the machine:' & @CRLF) 


For $i = 0 To $searchResult.Updates.Count-1
	$update = $searchResult.Updates.Item($i)
	ConsoleWrite($i + 1 & "> " & $update.Title & @CRLF) 
Next


If $searchResult.Updates.Count = 0 Then Exit ConsoleWrite('There are no applicable updates.' & @CRLF)


ConsoleWrite('Creating collection of updates to download:' & @CRLF)


$updatesToDownload = ObjCreate("Microsoft.Update.UpdateColl")


For $i = 0 To $searchResult.Updates.Count-1
	$update = $searchResult.Updates.Item($i)
	$addThisUpdate = False
	If $update.InstallationBehavior.CanRequestUserInput = True Then
		ConsoleWrite($i + 1 & "> skipping: " & $update.Title & " because it requires user input" & @CRLF) 
	Else
		If $update.EulaAccepted = False Then
			ConsoleWrite($i + 1 & "> note: " & $update.Title & " has a license agreement that must be accepted:" & @CRLF) 
			ConsoleWrite($update.EulaText & @CRLF) 
			If MsgBox(262180,"License","Do you accept this license agreement?") = 6 Then ; 'Ja'
				$update.AcceptEula()
				$addThisUpdate = true
			Else
				ConsoleWrite($i + 1 & "> skipping: " & $update.Title & " because the license agreement was declined" & @CRLF) 
			EndIf
		Else
			$addThisUpdate = true
		EndIf
	EndIf
	If $addThisUpdate = true Then
		ConsoleWrite($i + 1 & "> adding: " & $update.Title & @CRLF) 
		$updatesToDownload.Add($update)
	EndIf
Next


If $updatesToDownload.Count = 0 Then Exit ConsoleWrite("All applicable updates were skipped." & @CRLF) 


ConsoleWrite("Downloading updates..." & @CRLF) 


$downloader = $updateSession.CreateUpdateDownloader()
$downloader.Updates = $updatesToDownload
$downloader.Download()


$updatesToInstall = ObjCreate("Microsoft.Update.UpdateColl")


$rebootMayBeRequired = false


ConsoleWrite("Successfully downloaded updates:" & @CRLF) 


For $i = 0 To $searchResult.Updates.Count-1
	$update = $searchResult.Updates.Item($i)
	If $update.IsDownloaded = true Then
		ConsoleWrite($i + 1 & "> " & $update.Title & @CRLF) 
		$updatesToInstall.Add($update)
		If $update.InstallationBehavior.RebootBehavior > 0 Then $rebootMayBeRequired = true
	EndIf
Next


If $updatesToInstall.Count = 0 Then Exit ConsoleWrite("No updates were successfully downloaded." & @CRLF) 


If $rebootMayBeRequired = true Then ConsoleWrite("These updates may require a reboot." & @CRLF)


If MsgBox(262180,"Install","Would you like to install updates now?") = 6 Then ; 'Ja'
	ConsoleWrite("Installing updates..." & @CRLF) 
	$installer = $updateSession.CreateUpdateInstaller()
	$installer.Updates = $updatesToInstall
	$installationResult = $installer.Install()
	; Output results of install
	ConsoleWrite("Installation Result: " & $installationResult.ResultCode & @CRLF) 
	ConsoleWrite("Reboot Required: " & $installationResult.RebootRequired & @CRLF) 
	ConsoleWrite("Listing of updates installed and individual installation results:" & @CRLF)
	For $i = 0 to $updatesToInstall.Count - 1
		ConsoleWrite($i + 1 & "> " & $updatesToInstall.Item($i).Title & ": " & $installationResult.GetUpdateResult($i).ResultCode & @CRLF)
	Next
EndIf

Global $GUI, $aInput[2] = [1], $btAdd


$GUI = GUICreate('Test', 400, 50)
$aInput[1] = GUICtrlCreateInput('', 10, 10, 300, 21)
GUICtrlSetResizing(-1, 802) ; $GUI_DOCKALL
$btAdd = GUICtrlCreateButton('Add Input', 320, 10, 70, 21)
GUICtrlSetResizing(-1, 802) ; $GUI_DOCKALL
GUISetState()


While 1
	Switch GUIGetMsg()
		Case -3
			Exit
		Case $btAdd
			_NewCtrl()
	EndSwitch
WEnd


Func _NewCtrl()
	Local $iDiff = 31     ; == Abstand + Höhe ==> 10 + 21
	Local Static $iY = 10 ; == Startwert vom ersten Ctrl
	$iY += $iDiff
	$aInput[0] += 1
	ReDim $aInput[$aInput[0]+1]
	Local $aWin = WinGetPos($GUI)
	WinMove($GUI, '', $aWin[0], $aWin[1], $aWin[2], $aWin[3] + 31)
	$aInput[$aInput[0]] = GUICtrlCreateInput('', 10, $iY, 300, 21)
	GUICtrlSetResizing(-1, 802) ; $GUI_DOCKALL
EndFunc

; ======================================================================== INSTALLATIONSORDNER =====
; dieser Ordner wird als Unterordner im aktuellen Pfad erstellt und das Skript dorthin kopiert
Global $sFolderInstall = '__Mein_Installationsordner__'
; ==================================================================================================


; ======================================================================== PRÜFT AUF PARAMETER =====
; wenn Parameter: das kopierte Skript wird im neuen Ordner gestartet und das Original gelöscht
_CheckCmdLine()
; ==================================================================================================




; ======================================================================== HAUPTSKRIPT =============
MsgBox(0, 'Skript-Kopie', 'Ich bin gestartet')


; ==================================================================================================




#Region - functions
; ==================================================================================================
Func _CheckCmdLine()
	If $CmdLine[0] Then
		Local $aCmd = StringRegExp($CmdLineRaw, "'(\w+)=([^']+)", 3)
		Local $iPID, $sPathCaller
		For $i = 0 To UBound($aCmd) -2 Step 2
			Switch $aCmd[$i]
				Case 'pid'
					$iPID = $aCmd[$i+1]
				Case 'caller'
					$sPathCaller = $aCmd[$i+1]
			EndSwitch
		Next
		; Aufruferskript beenden, wenn es noch laufen sollte
		If ProcessExists($iPID) Then ProcessWaitClose($iPID)
		; Aufruferskript löschen
		FileDelete($sPathCaller)
	Else
		_Check2Move($sFolderInstall)
	EndIf
EndFunc  ;==>_CheckCmdLine


Func _Check2Move($sFolderTarget)
	; $sFolderTarget = Ordner in dem das Programm sein sollte


	; Ordner in dem das Programm ist
	Local $sFolderCurrent = _GetFullPathNameDetail('.', 'folder')


	; Ordnernamen vergleichen --> wenn ungleich: Zielordner als Unterordner des aktuellen Ordners erstellen,
	; Skript dorthin kopieren, starten und das aufrufende Skript beenden und löschen
	If $sFolderCurrent <> $sFolderTarget Then
		Local $sFullTarget = _GetFullPathNameDetail('.') & '\' & $sFolderTarget
		; Ordner erstellen
		If Not FileExists($sFullTarget) Then DirCreate($sFullTarget)
		; Skript kopieren
		Local $sExe = StringTrimLeft(@ScriptFullPath, StringInStr(@ScriptFullPath, '\', 0, -1))
		FileCopy(@ScriptFullPath, $sFullTarget & '\' & $sExe)
		Local $iPID = (ProcessList($sExe))[1][1]
		; kopiertes Skript starten (eigene PID,Pfad übergeben)
		Local $sParam = StringFormat(" 'pid=%s' 'caller=%s'", $iPID, @ScriptFullPath)
		ShellExecute($sFullTarget & '\' & $sExe, $sParam)
		; Skript beenden
		Exit
	EndIf
EndFunc  ;==>_Check2Move


Func _GetFullPathNameDetail($_sFilePath, $_sSelect='full')
	Local $aRet = DllCall('kernel32.dll', 'dword', 'GetFullPathNameW', 'wstr', $_sFilePath, 'dword', 4096, 'wstr', '', 'ptr', 0)
	If @error Or Not $aRet[0] Then Return SetError(@error, @extended, '')
	Switch $_sSelect
		Case 'full'
			Return $aRet[3]
		Case 'drive'
			Return StringLeft($aRet[3], 2)
		Case 'folder'
			If StringLen($aRet[3]) > 3 Then
				Return StringTrimLeft($aRet[3], StringInStr($aRet[3], '\', 0, -1))
			Else
				Return ''
			EndIf
	EndSwitch
EndFunc  ;==>_GetFullPathNameDetail
; ==================================================================================================
#endregion

$sText = 'class="adress">Rathausplatz 5<br/>90403 Nürnberg<br/><a href=" ' & @CRLF & _
'Kontakt</h3><p class="adress">Äußere Bayreuther Str. 121<br/>90409 Nürnberg<br/><a href="' & @CRLF & _
'</span></p><h3>Kontakt</h3><p class="adress">Wallensteinstraße 28<br/>90439 Nürnberg<br/><a href="' & @CRLF & _
'</span></p><h3>Kontakt</h3><p class="adress">Glogauer Str. 30 - 38<br/>90473 Nürnberg<br/><a href="'


$sPatt = '(?s)class="adress">([^<]+)<br/>(\d{5})\s([^<]+)'
$aMatch = StringRegExp($sText, $sPatt, 4)


Local $aResult[UBound($aMatch)][3]
For $i = 0 To UBound($aMatch) -1
	$aResult[$i][0] = ($aMatch[$i])[1]
	$aResult[$i][1] = ($aMatch[$i])[2]
	$aResult[$i][2] = ($aMatch[$i])[3]
Next


_ArrayDisplay($aResult)