Beiträge von BugFix

**BugFix**

Zitat von LaMagnos

Ich möchte das ein timer die Zeit hochzählt bis ich oft genug auf ein Knopf gedrückt habe.
Außerdem das angezeigt wird wie oft ich den Knopf bereits gedrückt habe.

Ich verstehe nur Bahnhof...
Stell bitte ein zumindest rudimentär funktionsfähiges Skript ein, das erklärt, was du vorhast. Aus deiner Beschreibung wird das nicht ersichtlich.
Und Sleep unterbricht dein Programm, ist also für einen Timer ungeeignet, dazu gibt es TimerInit/TimerDiff.
Eine Schleife innerhalb einer Funktion ist nur dann sinnvoll, wenn dort eine definierte Anzahl von Ereignissen abgearbeitet wird. Da in deiner Schleife aber nichts passiert ausser: <Programm Stop> - <Zähler hoch> - <Programm Stop> - <Zähler hoch> ... kannst du auch keine anderen Ereignisse berücksichtigen.

**BugFix**

Zitat von Xorianator

Achso: Wenn $type = 1 ist, wird nicht negiert, wenn $type = 0 ist, dann wird negiert.

Das würde ich eigentlich genau entgegengesetzt ausführen, ist schlüssiger: '0'-kein NOT vorhanden, '1'-NOT vorhanden.

**BugFix**

Mit FileGetShortName bzw. FileGetLongName kannst du jeweils umwandeln und hast wieder den vollen Überblick.

**BugFix**

Es gibt noch einiges mehr zu ersetzen, gerade bei dir in der Gegend sind doch auch die exotischen Buchstaben möglich

Code

Ersetzen:
- "SCH"       = "Y"
- "ß"         = "SS"
- "Ä,Æ"       = "AE"
- "Ö,Œ"       = "OE"
- "Ü"         = "UE"
Bei Zeichen, die ein Diakritikum wie Akut, Gravis, Zirkumflex, Tilde, Kroužek, Cedille,
Trema (außer bei deutschen Umlauten), Schrägstrich oder Hatschek enthalten,
wird dieses Zeichen durch den Basisbuchstaben ersetzt.
- "À,Á,Â,Ã,Å" = "A"
- "Ç"         = "C"
- "È,É,Ê,Ë"   = "E"
- "Ì,Í,Î,Ï"   = "I"
- "Ð"         = "D"
- "Ñ"         = "N"
- "Ò,Ó,Ô"     = "O"
- "Ù,Ú,Û"     = "U"
- "Ý"         = "Y"

Alles anzeigen

EDIT:
Für die "Sonderbuchstaben" ist noch einiges zu beachten:
- die nativen String-Funktionen können damit nicht immer korrekt umgehen, da sie diese als Kombination zweier Zeichen sehen (Problem bei StringSplit, StringLen, StringMid)
- StringUpper() ist nicht anwendbar (gilt ebenso für deutsche Umlaute)

Ich habe deshalb mal eine Funktion erstellt die das beim Ersetzen berücksichtigt. Einfach mit Name oder Vorname aufrufen (oder auch beides zusammen, wenn keine Namenszusätze oder Bindenamen vorhanden sind):

EDIT_2:
Habe nun noch eine kpl. Umsetzung erstellt, inkl. Prüfziffer:

AutoIt

$sFullName = 'Thomas Schmidt'
$sGebDat = '17.11.1959'
;~ $sFullName = 'Hans-Peter von Müller zu Oberhausen'
;~ $sGebDat = '1.1.1978'




ConsoleWrite( _Get_eTIN($sFullName, $sGebDat) & @CRLF)






Func _Get_eTIN($_sFullName, $_sGebDat)
	Local $aRet = _SplitFullName($_sFullName)
	Local $Name = _ConvertName( _ReplaceInName( $aRet[1] ) )
	Local $Vname = _ConvertName( _ReplaceInName( $aRet[0] ) )
	Local $Geb = _ConvertDate( $_sGebDat )
	Local $sConvert = StringFormat('%s%s%s', $Name, $Vname, $Geb)
	Local $Check = _GetCheckValue( $sConvert )
	Return $sConvert & $Check
EndFunc


Func _SplitFullName($_sName)
	Local Static $a[] = [' von ',' van ',' v. ',' auf ',' dos ',' des ',' del ',' da ',' de ',' do ',' di ',' d ',' la ',' le ',' lo ']
	Local $iSplitPos, $iPos = StringInStr($_sName, ' zu ')
	If $iPos <> 0 Then ; 'zu' enthalten
		$iSplitPos = StringInStr($_sName, ' ', 0, -1, $iPos-1)
	Else
		For $i = 0 To UBound($a) -1
			$iPos = StringInStr($_sName, $a[$i])
			If $iPos Then ExitLoop
		Next
		If $iPos Then
			$iSplitPos = $iPos
		Else
			$iSplitPos = StringInStr($_sName, ' ', 0, -1)
		EndIf
	EndIf
	Local $aRet[] = [StringLeft($_sName, $iSplitPos-1), StringTrimLeft($_sName, $iSplitPos)]
	Return $aRet  ; [VName,Name (mit evtl. Zusatz voran)]
EndFunc


Func _ReplaceInName($sName)
	Local Static $aReplace[58][2] = [['SCH','Y'],['ß','SS'],['ä','AE'],['Ä','AE'],['æ','AE'], _
	['Æ','AE'],['ö','OE'],['Ö','OE'],['œ','OE'],['Œ','OE'],['ü','UE'],['Ü','UE'],['à','A'], _
	['á','A'],['â','A'],['ã','A'],['å','A'],['À','A'],['Á','A'],['Â','A'],['Ã','A'],['Å','A'], _
	['ç','C'],['Ç','C'],['è','E'],['é','E'],['ê','E'],['ë','E'],['È','E'],['É','E'],['Ê','E'], _
	['Ë','E'],['ì','I'],['í','I'],['î','I'],['ï','I'],['Ì','I'],['Í','I'],['Î','I'],['Ï','I'], _
	['ð','D'],['Ð','D'],['ñ','N'],['Ñ','N'],['ò','O'],['ó','O'],['ô','O'],['Ò','O'],['Ó','O'], _
	['Ô','O'],['ù','U'],['ú','U'],['û','U'],['Ù','U'],['Ú','U'],['Û','U'],['ý','Y'],['Ý','Y']]
	$sName = StringUpper($sName)
	For $i = 0 To UBound($aReplace) -1
		$sName = StringReplace($sName, $aReplace[$i][0], $aReplace[$i][1])
	Next
	Return $sName
EndFunc


Func _ConvertName($sName)
	Local Static $aDel[] = ['ZU ','VON ','VAN ','V. ','AUF ','DOS ','DES ','DEL ', _
	'DA ','DE ','DO ','DI ','D ','LA ','LE ','LO ','-',' ']
	Local $sReturn = ''
	; Zusätze, Leerzeichen, Bindestriche löschen
	For $i = 0 To UBound($aDel) -1
		$sName = StringReplace($sName, $aDel[$i], '')
	Next
	; ersten 4 Konsonanten suchen
	Local $aName = StringSplit($sName, ''), $iCons = 0
	For $i = 1 To $aName[0]
		If $iCons = 4 Then ExitLoop
		If Not StringInStr('AEIOU', $aName[$i]) Then
			$iCons += 1
			$sReturn &= $aName[$i]
		EndIf
	Next
	; wenn zu kurz mit Vokalen (vom letzten Vokal beginnend) auffüllen
	If StringLen($sReturn) < 4 Then
		For $i = $aName[0] To 1 Step -1
			If StringInStr('AEIOU', $aName[$i]) Then
				$sReturn &= $aName[$i]
				If StringLen($sReturn) = 4 Then ExitLoop
			EndIf
		Next
	EndIf
	; wenn noch zu kurz mit 'X' auffüllen
	While StringLen($sReturn) < 4
		$sReturn &= 'X'
	WEnd
	Return $sReturn
EndFunc


Func _ConvertDate($sDate)
	Local $aDate = StringRegExp($sDate, '(\d{1,2})\.(\d{1,2})\.(\d{4})', 3)
	Local $sYY = StringRight(String($aDate[2]), 2)
	Local $sM = Chr(Int($aDate[1])+64)
	Local $sDD = StringFormat('%02d', $aDate[0])
	Return StringFormat('%s%s%s', $sYY, $sM, $sDD)
EndFunc


Func _GetCheckValue($sConverted)
	Local Static $aValue[][3] = [[0,1,'A'],[0,1,'0'],[1,0,'B'],[1,0,'1'],[2,5,'C'],[2,5,'2'], _
	[3,7,'D'],[3,7,'3'],[4,9,'E'],[4,9,'4'],[5,13,'F'],[5,13,'5'],[6,15,'G'],[6,15,'6'],[7,17,'H'], _
	[7,17,'7'],[8,19,'I'],[8,19,'8'],[9,21,'J'],[9,21,'9'],[10,2,'K'],[11,4,'L'],[12,18,'M'], _
	[13,20,'N'],[14,11,'O'],[15,3,'P'],[16,6,'Q'],[17,8,'R'],[18,12,'S'],[19,14,'T'],[20,16,'U'], _
	[21,10,'V'],[22,22,'W'],[23,23,'X'],[24,24,'Y'],[25,25,'Z']]
	Local $iSum = 0
	For $i = 1 To StringLen($sConverted)
		For $j = 0 To UBound($aValue) -1
			If $aValue[$j][2] = StringMid($sConverted, $i, 1) Then
				$iSum += $aValue[$j][Mod($i,2)]
				ExitLoop
			EndIf
		Next
	Next
	Return Chr(Mod($iSum,26)+65)
EndFunc

Alles anzeigen

**BugFix**

Nebenbei: Wenn du crosspostest, ist es üblich auf den anderen Post zu verweisen.

**BugFix**

Lass dir mit dem AutoIt Window Info Tool die Infos zum Fenster geben. Titel reicht oft nicht, weil der bei verschiedenen Instanzen des Fensters identisch ist. Über zusätzlichen Text des Fensters oder besser über CLASS und INSTANCE kannst du das Fenster i.d.R. eindeutig identifizieren und auch über die Win-Funktionen ansprechen.
Schau dir in der Hilfe unter <Using AutoIt> die Kapitel "Window Titles and Text" mal genauer an.

**BugFix**

Batch ist für mich fremdes Land, k.A., wie die Daten aufnehmen. Aber wenn die Exe was zurückgeben soll, ist. m.E. erforderlich, dass sie als CUI kompiliert wird.

**BugFix**

Also der Bezug zu Dropbox hat sich dann doch als Irrweg erwiesen, da die Symptome danach weg waren.

Da dasselbe Problem wieder auftrat habe ich weiter gesucht und bin auch fündig geworden, indem ich zeitgleich mit dem Versuch das Kontextmenü auf Dateien im Explorer zu öffnen, auf neue Ereignisse in der Ereignisanzeige geschaut habe. Und tada... hier ist der Bösewicht, ein Dienst, der sich nicht starten lässt:

bluetooth_fail.JPG

Aber was kann man dagegen tun? Ich habe den Dienst erst mal deaktiviert um die Funktionalität des Kontextmenüs zurück zu haben. Aber ohne den Dienst kann ich natürlich keine BT-Verbindungen herstellen - also: wie repariere ich das? Muss die devmonsrv.exe neu installiert werden?

**BugFix**

Mist, kaum probiert man sein neues Stealth-Mobil aus, kommt einer mit superscharfen Augen daher und versaut einem die Freude.
In Zukunft kann ich wohl doch nur noch übers Meer fliegen. Naja, man lernt nie aus.

**BugFix**

Zitat von NewProgger

die Var 1-21 stammen aus abfragen ob Checkboxen gechecked sind oder nicht.

Für dieses Ergebnis reicht ein einziger Parameter. Du kannst den Checkboxen Werte zuordnen (2-er Potenzen), dadurch ist jeder Wert eineindeutig in einer Gesamtsumme identifizierbar. Hier mal ein Bsp. aus meinen Musterskripten, kannst es dann anpassen:

AutoIt

; Muster Checkbox-Bearbeitung
; Ziel: einfache Abfrage, welche CB aktiviert sind


#include <GUIConstants.au3>
Opt('GUIOnEventMode', 1)
Opt("MustDeclareVars", 1)
Global $bCheckAll, $bUnCheckAll, $GUI, $i, $str
Global $arCB[20][2]             ; Array für Handle und Dual-Wert der CB
For $i = 0 To UBound($arCB) -1
	$arCB[$i][1] = 2^$i         ; Zuweisung eindeutiger Wert
Next
Global $Checked = 0             ; Variable nimmt Status ALLER Checkboxen in einem Wert auf,
                                ; Startstatus für alle: UNCHECKED
Global $w = 500, $h = 20*30+40, $l = (@DesktopWidth-$w)/2, $t = (@DesktopHeight-$h)/2
Global $top = -10
$GUI = GUICreate('Test Checkbox', $w, $h, $l, $t)
GUISetOnEvent($GUI_EVENT_CLOSE, '_Ende')
For $i = 0 To UBound($arCB) -1
	$top += 30
	$arCB[$i][0] = GUICtrlCreateCheckbox('CheckBox_' & $i+1, 40, $top, 120)
	GUICtrlSetOnEvent(-1, '_ClickCB')
Next
$bCheckAll = GUICtrlCreateButton('Alle markieren', 250, 20, 150, 21)
GUICtrlSetOnEvent(-1, '_CheckAll')
$bUnCheckAll = GUICtrlCreateButton('Markierung aufheben', 250, 50, 150, 21)
GUICtrlSetOnEvent(-1, '_UnCheckAll')
GUISetState()


While 1
	Sleep(100)
WEnd


Func _Ende()
	Exit
EndFunc


Func _ClickCB()
	For $i = 0 To UBound($arCB) -1
		If $arCB[$i][0] = @GUI_CtrlId Then
			$Checked = BitXOR($Checked, $arCB[$i][1])
			_ReadCB()
			ExitLoop
		EndIf
	Next
EndFunc


Func _CheckAll()
	For $i = 0 To UBound($arCB) -1
		If Not BitAND($Checked, $arCB[$i][1]) Then
;~ 			GUICtrlSetState($arCB[$i][0], $GUI_CHECKED)
			GUICtrlSetState($arCB[$i][0], BitOR($GUI_CHECKED, $GUI_DISABLE)) ; markieren und disablen
			$Checked = BitXOR($Checked, $arCB[$i][1])
		EndIf
	Next
	_ReadCB()
EndFunc


Func _UnCheckAll()
	For $i = 0 To UBound($arCB) -1
		If BitAND($Checked, $arCB[$i][1]) Then
;~ 			GUICtrlSetState($arCB[$i][0], $GUI_UNCHECKED)
			GUICtrlSetState($arCB[$i][0], BitOR($GUI_UNCHECKED, $GUI_ENABLE)) ; Markierung aufheben und enablen
			$Checked = BitXOR($Checked, $arCB[$i][1])
		EndIf
	Next
	_ReadCB()
EndFunc


Func _ReadCB() ; Fkt. dient nur zur Ausgabe, welche CB markiert sind
	Local $str = 'Markiert:  '
	For $i = 0 To UBound($arCB) -1
		If BitAND($Checked, $arCB[$i][1]) Then $str &= $i+1 & ', '
	Next
	WinSetTitle($GUI, '', StringTrimRight($str, 2))
EndFunc

Alles anzeigen

**BugFix**

Zitat von Schumi

Kann man beim Entpacken die Dateinamen (also die entpackt werden sollen) auslesen.

Können kann man sicher :D.
Das ZIP-Dateiformat hat einen strukturierten Aufbau und enthält ein "Inhaltsverzeichnis".
Zitat:
"Nach der letzten Datei steht ein weiteres Kennzeichen, das aus den vier Byte "PK12" als CentralFileHeaderSign besteht.
Dieses leitet den Abschnitt der zentralen Dateikennungen ein. Hier stehen in dichter Folge im Sinne eines Directory noch einmal alle im Archiv enthaltenen Dateinamen nebst beschreibenden Datenangaben."
Die ZIP binär einlesen, den Einstiegspunkt für die Auflistung suchen und auslesen.
Kannst dich gerne dran versuchen, ich habe vorerst nicht die Muße dazu.

**BugFix**

Habe die Ursache gefunden:
Im Kontextmenü gab es einen Eintrag für die Dropbox unter Nutzung der DropboxExt64.34.dll. Diese wurde in etwa zur gleichen Zeit aktualisiert, als ich die M$ Updates durchgeführt habe. Als ich danach das Problem bemerkte, kam mir als Ursache der Patchday in den Sinn.
Ausnahmsweise ist M$ aber hieran nicht schuld. Ich habe den Eintrag für Dropbox deaktiviert und nun ist wieder alles paletti.

**BugFix**

Daten werden mit GUICtrlSetData eingetragen und dann funktioniert es genau, wie vorab beschrieben, mit dem DataSeparator (Standard ist die Pipe).

**BugFix**

Das dürfte bei mir dann nicht zutreffen - habe nur SSD.

**BugFix**

Neue Erkenntnis: Es ist nur das Kontextmenü für Dateien betroffen.
Bei Ordnern erscheint es auch sofort.

Ich werde mal nach und nach alle Einträge deaktivieren - einer muss ja "Schuld" haben

**BugFix**

Hi,
seit den letzten Updates habe ich folgendes Problem:
- Windows Explorer --> bei Rechtsklick dauert es bis zu 20 s bevor das Kontextmenü erscheint

Mein System: Win7 pro x64

Hat jemand auch dieses Problem oder bin ich der einzig "Glückliche"?

**BugFix**

Zitat von Bitnugger

und gibt ein 2D-Array zurück...

Oops - da war ich einen Moment verpeilt. Auch wenn ArrayDisplay ein $a[n][1] ebenso darstellt wie ein $a[n] ist es halt doch nicht dasselbe.
Habe es im Code korrigiert.

**BugFix**

Ich habe mir jetzt eine eigene Routine erstellt.
Grundprinzip:
- wenn am Itemanfang Zahlen sind (optional auch in Klammern, also "(1) Bla" oder "[2] Blub") werden diese mit Vornullen versehen
- dazu werden die Einträge in einem temporären Array gespeichert
- der Index im Original-Array wird ebenfalls im Temp-Array gespeichert
- das Temparray wird nun anhand des mit Vornullen ergänzten und dadurch als String sortierbarem Array, in der Spalte Name sortiert
- die Original-Item werden jetzt aus dem Originalarray an die umgeordneten zugehörigen Indexpositionen geschrieben
- das Originalarray wird mit dem sortierten ersetzt

AutoIt

#include <Array.au3>


Global $_gSNUM
Local $a[] = ['(1) Bla','(10) Blub','(11) Ccc','(12) Ddd','(2) Haa','(3) Hoo','(4) Muh','(5) Wuff','(6) Brr','(7) Klirr','(8) Knarr','(9) Uff','Hallo','Welt','AutoIt']
;~ Local $a[] = ['1 Bla','10 Blub','11 Ccc','12 Ddd','2 Haa','3 Hoo','4 Muh','5 Wuff','6 Brr','7 Klirr','8 Knarr','9 Uff','Hallo','Welt','AutoIt']
_ArrayDisplay($a)


_ArraySortLikeExplorer($a)
_ArrayDisplay($a)




Func _ArraySortLikeExplorer(ByRef $_aArray)
	Local $aNameIndexed[UBound($_aArray)][4]
	Local $iDigitMax = 0, $sZero = '0000000000'
	For $i = 0 To UBound($aNameIndexed) -1
		$aNameIndexed[$i][0] = $i                                              ; Index im Original-Array
		$aNameIndexed[$i][1] = $_aArray[$i]                                    ; Originalname
		$aNameIndexed[$i][2] = _GetStrDigits($_aArray[$i])                     ; String mit Zahl (Umfassung der Zahl durch z.B. Klammern mgl.), wenn vorhanden
		$aNameIndexed[$i][3] = _GetCountDigits($aNameIndexed[$i][2])           ; Länge vorangestellter Zahl (Umfassung der Zahl durch z.B. Klammern mgl.)
		If $aNameIndexed[$i][3] > $iDigitMax Then $iDigitMax = $aNameIndexed[$i][3]
	Next
	For $i = 0 To UBound($aNameIndexed) -1                                     ; Zahlen mit Vornullen versehen in Item-Namen, somit sortierbar
		If $aNameIndexed[$i][3] = 0 Then ContinueLoop
		$_gSNUM = StringLeft($sZero, ($iDigitMax-$aNameIndexed[$i][3]))
		_StringRegExpReplace_Callback($aNameIndexed[$i][1], '^([\D]?)(\d+)([\D]?)', '_MyRegExCallback("$1", "$2", "$3")')
	Next
	_ArraySort($aNameIndexed, 0, 0, 0, 1)                                      ; Sortieren nach geändertem Item-Namen
	; Spalte 0 enthält jetzt die Indizes in der erforderlichen Reihenfolge der Sortierung
	; Jetzt in neuem Array Originalnamen in der neuen Reihenfolge eintragen
	Local $aTmp[UBound($_aArray)]
	For $i = 0 To UBound($aTmp) -1
		$aTmp[$i] = $_aArray[$aNameIndexed[$i][0]]
	Next
	$_aArray = $aTmp
EndFunc


Func _MyRegExCallback($_s1, $_s2, $_s3)
	Return $_s1 & $_gSNUM & $_s2 & $_s3
EndFunc


Func _GetStrDigits($_sItem)
	Local $sDigit = ''
	Local $aRet = StringRegExp($_sItem, '^([\D]?\d+[\D]?)', 1)
	If IsArray($aRet) Then $sDigit = $aRet[0]
	Return $sDigit
EndFunc


Func _GetCountDigits($_sDigit)
	StringRegExpReplace($_sDigit, '(\d)', '$1')
	Return @extended
EndFunc


; #FUNCTION# ====================================================================================================================
; Name ..........: _StringRegExpReplace_Callback
; Description ...: Replaces ByRef all matches in a string by manipulation of the matches in a callback function
; Parameters ....: $sString    String to manipulate
; ...............: $sPattern   RegExp pattern for the match
; ...............: $sCallback  Callback function as string, i.e. "MyCallback('$1')" -- '$1' represents the match
; .....optional..: $sBefore    String to insert before the manipulated match
; .....optional..: $sAfter     String to insert after the manipulated match
; Return values .: Success     1
; ...............: Failure     0  set error = 1
; Author ........: Taz77
; ===============================================================================================================================
Func _StringRegExpReplace_Callback(ByRef $sString, $sPattern, $sCallback, $sBefore = '', $sAfter = '')
	ConsoleWrite("'" & StringRegExpReplace(StringReplace($sString, "'", Chr(26), 0, 2), $sPattern, $sBefore & "'&" & $sCallback & "&'" & $sAfter) & "'" & @CRLF)
	$sString = Execute("'" & StringRegExpReplace(StringReplace($sString, "'", Chr(26), 0, 2), $sPattern, $sBefore & "'&" & $sCallback & "&'" & $sAfter) & "'")
	If @error Then
		ConsoleWrite('_StringRegExpReplace_Callback error! Pattern: "' & $sPattern & '", Callback: "' & $sCallback & '"' & @LF)
		Return SetError(1,0,0)
	EndIf
	$sString = StringReplace($sString, Chr(26), "'", 0, 2)
	Return 1
EndFunc  ;==>_StringRegExpReplace_Callback

Alles anzeigen

EDIT:
Das berücksichtigt jetzt nicht, wenn die Zahlen nicht am Stringanfang auftauchen. Da dann meist die Sortierung etwas untergeordnet ist, sehe ich das aber als unproblematisch. Für meine Zwecke reicht die Prüfung auf Zahlen am Anfang aus.

EDIT_2:
Sehe jetzt erst Oscars Beitrag, mal diese UDF in Augenschein nehmen.

**BugFix**

Zitat von Kanashius

Damit eine for Schleife basteln, die von 0 bis itemcount geht

Damit sägst du den Ast ab, auf dem du sitzt
Du mußt das Listview vom letzten Eintrag zum ersten iterieren (Itemcount-1 to 0 step -1). Anderenfalls stimmen die Indexwerte nach Löschen eines Eintrages nicht mehr.

**BugFix**

Hi,

ich lese die Ordner eines Pfades aus um sie in einem Tree darzustellen. Schaue ich mir den Ordner im Explorer an, werden auch Zahlen in Strings nach den Zahlen sortiert:

Wenn ich mit _FileListToArrayRec($sPath, "*", $FLTAR_FOLDERS, $FLTAR_NORECUR, $FLTAR_SORT) einlese ist es String-sortiert:

Das gleich ist in der Konsole mit TREE der Fall:
tree_cmd.png

Wie kann ich die Sortierung, wie im Explorer erreichen?

Beiträge von BugFix

Timer und Knopfdrücke gleichzeitig

If NOT über variable

Prozessname in der Prozessliste des Windows Taskmanagers als 8.3 Dateiname

eTIN: erstellen

Aus CVS Datei erste Zeile löschen

Problem mit MouseClick()

exe an cmd/dos

Probleme nach M$ Patchday Juni-2016 [GELÖST - doch nicht]

Seltsames Leuchten in den Wolken

Hilfe bei Array !

ZIP - Packen / Entpacken mit Windows eigener Funktion

Probleme nach M$ Patchday Juni-2016 [GELÖST - doch nicht]

Listbox und Combobox - wie Zeilenumbruch? - mehrzeilige Anzeige?

Probleme nach M$ Patchday Juni-2016 [GELÖST - doch nicht]

Probleme nach M$ Patchday Juni-2016 [GELÖST - doch nicht]

Probleme nach M$ Patchday Juni-2016 [GELÖST - doch nicht]

Sortierung, wie im Explorer-Tree - wie gehts?

Sortierung, wie im Explorer-Tree - wie gehts?

bestimmte listview einträge löschen

Sortierung, wie im Explorer-Tree - wie gehts?