Beiträge von BugFix

#include <WinAPIFiles.au3>

; #FUNCTION# =======================================================================================
; Name ..........: _PathGetUnmapped
; Description ...: Resolving network links in paths to absolute paths
; Syntax ........: _PathGetUnmapped($_sPath)
; Parameters ....: $_sPath              - The path to be checked.
; Return values .: The resolved path or the original path.
; Author ........: BugFix
; Remarks .......: Requires <WinAPIFiles.au3>
; ==================================================================================================
Func _PathGetUnmapped($_sPath)
    If StringLeft($_sPath, 2) = '\\' Then Return $_sPath    ; qualified network path
    Local $aPath = StringRegExp($_sPath, '([A-Za-z]:)(.+)', 1)
    Local $vReturn = _WinAPI_QueryDosDevice($aPath[0])
    If StringRegExp($vReturn, '^\\Device\\LanmanRedirector') Then
        If StringInStr($vReturn, 'localhost') Then
            $vReturn = StringReplace(StringRegExpReplace($vReturn, '\\Device\\LanmanRedirector\\[^\\]+\\localhost\\', ''), '$', ':')
        Else
            $vReturn = '\' & StringRegExp($vReturn, '(\\Device\\LanmanRedirector\\;[^\\]+)(.+)', 1)[1]
        EndIf
        Return $vReturn & (UBound($aPath) = 2 ? $aPath[1] : '')
    Else
        $vReturn = StringRegExp($vReturn, '(\\Device\\[^\\]+\\;[^\\]+)(\\.+)', 1)
    EndIf
    If IsArray($vReturn) Then
        Return '\' & $vReturn[1] & (UBound($aPath) = 2 ? $aPath[1] : '')
    Else
        Return $_sPath
    EndIf
EndFunc

#include <AutoItConstants.au3>

; wechseln in Verzeichnis ohne Repo
FileChangeDir('C:\Users')
$Status = _GitStatus()
ConsoleWrite('<< Status >>' & @CRLF & $Status & @CRLF)


Func _GitStatus()
    Return _CMDLineRead('git status')
EndFunc

Func _CMDLineRead($_sCMD)
    Local $PID = Run(@ComSpec & " /c " & $_sCMD, "", @SW_HIDE, $STDOUT_CHILD)
    Local $sLine, $sOutput = ''
    While 1
        $sLine = StdoutRead($PID)
        If @error Then ExitLoop
        $sOutput &= $sLine
    WEnd
    Return $sOutput
EndFunc

#include <GuiToolbar.au3>
#include <WinAPIShellEx.au3>

;---------------------------------------------------------------------------------------------------

Global $ICO = @ScriptDir & '\ico\'
Global $mIcon[]
$mIcon['IsRepo'] = $ICO & 'git_hasrepo.ico'
$mIcon['NoRepo'] = $ICO & 'git_norepo.ico'
$mIcon['Changing'] = $ICO & 'git_repo-w-changings.ico'
For $i = 1 To 9
    $mIcon[$i] = $ICO & $i & '_16.ico'
Next
$mIcon[99] = $ICO & '9+_16.ico' ; >9 files

;---------------------------------------------------------------------------------------------------

Global $gm_SciTE[]
$gm_SciTE.hWnd = 0
$gm_SciTE.ExistsLast = 0
$gm_SciTE.ExistsCurr = 0
$gm_SciTE.WinArrayLast = 0
$gm_SciTE.WinArrayCurr = 0
$gm_SciTE.bReDraw = False
$gm_SciTE.aStatusIcon = 0
$gm_SciTE.aCounterIcon = 0
$gm_SciTE.StatusIcon = Null
$gm_SciTE.CounterIcon = Null

;---------------------------------------------------------------------------------------------------
_SciTEToolBar_DrawIconGitStatus('Changing')
_SciTEToolBar_DrawIconGitCounter(99)
;---------------------------------------------------------------------------------------------------

_CheckSciTE()
AdlibRegister(_CheckSciTE, 1000)

While True
    Sleep(5000)
WEnd


Func _End()
    AdlibUnRegister(_CheckSciTE)
    Exit
EndFunc


Func _CheckSciTE()
    If ProcessExists("SciTE.exe") Then
        Local $hScite, $hToolbar, $hStatusbar
        _GetSciTEhWnd($hScite, $hToolbar, $hStatusbar)
        $gm_SciTE.ExistsCurr = 1
        If $gm_SciTE.ExistsLast = 0 Then
            $gm_SciTE.ExistsLast = 1
            $gm_SciTE.hWnd = $hScite
            AdlibRegister(_CheckReDraw, 350)
        EndIf
    Else
        $gm_SciTE.ExistsCurr = 0
        If $gm_SciTE.ExistsLast = 1 Then
            $gm_SciTE.ExistsLast = 0
            $gm_SciTE.hWnd = 0
            AdlibUnRegister(_CheckReDraw)
        EndIf
    EndIf
EndFunc


Func _CheckReDraw()
    ; check if size/pos has changed (after min/max the pos has also changed)
    $gm_SciTE.WinArrayCurr = WinGetPos($gm_SciTE.hWnd)
    Local $bChanged = False
    If IsArray($gm_SciTE.WinArrayLast) Then
        $bChanged = _WinSizeDiff()    ; if Diff returns: True
    Else
        $bChanged = True
    EndIf
    $gm_SciTE.bReDraw = $bChanged
    _ReDraw()
EndFunc


Func _WinSizeDiff()
    If ($gm_SciTE.WinArrayLast[0] <> $gm_SciTE.WinArrayCurr[0]) Or _
       ($gm_SciTE.WinArrayLast[1] <> $gm_SciTE.WinArrayCurr[1]) Or _
       ($gm_SciTE.WinArrayLast[2] <> $gm_SciTE.WinArrayCurr[2]) Or _
       ($gm_SciTE.WinArrayLast[3] <> $gm_SciTE.WinArrayCurr[3]) Then
        Return True
    Else
        Return False
    EndIf
EndFunc


Func _ReDraw()
    If Not $gm_SciTE.bReDraw Then
        Return
    Else
        AdlibUnRegister(_CheckReDraw)
        _SciTEToolBar_DrawIconGitStatus($gm_SciTE.StatusIcon)
        _SciTEToolBar_DrawIconGitCounter($gm_SciTE.CounterIcon)
        $gm_SciTE.WinArrayLast = $gm_SciTE.WinArrayCurr
        AdlibRegister(_CheckReDraw, 350)
    EndIf
EndFunc


Func _SciTEToolBar_DrawIconGitStatus($_sStatus) ; 'IsRepo', 'NoRepo', 'Changing'
    $gm_SciTE.aStatusIcon = _SciTEToolBar_DrawIcon($mIcon[$_sStatus], True)
    $gm_SciTE.StatusIcon = $_sStatus
EndFunc


Func _SciTEToolBar_DrawIconGitCounter($_iCounter) ; 1,2,3,4,5,6,7,8,9,99    0-Deletes the counter Icon
    If $_iCounter = 0 Then
        _SciTEToolBar_DeleteDrawedIcon($gm_SciTE.aCounterIcon)
        $gm_SciTE.aCounterIcon = 0
        $gm_SciTE.CounterIcon = Null
    ElseIf $_iCounter = Null Then
        Return
    Else
        $gm_SciTE.aCounterIcon = _SciTEToolBar_DrawIcon($mIcon[$_iCounter], True, 16)
        $gm_SciTE.CounterIcon = $_iCounter
    EndIf
EndFunc


Func _SciTEToolBar_DrawIcon($_sPathIcon, $_bDeleteBG=True, $_xRel2LastTBItem=Null)
    Local $hScite, $hToolbar, $hStatusbar   ; get SciTE handles
    _GetSciTEhWnd($hScite, $hToolbar, $hStatusbar)
    If @error Then Return SetError(1)
    Local $aPadding = _GUICtrlToolbar_GetPadding($hToolbar)
    Local $xPad = $aPadding[0]
    Local $aLastItem = _GUICtrlToolbar_GetButtonRect($hToolbar, _
          _GUICtrlToolbar_IndexToCommand($hToolbar, _GUICtrlToolbar_ButtonCount($hToolbar)-1))
    Local $x = $_xRel2LastTBItem = Null ? $aLastItem[2] : ($aLastItem[2] + $xPad + $_xRel2LastTBItem)
    Local $hDC = _WinAPI_GetDC($hToolbar)
    If $_bDeleteBG Then ; Delete last icon by overwriting
        Local $a[] = [$x+$xPad, 3, 16, 16]
        _SciTEToolBar_DeleteDrawedIcon($a, $hDC)
    EndIf
    Local $hIcon = _WinAPI_ShellExtractIcon($_sPathIcon, 0, 16, 16)
    Local $aIconDrawed[] = [$x+$xPad, 3, 16, 16]
    _WinAPI_DrawIconEx($hDC, $x+$xPad, 3, $hIcon, 16, 16)
    _WinAPI_DestroyIcon($hIcon)
    _WinAPI_DeleteDC($hDC)
    Return $aIconDrawed
EndFunc


Func _SciTEToolBar_DeleteDrawedIcon($_aIcon, $_hDC=Null)    ; $_aIcon returned from _SciTEToolBar_DrawIcon
    Local $tRect = DllStructCreate($tagRect), $bDelDC = False
    $tRect.Left = $_aIcon[0]
    $tRect.Top = $_aIcon[1]
    $tRect.Right = $_aIcon[0] + $_aIcon[2]
    $tRect.Bottom = $_aIcon[1] + $_aIcon[3]
    If $_hDC = Null Then
        Local $hScite, $hToolbar, $hStatusbar   ; get SciTE handles
        _GetSciTEhWnd($hScite, $hToolbar, $hStatusbar)
        If @error Then Return SetError(1)
        $_hDC = _WinAPI_GetDC($hToolbar)
        $bDelDC = True
    EndIf
    Local $hBrush = _WinAPI_CreateSolidBrush(0xF0F0F0)
    _WinAPI_FillRect($_hDC, $tRect, $hBrush)
    _WinAPI_DeleteObject($hBrush)
    If $bDelDC Then _WinAPI_DeleteDC($_hDC)
EndFunc


Func _GetSciTEhWnd(ByRef $_hScite, ByRef $_hToolbar, ByRef $_hStatusbar)
    $hActive = WinGetHandle('[ACTIVE]')
    $aResult = DllCall('user32.dll', "int", "GetClassNameW", "hwnd", $hActive, "wstr", "", "int", 4096)
    If Not @error And $aResult[2] = 'SciTEWindow' Then
        $_hScite = $hActive
        $_hToolbar = ControlGetHandle($_hScite, '', '[CLASS:ToolbarWindow32; INSTANCE:1]')
        $_hStatusbar = ControlGetHandle($_hScite, '', '[CLASS:msctls_statusbar32; INSTANCE:1]')
        Return 1
    Else
        Return SetError(1)
    EndIf
EndFunc

Func _CMDLineRead($_sCMD)
    Local $PID = Run(@ComSpec & " /c " & $_sCMD, "", @SW_HIDE, $STDOUT_CHILD)
    Local $sLine, $sOutput = ''
    While 1
        $sLine = StdoutRead($PID)
        If @error Then ExitLoop
        If StringStripWS($sLine, 8) <> '' Then $sOutput &= $sLine
    WEnd
    Return $sOutput
EndFunc


$group = _CMDLineRead("whoami /groups")
ConsoleWrite($group & @CRLF)

--[[
----------------------------------------------------------------------------------------------------
   Creating a UUID using values from the SciTE registry table, os.clock and os.time
   A unique value is generated for each call.
--------------------------------------------------------------------------------------------------]]
function GenerateSciTEUserUUID()
   local GetHexRev = function(_s) return tonumber('0x'..tostring(_s):match('([A-F0-9]+)'):reverse()) end
   local Dec2Hex = function(_d, _len, _raw)
       local tNumstr = {'0','1','2','3','4','5','6','7','8','9','A','B','C','D','E','F'}
       local sRet, rest = '', 0
       repeat
           rest = (_d % 16) +1
           sRet = tNumstr[rest]..sRet
           _d = math.floor(_d/16)
       until _d == 0
       local len, lenret = _len or 8, sRet:len()
       if lenret > len then sRet = sRet:sub(-1*len) end
       if _raw ~= nil then return ('0'):rep(len-lenret)..sRet end
       return tonumber('0x'..('0'):rep(len-lenret)..sRet)
   end
   local rTime = function()
       local s, ms = tostring(os.clock()):match('(%d+)%.(%d+)')
       local datedigits = os.date():gsub('%D','') return s*ms*datedigits
   end
   local Addend = function() return Dec2Hex(rTime()) end
   local tReg = debug.getregistry()
   local tVal = {GetHexRev(tReg['_IO_output'])+Addend(),GetHexRev(tReg['SciTE_MT_Props'])+Addend(),
                 GetHexRev(tReg['SciTE_InitialPackageState'])+Addend(),GetHexRev(tReg['LUABOX'])+Addend(),
                 GetHexRev(tReg['SciTE_MT_Pane'])+Addend(),GetHexRev(tReg['SciTE_BufferData_Array'])+Addend()}
   local uuid =
   tostring(Dec2Hex(tVal[1],8,1))..'-'..
   tostring(Dec2Hex(tVal[2],4,1))..'-'..
   tostring(Dec2Hex(tVal[3],4,1))..'-'..
   tostring(Dec2Hex(tVal[4],4,1))..'-'..
   tostring(Dec2Hex(tVal[5],8,1))..tostring(Dec2Hex(tVal[6],4,1))
   return uuid
end -- GenerateSciTEUserUUID()

--[[
----------------------------------------------------------------------------------------------------
   Replaces each occurrence of an expression defined with a pattern with the passed string.
   _pattern        - the string pattern
   _replacement    - the replacement string
--------------------------------------------------------------------------------------------------]]
function ReplaceInEditor(_pattern, _replacement)
   local pos = editor.CurrentPos
   local line = editor:LineFromPosition(pos)
   local column = editor.Column[pos]
   local fvline = editor.FirstVisibleLine
   local shiftline = line - fvline                         -- store difference from top
   local uuid = GenerateSciTEUserUUID()
   editor:BeginUndoAction()
   editor:InsertText(pos, uuid)                            -- insert unique value to identify the caret position
   local text = editor:GetText()
   editor:SetText(text:gsub(_pattern, _replacement))       -- make the replacement(s)
   pos = editor:GetText():find(uuid:gsub('%-', '%%-')) -1  -- search for the previous position of the cursor in the new text
   local uuidline = editor:LineFromPosition(pos)           -- current number from our marked line
   local newfirstvisible = uuidline - shiftline            -- to have the old distance
   if newfirstvisible < 0 then newfirstvisible = 0 end
   editor:SetSel(pos, pos + uuid:len())
   editor:ReplaceSel('')                                   -- remove the uuid
   editor.FirstVisibleLine = newfirstvisible
   editor:SetSel(pos, pos)
   editor:EndUndoAction()
end -- ReplaceInEditor()

--[[
----------------------------------------------------------------------------------------------------
   Creating a UUID using values from the SciTE registry table
   Parts that change their value:
       W  - after Windows has been (re)started
       O  - after SciTE was (re)opened
       T  - after the number of opened tabs has changed
--------------------------------------------------------------------------------------------------]]
function GenerateSciTEUserUUID()
   local extract = function(s, count)
       return tostring(s):match('([A-F0-9]+)'):reverse():sub(1, count)
   end
   local tSciTEREG = debug.getregistry()
   local uuid =
   tostring(extract(tSciTEREG['_IO_output'], 8)) .. '-' ..                 -- [W]
   tostring(extract(tSciTEREG['SciTE_MT_Props'], 4)) .. '-' ..             -- [W, O]
   tostring(extract(tSciTEREG['SciTE_InitialPackageState'], 4)) .. '-' ..  -- [W, O, T]
   tostring(extract(tSciTEREG['LUABOX'], 4)) .. '-' ..                     -- [W, O]
   tostring(extract(tSciTEREG['SciTE_MT_Pane'], 8)) ..                     -- [W, O, T]
   tostring(extract(tSciTEREG['SciTE_BufferData_Array'], 4))
   return uuid
end -- GenerateSciTEUserUUID()