Ich weiß zwar nicht, wo in dem Bild ein Trapez sein soll, aber das Ganze lässt sich ganz gut in GDI+ realisieren.
$hImage=_GDIPlus_ImageLoadFromFile($sFileName) ;Bild laden
_GDIPlus_ImageScale ( $hImage, $iScaleW, $iScaleH [, $iInterpolationMode = $GDIP_INTERPOLATIONMODE_HIGHQUALITYBICUBIC] ) ;Bild skalieren
_GDIPlus_ImageGetGraphicsContext ( $hImage ) ;Graphic um Text draufzumalen
Und dann hat @chesstiger grad erst ein Tutorial zu GDI+ gemacht. Da steht, wie du auf ein Bild malst.
Rundumschlag GDI+?
Ein Trapez mit dem Bild geht leider nicht, aber ein Parallelogramm schon! -> _GDIPlus_DrawImagePoints
Du kannst ja dies mal als Ansatz nehmen:
#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
Global $sImageFile = FileOpenDialog("Select an image", "", "Images (*.jpg;*.png;*.bmp)")
If @error Then Exit MsgBox(0, "Information", "Nothing selected - stopping script!", 30)
_GDIPlus_Startup()
Global $hBitmap = _GDIPlus_BitmapCreateFromFile($sImageFile)
DrawTextOnBitmap($hBitmap, "This is a GDI+ demo", 50)
Global Const $iW = _GDIPlus_ImageGetWidth($hBitmap), $iH = _GDIPlus_ImageGetHeight($hBitmap)
Global Const $hGUI = GUICreate("GDI+ Test", $iW, $iH)
GUISetBkColor(0)
GUISetState()
Global Const $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI)
Global Const $hBmp = _GDIPlus_BitmapCreateFromGraphics($iW, $iH, $hGraphics)
Global Const $hCtxt = _GDIPlus_ImageGetGraphicsContext($hBmp)
_GDIPlus_GraphicsSetPixelOffsetMode($hCtxt, 2)
Global $fPosX = 0, $fPosY = 0
AdlibRegister("Anim", 30)
Do
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
AdlibUnRegister("Anim")
_GDIPlus_GraphicsDispose($hGraphics)
_GDIPlus_GraphicsDispose($hCtxt)
_GDIPlus_BitmapDispose($hBitmap)
_GDIPlus_BitmapDispose($hBmp)
_GDIPlus_Shutdown()
GUIDelete()
Exit
EndSwitch
Until False
Func Anim()
_GDIPlus_GraphicsClear($hCtxt)
_GDIPlus_DrawImagePoints($hCtxt, $hBitmap, 0, 0, $iW, 0, $fPosX, $fPosY)
_GDIPlus_GraphicsDrawImageRect($hGraphics, $hBmp, 0, 0, $iW, $iH)
Local Static $iX = 0, $fAmpl = 40
$fPosY += ($fPosY <= $iH) ? 2 : 0
If $fPosY <= $iH Then
$fPosX = Cos($fPosY / 30) * $fAmpl
$iX = $fPosY
Else
$fPosX = Cos($iX / 30) * $fAmpl
$iX += 2
$fAmpl -= $fAmpl > 0 ? 0.25 : 0
If $fAmpl <= 0 Then AdlibUnRegister("Anim")
EndIf
EndFunc
Func DrawTextOnBitmap(ByRef $hBitmap, $sText, $fFontSize, $sFontTyp = "Impact", $iInnerColor = 0xFFFFFFFF, $iBorderColor = 0xFF000000)
Local Const $iW = _GDIPlus_ImageGetWidth($hBitmap), $iH = _GDIPlus_ImageGetHeight($hBitmap)
Local Const $hGfx = _GDIPlus_ImageGetGraphicsContext($hBitmap)
_GDIPlus_GraphicsSetSmoothingMode($hGfx, 4)
_GDIPlus_GraphicsSetTextRenderingHint($hGfx, 3)
_GDIPlus_GraphicsSetPixelOffsetMode($hGfx, 2)
Local Const $hBrush_Inner = _GDIPlus_BrushCreateSolid($iInnerColor), $hPen_Border = _GDIPlus_PenCreate($iBorderColor, 1.5)
Local Const $hPath = _GDIPlus_PathCreate(), $hFamily = _GDIPlus_FontFamilyCreate($sFontTyp), $hFormat = _GDIPlus_StringFormatCreate()
Local Const $tLayout = _GDIPlus_RectFCreate(0, 0, $iW, $iH)
_GDIPlus_StringFormatSetAlign($hFormat, 1)
_GDIPlus_StringFormatSetLineAlign($hFormat, 1)
_GDIPlus_PathAddString($hPath, $sText, $tLayout, $hFamily, 0, $fFontSize, $hFormat)
_GDIPlus_GraphicsFillPath($hGfx, $hPath, $hBrush_Inner)
_GDIPlus_GraphicsDrawPath($hGfx, $hPath, $hPen_Border)
_GDIPlus_GraphicsDispose($hGfx)
_GDIPlus_BrushDispose($hBrush_Inner)
_GDIPlus_PenDispose($hPen_Border)
_GDIPlus_PathDispose($hPath)
_GDIPlus_FontFamilyDispose($hFamily)
_GDIPlus_StringFormatDispose($hFormat)
EndFunc
Den Ansatz hast du, haue rein, wie du es gerne hättest.
Probiere es mal damit:
[autoit]#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
Global $sImageFile = FileOpenDialog("Select an image", "", "Images (*.jpg;*.png;*.bmp)")
If @error Then Exit MsgBox(0, "Information", "Nothing selected - stopping script!", 30)
_GDIPlus_Startup()
Global $hBitmap = _GDIPlus_BitmapCreateFromFile($sImageFile)
DrawTextOnBitmap($hBitmap, "This is a GDI+ demo", 50)
Global Const $iW = _GDIPlus_ImageGetWidth($hBitmap), $iH = _GDIPlus_ImageGetHeight($hBitmap)
Global Const $hGUI = GUICreate("GDI+ Test", $iW, $iH)
GUISetBkColor(0)
GUISetState()
Global Const $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI)
Global Const $hBmp = _GDIPlus_BitmapCreateFromGraphics($iW, $iH, $hGraphics)
Global Const $hCtxt = _GDIPlus_ImageGetGraphicsContext($hBmp)
_GDIPlus_GraphicsSetPixelOffsetMode($hCtxt, 2)
Global $fPosX = 0, $fPosY = 0, $iSpeed = $iH / 20
ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $iSpeed = ' & $iSpeed & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console
AdlibRegister("Anim", 20)
Do
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
AdlibUnRegister("Anim")
_GDIPlus_GraphicsDispose($hGraphics)
_GDIPlus_GraphicsDispose($hCtxt)
_GDIPlus_BitmapDispose($hBitmap)
_GDIPlus_BitmapDispose($hBmp)
_GDIPlus_Shutdown()
GUIDelete()
Exit
EndSwitch
Until False
Func Anim()
_GDIPlus_GraphicsClear($hCtxt)
_GDIPlus_DrawImagePoints($hCtxt, $hBitmap, 0, 0, $iW, 0, $fPosX, $fPosY)
_GDIPlus_GraphicsDrawImageRect($hGraphics, $hBmp, 0, 0, $iW, $iH)
$fPosY += ($fPosY < $iH) ? $iSpeed : AdlibUnRegister("Anim")
EndFunc
Func DrawTextOnBitmap(ByRef $hBitmap, $sText, $fFontSize, $sFontTyp = "Impact", $iInnerColor = 0xFFFFFFFF, $iBorderColor = 0xFF000000)
Local Const $iW = _GDIPlus_ImageGetWidth($hBitmap), $iH = _GDIPlus_ImageGetHeight($hBitmap)
Local Const $hGfx = _GDIPlus_ImageGetGraphicsContext($hBitmap)
_GDIPlus_GraphicsSetSmoothingMode($hGfx, 4)
_GDIPlus_GraphicsSetTextRenderingHint($hGfx, 3)
_GDIPlus_GraphicsSetPixelOffsetMode($hGfx, 2)
Local Const $hBrush_Inner = _GDIPlus_BrushCreateSolid($iInnerColor), $hPen_Border = _GDIPlus_PenCreate($iBorderColor, 1.5)
Local Const $hPath = _GDIPlus_PathCreate(), $hFamily = _GDIPlus_FontFamilyCreate($sFontTyp), $hFormat = _GDIPlus_StringFormatCreate()
Local Const $tLayout = _GDIPlus_RectFCreate(0, 0, $iW, $iH)
_GDIPlus_StringFormatSetAlign($hFormat, 1)
_GDIPlus_StringFormatSetLineAlign($hFormat, 1)
_GDIPlus_PathAddString($hPath, $sText, $tLayout, $hFamily, 0, $fFontSize, $hFormat)
_GDIPlus_GraphicsFillPath($hGfx, $hPath, $hBrush_Inner)
_GDIPlus_GraphicsDrawPath($hGfx, $hPath, $hPen_Border)
_GDIPlus_GraphicsDispose($hGfx)
_GDIPlus_BrushDispose($hBrush_Inner)
_GDIPlus_PenDispose($hPen_Border)
_GDIPlus_PathDispose($hPath)
_GDIPlus_FontFamilyDispose($hFamily)
_GDIPlus_StringFormatDispose($hFormat)
EndFunc
Super danke 
Kann man eigentlich auf eine Bitmap nochmal eine Grafik oben "draufzeichnen"?
Das geht auch. D.h. anstelle die Grafik zu löschen, muss du das vorige Bild in die Grafik kopieren.
Ok ist auch fast erledigt
Aber eine Frage habe ich dann doch noch:
Wenn ich einen beliebig lagen Text (meistens nur ein bis wenige Wörter) in einer Variable $text habe, wie kann ich für die oben gegebene Funktion
Func DrawTextOnBitmap(...)
[/autoit]
die größtmögliche Schritftgröße in Abhängigkeit von den maximalen Breite (@DesktopWidth-50) und Höhe (2/3*@DesktopWidth) errechnen?
Du kannst die Größe zb. so anpassen:
[autoit]
#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
Global $sImageFile = FileOpenDialog("Select an image", "", "Images (*.jpg;*.png;*.bmp)")
If @error Then Exit MsgBox(0, "Information", "Nothing selected - stopping script!", 30)
_GDIPlus_Startup()
Global $hBitmap = _GDIPlus_BitmapCreateFromFile($sImageFile)
DrawTextOnBitmap($hBitmap, "This is a GDI+ demo")
Global Const $iW = _GDIPlus_ImageGetWidth($hBitmap), $iH = _GDIPlus_ImageGetHeight($hBitmap)
Global Const $hGUI = GUICreate("GDI+ Test", $iW, $iH)
GUISetBkColor(0)
GUISetState()
Global Const $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI)
Global Const $hBmp = _GDIPlus_BitmapCreateFromGraphics($iW, $iH, $hGraphics)
Global Const $hCtxt = _GDIPlus_ImageGetGraphicsContext($hBmp)
_GDIPlus_GraphicsSetPixelOffsetMode($hCtxt, 2)
Global $fPosX = 0, $fPosY = 0, $iSpeed = $iH / 20
ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $iSpeed = ' & $iSpeed & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console
AdlibRegister("Anim", 20)
Do
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
AdlibUnRegister("Anim")
_GDIPlus_GraphicsDispose($hGraphics)
_GDIPlus_GraphicsDispose($hCtxt)
_GDIPlus_BitmapDispose($hBitmap)
_GDIPlus_BitmapDispose($hBmp)
_GDIPlus_Shutdown()
GUIDelete()
Exit
EndSwitch
Until False
Func Anim()
_GDIPlus_GraphicsClear($hCtxt)
_GDIPlus_DrawImagePoints($hCtxt, $hBitmap, 0, 0, $iW, 0, $fPosX, $fPosY)
_GDIPlus_GraphicsDrawImageRect($hGraphics, $hBmp, 0, 0, $iW, $iH)
$fPosY += ($fPosY < $iH) ? $iSpeed : AdlibUnRegister("Anim")
EndFunc ;==>Anim
Func DrawTextOnBitmap(ByRef $hBitmap, $sText, $iBorder = 10, $sFontTyp = "Impact", $iInnerColor = 0xFFFFFFFF, $iBorderColor = 0xFF000000)
Local Const $iW = _GDIPlus_ImageGetWidth($hBitmap), $iH = _GDIPlus_ImageGetHeight($hBitmap)
Local Const $hGfx = _GDIPlus_ImageGetGraphicsContext($hBitmap)
_GDIPlus_GraphicsSetSmoothingMode($hGfx, 4)
_GDIPlus_GraphicsSetTextRenderingHint($hGfx, 3)
_GDIPlus_GraphicsSetPixelOffsetMode($hGfx, 2)
Local Const $hBrush_Inner = _GDIPlus_BrushCreateSolid($iInnerColor), $hPen_Border = _GDIPlus_PenCreate($iBorderColor, 1.5)
Local Const $hPath = _GDIPlus_PathCreate(), $hFamily = _GDIPlus_FontFamilyCreate($sFontTyp), $hFormat = _GDIPlus_StringFormatCreate()
Local Const $tLayout = _GDIPlus_RectFCreate(0, 0, $iW, $iH)
;_GDIPlus_StringFormatSetAlign($hFormat, 1)
;_GDIPlus_StringFormatSetLineAlign($hFormat, 1)
_GDIPlus_PathAddString($hPath, $sText, $tLayout, $hFamily, 0, 10, $hFormat)
Local $aBounds = _GDIPlus_PathGetWorldBounds($hPath)
Local $fScale = ($iW - $iBorder * 2) / $aBounds[2]
If ($iH - $iBorder * 2) / $aBounds[3] < $fScale Then $fScale = ($iH - $iBorder * 2) / $aBounds[3]
Local $hMatrix = _GDIPlus_MatrixCreate()
_GDIPlus_MatrixTranslate($hMatrix, -($aBounds[0] + $aBounds[2] * 0.5), -($aBounds[1] + $aBounds[3] * 0.5))
_GDIPlus_MatrixScale($hMatrix, $fScale, $fScale, True)
_GDIPlus_MatrixTranslate($hMatrix, $iW * 0.5, $iH * 0.5, True)
_GDIPlus_PathTransform($hPath, $hMatrix)
_GDIPlus_MatrixDispose($hMatrix)
_GDIPlus_GraphicsFillPath($hGfx, $hPath, $hBrush_Inner)
_GDIPlus_GraphicsDrawPath($hGfx, $hPath, $hPen_Border)
_GDIPlus_GraphicsDispose($hGfx)
_GDIPlus_BrushDispose($hBrush_Inner)
_GDIPlus_PenDispose($hPen_Border)
_GDIPlus_PathDispose($hPath)
_GDIPlus_FontFamilyDispose($hFamily)
_GDIPlus_StringFormatDispose($hFormat)
EndFunc ;==>DrawTextOnBitmap
Funktioniert jetzt auch 
Kann man die Funktion auch so schreiben, dass...
1. man einen Bereich vorgibt wo die Schrift steht, also eine Position und eine Breite bzw. Höhe des "Rahmens" und
(konkret heißt das, dass man eine xund eine y Position und dazu noch die Width und die High)
2. sie automatisch einen Zeilenumbruch macht, wenn der Text insgesamt mit Zeilenumbruch größer wäre als ohne?
(Beispiel: Der Text "Landwirtschaft nimmt wieder stark zu" wäre in eine Zeile gequetscht ziemlich klein. Hier wäre ein Zeilenumbruch wie z.B. "Landwirtschaft nimmt / wieder stark zu" sinnvoll und die Schrift wäre insgesamt dadurch größer. Zeilenumbrüche sollten aber nur eingefügt werden, wenn ein Leerzeichen vorhanden sind. Worttrennungen sind also nicht nötig.)
Der rote Kasten entspricht den Vorgaben unter Punkt 1.
Ich habe auch dafür keinen Ansatz parat.
Dies sollte deine 2 Fragen beantworten:
#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
Global $sImageFile = FileOpenDialog("Select an image", "", "Images (*.jpg;*.png;*.bmp)")
If @error Then Exit MsgBox(0, "Information", "Nothing selected - stopping script!", 30)
_GDIPlus_Startup()
Global $hBitmap = _GDIPlus_BitmapCreateFromFile($sImageFile)
DrawTextOnBitmap($hBitmap, "Landwirtschaft nimmt wieder stark zu")
Global Const $iW = _GDIPlus_ImageGetWidth($hBitmap), $iH = _GDIPlus_ImageGetHeight($hBitmap)
Global Const $hGUI = GUICreate("GDI+ Test", $iW, $iH)
GUISetBkColor(0)
GUISetState()
Global Const $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI)
Global Const $hBmp = _GDIPlus_BitmapCreateFromGraphics($iW, $iH, $hGraphics)
Global Const $hCtxt = _GDIPlus_ImageGetGraphicsContext($hBmp)
_GDIPlus_GraphicsSetPixelOffsetMode($hCtxt, 2)
Global $fPosX = 0, $fPosY = 0, $iSpeed = $iH / 20
AdlibRegister("Anim", 20)
Do
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
AdlibUnRegister("Anim")
_GDIPlus_GraphicsDispose($hGraphics)
_GDIPlus_GraphicsDispose($hCtxt)
_GDIPlus_BitmapDispose($hBitmap)
_GDIPlus_BitmapDispose($hBmp)
_GDIPlus_Shutdown()
GUIDelete()
Exit
EndSwitch
Until False
Func Anim()
_GDIPlus_GraphicsClear($hCtxt)
_GDIPlus_DrawImagePoints($hCtxt, $hBitmap, 0, 0, $iW, 0, $fPosX, $fPosY)
_GDIPlus_GraphicsDrawImageRect($hGraphics, $hBmp, 0, 0, $iW, $iH)
$fPosY += ($fPosY < $iH) ? $iSpeed : AdlibUnRegister("Anim")
EndFunc ;==>Anim
Func DrawTextOnBitmap(ByRef $hBitmap, $sText, $fFontSize = 80, $sFontTyp = "Impact", $fDX = 0, $fDY = 0, $iInnerColor = 0xFFFFFFFF, $iBorderColor = 0xFF000000, $iBorder = 50)
Local Const $iW = _GDIPlus_ImageGetWidth($hBitmap), $iH = _GDIPlus_ImageGetHeight($hBitmap)
Local Const $hGfx = _GDIPlus_ImageGetGraphicsContext($hBitmap)
_GDIPlus_GraphicsSetSmoothingMode($hGfx, 4)
_GDIPlus_GraphicsSetTextRenderingHint($hGfx, 3)
_GDIPlus_GraphicsSetPixelOffsetMode($hGfx, 2)
Local Const $hBrush_Inner = _GDIPlus_BrushCreateSolid($iInnerColor), $hPen_Border = _GDIPlus_PenCreate($iBorderColor, 1.5)
Local Const $hPath = _GDIPlus_PathCreate(), $hFamily = _GDIPlus_FontFamilyCreate($sFontTyp), $hFormat = _GDIPlus_StringFormatCreate()
Local $tLayout = _GDIPlus_RectFCreate(0, 0, $iW, $iH)
_GDIPlus_StringFormatSetAlign($hFormat, 1)
;~ _GDIPlus_StringFormatSetLineAlign($hFormat, 1)
_GDIPlus_PathAddString($hPath, $sText, $tLayout, $hFamily, 0, $fFontSize, $hFormat)
Local $aBounds = _GDIPlus_PathGetWorldBounds($hPath)
Local $fScale = ($iW - $iBorder * 2) / $aBounds[2]
If ($iH - $iBorder * 2) / $aBounds[3] < $fScale Then $fScale = ($iH - $iBorder * 2) / $aBounds[3]
Local $hMatrix = _GDIPlus_MatrixCreate()
_GDIPlus_MatrixTranslate($hMatrix, -($aBounds[0] + $aBounds[2] * 0.5) + $fDX, -($aBounds[1] + $aBounds[3] * 0.5) + $fDY)
_GDIPlus_MatrixScale($hMatrix, $fScale, $fScale, True)
_GDIPlus_MatrixTranslate($hMatrix, $iW * 0.5, $iH * 0.5, True)
_GDIPlus_PathTransform($hPath, $hMatrix)
_GDIPlus_MatrixDispose($hMatrix)
_GDIPlus_GraphicsFillPath($hGfx, $hPath, $hBrush_Inner)
_GDIPlus_GraphicsDrawPath($hGfx, $hPath, $hPen_Border)
_GDIPlus_GraphicsDispose($hGfx)
_GDIPlus_BrushDispose($hBrush_Inner)
_GDIPlus_PenDispose($hPen_Border)
_GDIPlus_PathDispose($hPath)
_GDIPlus_FontFamilyDispose($hFamily)
_GDIPlus_StringFormatDispose($hFormat)
EndFunc ;==>DrawTextOnBitmap
1. $fDX und $fDY
2. $fFontSize
Hallo,
für das automatische einfügen von Zeilenumbrüchen hatte mal eine Funktion geschriebe, vielleicht kannst damit ja was anfangen!
;===============================================================================
; Name: _StringWrap
; Description: Fügt Zeilenumbrüche in Strings ein
; Parameter(s): $strString = String der bearbeitet werden soll
; $nCount = Anzahl der Zeichen bevor der Umbruch
; eingefügt werden soll
; (optional)
; $cWrap = Zeichen das/die als Umbruch eingefügt werden
; sollen (default = @CRLF)
; $cBreaking = 0 (default) -> Softbreak (an Wortgrenze)
; 1 -> Hardbreak
; Note(s): Ist kein Leerzeichen im String enthalten wird hart umgebrochen
; Requirement(s): keine
; Return Value(s): String mit umbrüchen
; Author(s): bernd670
;
;===============================================================================
Func _StringWrap($strString, $nCount, $cWrap = Default, $cBreaking = Default)
Local $strRetString = "", $nPos
If $cWrap = Default Then $cWrap = @CRLF
If $cBreaking = Default Then $cBreaking = 0
Do
If StringLen($strString) > $nCount Then
$nPos = StringInStr(StringLeft($strString, $nCount + 1), " ", 0, -1)
If ($nPos And $cBreaking = 0) Then
$strRetString &= StringLeft($strString, $nPos - 1) & $cWrap
$strString = StringMid($strString, $nPos + 1)
Else
$strRetString &= StringLeft($strString, $nCount) & $cWrap
$strString = StringMid($strString, $nCount + 1)
EndIf
EndIf
Until StringLen($strString) < $nCount
$strRetString &= $strString
Return $strRetString
EndFunc ;==>_StringWrapPrizipiell schon gut, nur kann ich die FontSize manuell nicht anpassen. Das muss die Funktion anhand des übergeben Textes selber machen inkl. die Aufteilung in die Zeilen. Die Funktion von eukalyptus macht soetwas ja schon, es fehlt da halt nur die beiden Punkte, die ich oben notiert hatte.
Ich verstehe dich nicht ganz. Die Funktion bricht doch automatisch den Text um, wenn der Text nicht in eine Zeile passt. Oder willst du an Hand des Textes die maximale Größe des Textes haben?