Wert von Controls Anzeigen

Kizum

Ich würde gerne die jeweiligen Werte der Inputfelder beim durchtaben oder beim Ändern der Werte in einem Label Anzeigen lassen.

Ein Event kommt aber erst zustande wenn ich Enter drücke.

Also kurz gesagt: Den Wert des jeweiligen Inputs dass den Focus hat Anzeigen in einer Schleife sodass man sofort sieht was man eintippt.

Vielen Dank

AutoIt

;#include <GUIScrollbars_Ex.au3>
#include <Array.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>
#include <File.au3>

Local $hGui = GUICreate("T17", 800, 500, -1,-1,$WS_SIZEBOX + $WS_SYSMENU)

$btn = GUICtrlCreateButton("Ab Damit", 500, 20)
GUICtrlSetResizing(-1, 256+512)



$iStart = GUICtrlCreateDummy()
    Dim $Inp[21]

    $h=40
    For $i = 0 to 20 Step +1
        $Inp[$i] = GUICtrlCreateInput("<", $h, 40, 10, 20)
        GUICtrlSetResizing(-1, $GUI_DOCKWIDTH)
        $h +=20
    Next
$iEnd = GUICtrlCreateDummy()


;_ArrayDisplay($Inp)


    GUISetState(@SW_SHOW, $hGui)
    ;_GUIScrollbars_Generate($hGui, 0, 1000, 0, 0, False, 7)

GUICtrlSetState($Inp[0],256)

    While 1
         $nMsg = GUIGetMsg()
        Switch $nMsg
            Case $GUI_EVENT_CLOSE
                ExitLoop
            Case $iStart To $iEnd
                MsgBox(0,"","")
            Case $btn
                For $o = 0 to UBound($Inp)-1 Step +1
                    ConsoleWrite(GUICtrlRead($Inp[$o]))
                    GUICtrlSetData($Inp[$o], "<" & $o & ">" )
                    GUICtrlSetState($Inp[0],256)
                Next
                    ConsoleWrite(@CRLF)

        EndSwitch
    WEnd

Alles anzeigen

**Bitnugger**

Zitat von Kizum

Ein Event kommt aber erst zustande wenn ich Enter drücke.

Nein, das ist so nicht richtig... du weißt halt nur noch nicht, welche es sind und wie du sie abfragen kannst.

In deinem Fall ist $WM_COMMAND dein Freund!

Hier ein kleines Beispiel... in der AutoIt-Hilfe findest du im Anhang (Appendix) eine Liste mit Windows Message Codes.

AutoIt

;-- TIME_STAMP   2018-07-14 21:26:18   v 0.1

#Region    ;************ Includes ************
#Include <WinAPIConv.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>
#EndRegion ;************ Includes ************

Global $hGui, $idButton_AbDamit, $idLabel_ShowInp, $aInp[21]

_Main()

Func _Main()
    $hGui = GUICreate("T17", 1060, 230, -1, -1, $WS_SIZEBOX + $WS_SYSMENU)

    $idButton_AbDamit = GUICtrlCreateButton("Ab damit!", 10, 80, 120, 40)
    GUICtrlSetResizing(-1, BitOR($GUI_DOCKWIDTH, $GUI_DOCKHEIGHT))
    $idLabel_ShowInp = GUICtrlCreateLabel("Inp[0] = '<'", 10, 150, 1040, 40)
;~     GUICtrlSetResizing(-1, BitOR($GUI_DOCKWIDTH, $GUI_DOCKHEIGHT))
    GUICtrlSetFont(-1, 24)
    GUICtrlSetColor(-1, 0xFF0000)
    GUICtrlSetBkColor(-1, 0x483D8B)

    Local $x = 10, $sText
    For $i = 0 To 20 Step 1
        $aInp[$i] = GUICtrlCreateInput("<", $x, 40, 40, 20)
        GUICtrlSetResizing(-1, $GUI_DOCKWIDTH)
        $x += 50
    Next
    GUICtrlSetState($aInp[0], $GUI_FOCUS)

    GUISetState(@SW_SHOW, $hGui)

    ; Sent when the user selects a command item from a menu, when a control sends a notification message to its parent window, or when an accelerator keystroke is translated.
    GUIRegisterMsg($WM_COMMAND, "_WM_COMMAND")

    Local $nMsg
    While 1
        $nMsg = GUIGetMsg()
        Switch $nMsg
            Case $GUI_EVENT_CLOSE
                ExitLoop
            Case $idButton_AbDamit
                $sText = '! $idButton_AbDamit --> '
                For $i = 0 To UBound($aInp) - 1 Step +1
                    $sText &= GUICtrlRead($aInp[$i]) & ', '
                    GUICtrlSetData($aInp[$i], "<" & $i & ">")
                Next
                GUICtrlSetState($aInp[0], $GUI_FOCUS)
                ConsoleWrite(StringTrimRight($sText, 2) & @CRLF)
        EndSwitch
    WEnd
EndFunc  ;==>_Main


Func _WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg
    Local $hWndFrom, $iIDFrom, $iCode
    $hWndFrom = $lParam
    $iIDFrom = _WinAPI_LoWord($wParam)
    $iCode = _WinAPI_HiWord($wParam)

    Switch $iIDFrom
        Case $aInp[0] To $aInp[UBound($aInp) -1]
            Local $idInput = $iIDFrom - $aInp[0]
            Switch $iCode
                Case $EN_KILLFOCUS
                    ConsoleWrite('- _WM_COMMAND: $EN_KILLFOCUS - $aInp['&$idInput&'] hast lost focus!' & @CRLF)
                Case $EN_SETFOCUS
                    ConsoleWrite('+ _WM_COMMAND: $EN_SETFOCUS  - $aInp['&$idInput&'] now has the focus!' & @CRLF)
                    GUICtrlSetData($idLabel_ShowInp, "Inp["&$idInput&"] = '"&GUICtrlRead($iIDFrom)&"'")
                Case $EN_CHANGE
                    ConsoleWrite('! _WM_COMMAND: $EN_CHANGE    - $aInp['&$idInput&'] content has changed! --> ' & GUICtrlRead($iIDFrom) & @CRLF)
                    GUICtrlSetData($idLabel_ShowInp, "Inp["&$idInput&"] = '"&GUICtrlRead($iIDFrom)&"'")
            EndSwitch
    EndSwitch
EndFunc  ;==>_WM_COMMAND

Alles anzeigen