Progressbarfenster lässt sich nicht verschieben / Progressbarfenster für Run()-Befehl

hipfzwirgel

Hallo AutoIT-Spezialisten,

ich habe ein Script erstellt mit welchem ich eine Zip-Datei erzeuge und diese dann verschiebe. Für den Verschiebevorgang habe ich eine Progressbar(wie im Forum beschrieben) implementiert.
Dieses Progressbarfenster lässt sich NICHT verschieben und genau das ist meine Frage. Kann mir jemand erklären warum nicht und ob ich das ändern kann?

Des Weiteren hätte ich gerne eine Progressbar für den Vorgang des Erstellens der Zip-Datei, da diese eine sehr große Datei(ca. 25 GB/Datensicherung) sein wird und der Vorgang ziemlich lange dauert.
Hätte jemand eine Idee wie ich das bewerkstelligen könnte?

Auszug:

C

#include <MsgBoxConstants.au3>
#include <AutoItConstants.au3>
#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <Date.au3>
#include <String.au3>
#include <StringConstants.au3>
#include <EditConstants.au3>
#Include <Misc.au3>
#include <Array.au3>
#Include <WinAPIEx.au3>
#include <WinAPIDiag.au3>
#include <WinAPIFiles.au3>


Local $sLongDayName = _DateDayOfWeek(@WDAY, $DMW_LOCALE_LONGNAME) ; Name Wochentag feststellen
Local $sOutput = ""
Global $sSource = "C:\Users\User\Test.zip"
Global $sDesti = "U:\Test.zip"


If $sLongDayName = "Freitag" Then

    $sEidi = MsgBox(4, "Meldung", "Heute ist " & $sLongDayName & "!!!" & @CRLF & @CRLF & "Möchten sie die Datensicherung durchführen?")


    If $sEidi = "6" Then

         MsgBox(0, "Warnung!!!", "Bitte alle Programme und oder geöffneten Dateien schließen!!!")
         $sStatus = Run(@ComSpec & " /c " & "7z a -tzip Test.zip C:\E\01_DOKUMENTE -pPASSWORT", "C:\Users\User", @SW_HIDE, $STDOUT_CHILD) ; ZIP-File wird mit /Zip erzeugt
         ProcessWaitClose($sStatus)
         $sOutput &= StdoutRead($sStatus)

         Msgbox(0, "Meldung Verschieben", $sOutput & @CRLF & @CRLF & " Soll der Content Kopiert werden?", 7)

            Local $hProgressProc = DllCallbackRegister('_ProgressProc', 'bool', 'uint64;uint64;uint64;uint64;dword;dword;handle;handle;ptr')

            ProgressOn('Verschieben', 'Moving...', '0%', -1, -1, BitOR($DLG_NOTONTOP, $DLG_MOVEABLE))

            If Not _WinAPI_MoveFileEx($sSource, $sDesti, 3, DllCallbackGetPtr($hProgressProc)) Then
            _WinAPI_ShowLastError('Error copying ' & $sSource)
            EndIf

            DllCallbackFree($hProgressProc)

            ProgressOff()


    EndIF

Else

    MsgBox(0, "Meldung", "Heute ist nicht Freitag. Also keine Datensicherung!!!", 4)

EndIf


Func _ProgressProc($iTotalFileSize, $iTotalBytesTransferred, $iStreamSize, $iStreamBytesTransferred, $iStreamNumber, $iCallbackReason, $hSourceFile, $hDestinationFile, $pData)
            #forceref $iStreamSize, $iStreamBytesTransferred, $iStreamNumber, $iCallbackReason, $hSourceFile, $hDestinationFile, $pData

            Local $iPercent = Round($iTotalBytesTransferred / $iTotalFileSize * 100)

            If $iPercent = 100 Then
                ProgressSet($iPercent, '', 'Complete')
                Sleep(1500)
            Else
                ProgressSet($iPercent, $iPercent & '%')
            EndIf

            Sleep(10) ; to slow down to see the progress bar

            If _IsPressed('1B') Then    ;Abbruch wenn EXC-Taste gedrückt wird
                Return $PROGRESS_CANCEL
            Else
                Return $PROGRESS_CONTINUE
            EndIf

EndFunc   ;==>_ProgressProc

Alles anzeigen

**Musashi**

Zitat von hipfzwirgel

Des Weiteren hätte ich gerne eine Progressbar für den Vorgang des Erstellens der Zip-Datei, da diese eine sehr große Datei(ca. 25 GB/Datensicherung) sein wird und der Vorgang ziemlich lange dauert.
Hätte jemand eine Idee wie ich das bewerkstelligen könnte?

Da Du eine Riesendatei hast (nicht viele kleinere), fällt ein Progress über Dateizähler quasi weg.

Eine Möglichkeit wäre eine Progressbar im Marquee-Stil !

Ich hatte dazu mal ein Beispiel geschrieben : 7-Zip und AutoIt

EDIT : hipfzwirgel

Eine weitere Möglichkeit wäre es, die Variante 7zG.exe (benötigt 7z.dll) zu verwenden. 7zG.exe findest Du im Hauptverzeichnis wo Du 7-Zip installiert hast (Vollinstallation nötig, nicht stand-alone-Variante).

Ich habe mir das kurz angesehen -> Zwischenfazit :

Mit 7zG.exe wird genau das Fenster angezeigt, welches Du auch im Vollprogramm hast.

Allerdings läuft die Ausgabe (soweit ich bisher ermittelt habe) nur, wenn Du 7zG.exe über CMD startest.

Gruß Musashi

**Musashi**

Nachtrag :

1.

Zum Kopieren/Verschieben bietet sich auch die schöne UDF _FileCopyEx von Oscar an !

2. Demoskript mit dem Progressfenster von 7zG.exe selbst :

- Lege Dir ein Verzeichnis an, z.B. C:\Ziptest

Kopiere folgende Dateien (zu Testzwecken) dort hinéin :

- Das Demoskript (s.u.)

- 7zG.exe (findest Du im Dir der Vollinstallation von 7-Zip) -> ansonsten siehe Anhang

- 7z.dll (findest Du im Dir der Vollinstallation von 7-Zip) -> ansonsten siehe Anhang

---> hipfzwirgel : EDIT - hier hatte ich voher versehentlich 7-zip.dll angegeben

- eine große Datei (mit Source.zip benennen)

==> Ergebnis : die Datei Destination.zip im Skriptordner

C

; Zippen mit 7zG.exe :
#include <AutoItConstants.au3>
#include <MsgBoxConstants.au3>

Global $iStatus, $sCommand

$sCommand = '7zG a -y -tzip "' & @ScriptDir & '\Destination.zip" "' & @ScriptDir & '\Source.zip"'
$iStatus = RunWait($sCommand, "", @SW_SHOW, BitOR($STDOUT_CHILD, $STDERR_CHILD))
If Not @error Then
    If $iStatus == 0 Then
        Msgbox($MB_ICONQUESTION, "Meldung Verschieben : ", " Soll der Content kopiert werden ? " & @CRLF & @CRLF)
        ; ==> Hier Code zum Verschieben einfügen
    Else
        Msgbox($MB_ICONERROR, "Fehler : ", " Befehlssyntax fehlerhaft ! " & @CRLF & @CRLF)
    EndIf
Else
    Msgbox($MB_ICONERROR, "Fehler : ", "Befehl nicht gefunden ! " & $iStatus & @CRLF & @CRLF)
EndIf

Alles anzeigen

Ob das auch läuft, wenn man es innerhalb einer AutoIt-GUI aufruft habe ich (noch) nicht probiert

EDIT : siehe nächsten Beitrag (mit AutoIt-GUI)

Gruß Musashi

**Musashi**

Nachtrag 2 :

Zitat von Musashi

Ob das auch läuft, wenn man es innerhalb einer AutoIt-GUI aufruft habe ich (noch) nicht probiert

So, offenbar läuft es auch, wenn man 7zG.exe aus einer GUI aufruft (ohne COMSPEC !)

Demoskript 2 : Dateien wie in Beitrag #3 Punkt 2 beschrieben anlegen.

C

#AutoIt3Wrapper_UseUpx = N ; interne UPX Komprimierung ausschalten (Default=Y)

#include <GUIConstantsEx.au3>
#include <Constants.au3>
#include <AutoItConstants.au3>
#include <MsgBoxConstants.au3>

_Main()

Func _Main()
    Local $iGuiMsg, $idBtnZippen, $idBtnCancel, $iStatusLabel
    Local $iStatus, $sCommand

    GUICreate("TestGUI :", 600, 250, -1, -1)
    GUISetBkColor(0xFFFFFF)
    GUICtrlCreateLabel("Testprogramm für 7zG.exe in einer GUI", 10, 10, 500, 35)
     GUICtrlSetFont(-1, 12, 800)
    GUICtrlCreateLabel('  -> "Startet einen ZIP-Prozess', 10, 60, 600, 35)
     GUICtrlSetFont(-1, 12, 600)
    $idBtnZippen = GUICtrlCreateButton("Start ZIP", 100, 150, 150, 40)
    $idBtnCancel = GUICtrlCreateButton("Abbrechen", 300, 150, 150, 40)

    GUISetState()
    While 1
        $iGuiMsg = GUIGetMsg()
        Select
            Case $iGuiMsg = $GUI_EVENT_CLOSE
                ExitLoop

            Case $iGuiMsg = $idBtnZippen
                $sCommand = '7zG a -y -tzip "' & @ScriptDir & '\Destination.zip" "' & @ScriptDir & '\Source.zip"'
                $iStatus = RunWait($sCommand, "", @SW_SHOW, BitOR($STDOUT_CHILD, $STDERR_CHILD))
                If Not @error Then
                    If $iStatus == 0 Then
                        Msgbox($MB_ICONQUESTION, "Meldung Verschieben : ", " Soll der Content kopiert werden ? " & @CRLF & @CRLF)
                        ; ==> Hier Code zum Verschieben einfügen
                    Else
                        Msgbox($MB_ICONERROR, "Fehler : ", " Befehlssyntax fehlerhaft ! " & @CRLF & @CRLF)
                    EndIf
                Else
                    Msgbox($MB_ICONERROR, "Fehler : ", "Befehl nicht gefunden ! " & @CRLF & @CRLF)
                EndIf
                ExitLoop

            Case $iGuiMsg = $idBtnCancel
                ExitLoop
        EndSelect
    WEnd
    GUIDelete()
EndFunc    ;==>_Main

Alles anzeigen

Gruß Musashi