Erstellt eine Checkbox für die GUI.
GUICtrlCreateCheckbox ( "text", left, top [, width [, height [, style = -1 [, exStyle = -1]]]] )
text | Die Beschriftung der Checkbox. |
left | Die linke Seite des Controls. Wird -1 verwendet, dann wird left mit Hilfe von GUICoordMode berechnet. |
top | Die Oberkante des Controls. Wird -1 verwendet, dann wird top mit Hilfe von GUICoordMode berechnet. |
width | [optional] Die Breite des Controls (Standard: Länge des Textes). |
height | [optional] Die Höhe des Controls (Standard: Höhe des Textes). |
style | [optional] Legt den Stil des Controls fest. Siehe Anhang GUI-Stile für Controls. Standard ( -1) : $BS_AUTOCHECKBOX. Erzwungene Stile : $WS_TABSTOP und $BS_AUTOCHECKBOX, wenn kein Checkbox-Stil angegeben wurde. |
exStyle | [optional] Legt den erweiterten Stil des Controls fest. Siehe Tabelle der erweiterten Stile. |
Erfolg: | Die Identifikationsnummer (Control-ID) des neuen Controls. |
Fehler: | 0. |
Um den Wert des Controls zu erhalten, siehe GUICtrlRead().
Um Informationen im Control zu setzen oder zu verändern, siehe GUICtrlUpdate... Funktionen.
Eine Checkbox-Control kann ein Icon oder Bild anzeigen, wenn der Stil $BS_ICON oder $BS_BITMAP verwendet wurde. Um das Bild festzulegen, ist GUICtrlSetImage() zu verwenden.
Um weitere Stile zusätzlich zum Standardstil zu verwenden, ist BitOR ( $GUI_SS_DEFAULT_CHECKBOX, newstyle, ... ) zu verwenden.
Um die oben angegebenen Werte verwenden zu können, muss #include <ButtonConstants.au3> in das Skript eingefügt werden.
Als Standard für das Verhalten des Controls (bzgl. Größe und/oder Position) bei Größenänderung der GUI gilt $GUI_DOCKHEIGHT. (Die Höhe wird nicht geändert.)
Mögliche Resizing-Parameter siehe GUICtrlSetResizing.
- - - - - - - - Erklärung der Controls - - - - - - - -
GUICoordMode (Option), GUICtrlUpdate..., GUIGetMsg
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
Example()
Func Example()
; Erstellt eine GUI mit verschiedenen Controls.
Local $hGui = GUICreate("Example", 300, 200)
; Erstellt ein Checkbox-Control.
Local $idCheckbox = GUICtrlCreateCheckbox("Standard Checkbox", 10, 10, 185, 25)
Local $idButton_Close = GUICtrlCreateButton("Close", 210, 170, 85, 25)
; Zeigt die GUI
GUISetState(@SW_SHOW, $hGui)
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE, $idButton_Close
ExitLoop
Case $idCheckbox
If _IsChecked($idCheckbox) Then
MsgBox($MB_SYSTEMMODAL, "", "Die Checkbox ist angehakt.", 0, $hGui)
Else
MsgBox($MB_SYSTEMMODAL, "", "Die Checkbox ist nicht angehakt.", 0, $hGui)
EndIf
EndSwitch
WEnd
; Löscht die vorherige GUI und alle Controls.
GUIDelete($hGui)
EndFunc ;==>Example
Func _IsChecked($idControlID)
Return BitAND(GUICtrlRead($idControlID), $GUI_CHECKED) = $GUI_CHECKED
EndFunc ;==>_IsChecked