GUICtrlCreateDate

Beschreibung anzeigen in

Erstellt ein Datumsauswahl-Item für die GUI.

GUICtrlCreateDate ( "text", left, top [, width [, height [, style = -1 [, exStyle = -1]]]] )

Parameter

text	Das voreingestellte Datum (immer im Format "yyyy/mm/dd").
left	Die linke Seite des Controls. Wird -1 verwendet, dann wird left mit Hilfe von GUICoordMode berechnet.
top	Die Oberkante des Controls. Wird -1 verwendet, dann wird top mit Hilfe von GUICoordMode berechnet.
width	[optional] Die Breite des Controls (voreingestellt ist die zuvor verwendete Breite).
height	[optional] Die Höhe des Controls (voreingestellt ist die zuvor verwendete Höhe).
style	[optional] Legt den Stil des Controls fest. Siehe Anhang GUI-Stile für Controls. Standard (-1) : $DTS_LONGDATEFORMAT Erzwungener Stil : $WS_TABSTOP
exStyle	[optional] Legt den erweiterten Stil des Controls fest. Siehe Tabelle der erweiterten Stile. Standard (-1) : WS_EX_CLIENTEDGE

Rückgabewert

Erfolg:	Die Identifikationsnummer (Control-ID) des neuen Controls.
Fehler:	0.

Bemerkungen

Um den Wert des Controls zu erhalten siehe GUICtrlRead().
Um Informationen im Control zu setzen oder zu verändern siehe GUICtrlUpdate...() Funktionen.

Um weitere Stile zusätzlich zum Standardstil zu verwenden ist BitOR($GUI_SS_DEFAULT_DATE, newstyle, ... ) zu verwenden.
Um die oben angegebenen Werte verwenden zu können, muss #include <DateTimeConstants.au3> in das Skript eingefügt werden.

Um das Datum bzw. die Zeit zu formatieren siehe Beispiel 3. Dort wird erklärt, wie GUICtrlSendMsg() mit $DTM_SETFORMAT verwendet werden muss.

Als Standard für das Verhalten des Controls (bzgl. Größe und/oder Position) bei Größenänderung der GUI gilt $GUI_DOCKHEIGHT. (Die Höhe wird nicht geändert.)
Mögliche Resizing-Parameter siehe GUICtrlSetResizing.

Es ist auch möglich das UpDown-Control zu entfernen. Dies wird im folgenden beschrieben.
In Windows ist jedes Control ein Fenster. Somit ist das Updown ein Child des DateTime-Controls.
Mit der folgenden Zeile wird das Child-Handle ermittelt und dieses ausgeblendet
WinSetState(_WinAPI_GetWindow(GUICtrlGetHandle($DTP), $GW_CHILD), '', @SW_HIDE)

- - - - - - - - Erklärung der Controls - - - - - - - -

Beispiel

Beispiel 1

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    GUICreate("Meine GUI ermittelt das Datum", 200, 200, 800, 200)
    Local $idDate = GUICtrlCreateDate("1953/04/25", 10, 10, 185, 20)
    GUISetState(@SW_SHOW)

    ; Die Schleife wiederholt sich, bis der Benutzer eine Beenden-Aktion auslöst
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop

        EndSwitch
    WEnd

    MsgBox($MB_SYSTEMMODAL, "Datum", GUICtrlRead($idDate))
    GUIDelete()
EndFunc   ;==>Example

Beispiel 2

#include <DateTimeConstants.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    GUICreate("Meine GUI ermittelt das Datum", 200, 200, 800, 200)
    Local $idDate = GUICtrlCreateDate("", 10, 10, 100, 20, $DTS_SHORTDATEFORMAT)
    GUISetState(@SW_SHOW)

    ; Die Schleife wiederholt sich, bis der Benutzer eine Beenden-Aktion auslöst
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop

        EndSwitch
    WEnd

    MsgBox($MB_SYSTEMMODAL, "Datum", GUICtrlRead($idDate))
    GUIDelete()
EndFunc   ;==>Example

Beispiel 3

#include <DateTimeConstants.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    GUICreate("Meine GUI ermittelt das Datum", 200, 200, 800, 200)
    Local $idDate = GUICtrlCreateDate("1953/04/25", 10, 10, 185, 20)

    ; Um ein bestimmtes Standardformat auszuwählen
    Local $sStyle = "yyyy/MM/dd HH:mm:ss"
    GUICtrlSendMsg($idDate, $DTM_SETFORMATW, 0, $sStyle)

    GUISetState(@SW_SHOW)

    ; Die Schleife wiederholt sich, bis der Benutzer eine Beenden-Aktion auslöst
    While GUIGetMsg() <> $GUI_EVENT_CLOSE
    WEnd

    MsgBox($MB_SYSTEMMODAL, "Zeit", GUICtrlRead($idDate))
EndFunc   ;==>Example

Beispiel 4

#include <DateTimeConstants.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    GUICreate("Meine GUI ermittelt die Zeit", 200, 200, 800, 200)
    Local $idDate = GUICtrlCreateDate("", 20, 20, 100, 20, $DTS_TIMEFORMAT)
    GUISetState(@SW_SHOW)

    ; Die Schleife wiederholt sich, bis der Benutzer eine Beenden-Aktion auslöst
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop

        EndSwitch
    WEnd

    MsgBox($MB_SYSTEMMODAL, "Zeit", GUICtrlRead($idDate))
    GUIDelete()
EndFunc   ;==>Example

Funktionreferenz