Funktionreferenz

TrayCreateMenu

Beschreibung anzeigen in

Erstellt ein Menü-Control für das Traymenü.

TrayCreateMenu ( "sub/menutext" [, menuID = -1 [, menuentry = -1]] )

Parameter

sub/menutext Der Ersatztext bzw. Menütext.
menuID [optional] Falls festgelegt erlaubt es, ein Untermenü in dem gewünschten Menü zu erstellen. Standardwert: -1 (es wird das erste Menü verwendet)
menuentry [optional] Erlaubt es die Eintragsnummer zu erstellen. Die Einträge starten bei 0. Standardwert: -1 (unten)

Rückgabewert

Erfolg: Die ID (Control-ID) des neuen Traymenüs.
Fehler: 0.

Verwandte Funktionen

TrayGetMsg, TrayItemDelete, TrayItemSetState, TrayItemSetText

Beispiel

#include <MsgBoxConstants.au3>
#include <StringConstants.au3>
#include <TrayConstants.au3> ; wird für die $TRAY_ICONSTATE_SHOW Konstante benötigt.

#NoTrayIcon

Opt("TrayMenuMode", 3) ; Die Standard Traymenüeinträge (Skript pausieren/beenden) werden nicht angezeigt und die Items werden nicht angehakt wenn diese ausgewählt werden. Verwendet wurden die Optionen 1 und 2 für TrayMenuMode.

Example()

Func Example()
    Local $idSettings = TrayCreateMenu("Settings") ; Erstellt ein Traymenü mit zwei Untermenüs.
    Local $idDisplay = TrayCreateItem("Display", $idSettings)
    Local $idPrinter = TrayCreateItem("Printer", $idSettings)
    TrayCreateItem("") ; Erzeugt einen Trennstrich.

    Local $idAbout = TrayCreateItem("Über")
    TrayCreateItem("") ; Erzeugt einen Trennstrich.

    Local $idExit = TrayCreateItem("Exit")

    TraySetState($TRAY_ICONSTATE_SHOW) ; Zeigt das Traymenü.

    While 1
        Switch TrayGetMsg()
            Case $idAbout ; Zeigt ein Nachrichtenfenster mit der AutoIt Version und dem Installationspfad der AutoIt Startdatei.
                MsgBox($MB_SYSTEMMODAL, "", "AutoIt tray menu example." & @CRLF & @CRLF & _
                        "Version: " & @AutoItVersion & @CRLF & _
                        "Install Path: " & StringLeft(@AutoItExe, StringInStr(@AutoItExe, "\", $STR_NOCASESENSEBASIC, -1) - 1)) ; Ermittelt den Ordner eines kompletten Pfads.

            Case $idDisplay, $idPrinter
                MsgBox($MB_SYSTEMMODAL, "", "A sub menu item was selected from the tray menu.")

            Case $idExit ; Beendet die Schleife.
                ExitLoop
        EndSwitch
    WEnd
EndFunc   ;==>Example