Leert die Zwischenablage und gibt die Verweise (Handles) auf die Daten in der Zwischenablage frei
#include <Clipboard.au3>
_ClipBoard_Empty ( )
Erfolg: | True |
Fehler: | False |
Vor dem Aufruf dieser Funktion muss die Zwischenablage mit der Funktion _ClipBoard_Open() geöffnet worden sein.
Wenn beim Öffnen der Zwischenablage ein NULL Fensterverweis angegeben wurde, wird diese Funktion erfolgreich sein, setzt aber den Besitzer der Zwischenablage auf NULL.
Es ist zu beachten, das dadurch _ClipBoard_SetData() fehlschlagen wird.
_ClipBoard_GetOwner, _ClipBoard_Open, _ClipBoard_SetData, _ClipBoard_SetDataEx
Suche nach EmptyClipboard in der MSDN Bibliothek.
#include <Clipboard.au3>
#include <GUIConstantsEx.au3>
#include <WinAPIError.au3>
#include <WindowsConstants.au3>
Global $g_idMemo
Example()
Func Example()
Local $hGui
; Erstellt eine GUI
$hGui = GUICreate("Clipboard", 600, 400)
$g_idMemo = GUICtrlCreateEdit("", 2, 2, 596, 396, $WS_VSCROLL)
GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
GUISetState(@SW_SHOW)
; Öffnet die Zwischenablage
If _ClipBoard_Open($hGui) Then
ShowData($hGui)
; Leert die Zwischenablage
If Not _ClipBoard_Empty() Then _WinAPI_ShowError("_ClipBoard_Empty fehlgeschlagen")
; Schließt die Zwischenablage
_ClipBoard_Close()
Else
_WinAPI_ShowError("_ClipBoard_Open failed")
EndIf
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>Example
; Zeigt die Statistik der Zwischenablage
Func ShowData($hGui)
MemoWrite("GUI Handle ................: " & $hGui)
MemoWrite("Clipboard Besitzer ........: " & _ClipBoard_GetOwner())
MemoWrite("Für Clipboard geöffnetes Fenster .: " & _ClipBoard_GetOpenWindow())
MemoWrite("Clipboard Sequenz .........: " & _ClipBoard_GetSequenceNumber())
MemoWrite()
EndFunc ;==>ShowData
; Schreibt eine Nachricht in das Memo
Func MemoWrite($sMessage = "")
GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite