Funktionreferenz

_Date_Time_FileTimeToDOSDateTime

Beschreibung anzeigen in

Konvertiert Datei Datum/Zeit in MS-DOS Datum/Zeit

#include <Date.au3>
_Date_Time_FileTimeToDOSDateTime ( $tFileTime )

Parameter

$tFileTime Eine $tagFILETIME Struktur, die ein Datei-Datum/Zeit beinhaltet, die ins MS-DOS Format konvertiert werden soll oder einen Pointer zu dieser

Rückgabewert

Gibt ein Array mit dem folgenden Format zurück:
    [0] - MS-DOS Datum, verpackt wie folgt:
        Bits 0- 4 Tag des Monats (1–31)
        Bits 5- 8 Monat (1 = Januar, 2 = Februar und so weiter)
        Bits 9-15 Offset des Jahres von 1980 aus gesehen (es ist 1980 hinzuzuaddieren, um das aktuelle Jahr zu bekommen)
    [1] - MS-DOS Zeit, verpackt wie folgt:
        Bits 0- 4 Sekunden zweigeteilt
        Bits 5-10 Minuten (0–59)
        Bits 11-15 Stunden (0–23 im 24h-Format)

Verwandte Funktionen

$tagFILETIME, _Date_Time_DOSDateTimeToFileTime, _Date_Time_FileTimeToLocalFileTime, _Date_Time_FileTimeToSystemTime

Beispiel

#include <Date.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $tFile, $aDOS

    ; Erstellen der GUI
    GUICreate("Zeit", 400, 300)
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Entschlüsseln der Datei Zeit
    $tFile = _Date_Time_EncodeFileTime(@MON, @MDAY, @YEAR, @HOUR, @MIN, @SEC)
    $aDOS = _Date_Time_FileTimeToDOSDateTime($tFile)
    MemoWrite("DOS date .: 0x" & Hex($aDOS[0], 4))
    MemoWrite("DOS time .: 0x" & Hex($aDOS[1], 4))

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Schreibt eine Zeile in das Memo Control
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite