Funktionreferenz


_GDIPlus_ArrowCapSetHeight

Beschreibung anzeigen in

Setzt die Höhe der Pfeilspitze

#include <GDIPlus.au3>
_GDIPlus_ArrowCapSetHeight ( $hArrowCap, $fHeight )

Parameter

$hArrowCap Handle zu dem Pfeil-Objekt
$fHeight Bestimmt die Länge (in Unites) des Pfeils von der Basis zu seiner Spitze

Rückgabewert

Erfolg: True
Fehler: False und setzt das @error Flag auf ungleich null. @extended kann den GPSTATUS Fehlercode ($GPID_ERR* siehe GDIPlusConstants.au3) enthalten.

Verwandte Funktionen

_GDIPlus_ArrowCapGetHeight

Siehe auch

Suche nach GdipSetAdjustableArrowCapHeight in der MSDN Bibliothek.

Beispiel

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $hGui, $hGraphic, $hPen, $hEndCap

    ; Erstellt eine GUI
    $hGui = GUICreate("GDI+", 400, 300)
    GUISetState(@SW_SHOW)

    ; Erzeugt die Ressourcen
    _GDIPlus_Startup()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGui)
    $hPen = _GDIPlus_PenCreate(0xFF000000, 4)
    $hEndCap = _GDIPlus_ArrowCapCreate(3, 6)
    _GDIPlus_PenSetCustomEndCap($hPen, $hEndCap)

    ; Zeichnet Pfeil 1
    _GDIPlus_GraphicsDrawLine($hGraphic, 10, 120, 390, 120, $hPen)

    ; Zeichnet Pfeil 2
    _GDIPlus_ArrowCapSetHeight($hEndCap, _GDIPlus_ArrowCapGetHeight($hEndCap) + 2)
    _GDIPlus_PenSetCustomEndCap($hPen, $hEndCap)
    _GDIPlus_GraphicsDrawLine($hGraphic, 10, 150, 390, 150, $hPen)

    ; Zeichnet Pfeil 3
    _GDIPlus_ArrowCapSetHeight($hEndCap, _GDIPlus_ArrowCapGetHeight($hEndCap) + 2)
    _GDIPlus_PenSetCustomEndCap($hPen, $hEndCap)
    _GDIPlus_GraphicsDrawLine($hGraphic, 10, 180, 390, 180, $hPen)

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Ressourcen freigeben
    _GDIPlus_ArrowCapDispose($hEndCap)
    _GDIPlus_PenDispose($hPen)
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_Shutdown()
EndFunc   ;==>Example