Funktionreferenz

_GDIPlus_ImageGetPixelFormat

Beschreibung anzeigen in

Gibt das Pixelformat eines Bildes zurück: Anzahl Bits pro Pixel, Alpha Kanäle, RGB, Graustufen, indizierte Farbtabelle etc

#include <GDIPlus.au3>
_GDIPlus_ImageGetPixelFormat ( $hImage )

Parameter

$hImage Handle auf ein Bild-Objekt

Rückgabewert

Erfolg: Array mit dem folgenden Format:
    [0] - Pixelformat als Integer-Konstante
    [1] - String mit Beschreibung des Pixelformats
Fehler: Gibt ein leeres Array zurück und setzt das @error Flag auf ungleich null, @extended kann den GPSTATUS Fehlercode ($GPID_ERR* siehe GDIPlusConstants.au3) enthalten.
@error: 10 - Ungültiges Pixel-Format.
11 - Ungültiges Handle des Bild-Objekts.
12 - Ungültiges Pixel-Format.

Verwandte Funktionen

_GDIPlus_BitmapCloneArea, _GDIPlus_BitmapLockBits, _GDIPlus_ImageGetFlags

Siehe auch

Suche nach GdipGetImagePixelFormat in der MSDN Bibliothek.

Beispiel

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <ScreenCapture.au3>
#include <WinAPIHObj.au3>
#include <WindowsConstants.au3>


Global $g_idMemo

Example()

Func Example()
    Local $hBitmap, $hImage, $aRet

    ; Erstellt eine GUI
    GUICreate("GDI+", 600, 400)
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 596, 396, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Initialisiert (startet) Microsoft Windows GDI+
    _GDIPlus_Startup()

    ; Erstellt vom kompletten Bildschirm einen Screenshot und erzeugt daraus eine 32 bit Bitmap
    $hBitmap = _ScreenCapture_Capture("")
    $hImage = _GDIPlus_BitmapCreateFromHBITMAP($hBitmap)

    ; Gibt das Pixelformat des Screenshots zurück
    $aRet = _GDIPlus_ImageGetPixelFormat($hImage)
    MemoWrite("String mit Beschreibung des Pixelformats: " & $aRet[1]);
    MemoWrite("Pixelformat als Integer-Konstante             : " & $aRet[0]);
    MemoWrite();

    ; Speichert den Screenshot-Bitmap in eine Datei
    _GDIPlus_ImageSaveToFile($hImage, @MyDocumentsDir & "\GDIPlus_Image.jpg")

    ; Ressourcen freigeben
    _GDIPlus_ImageDispose($hImage)
    _WinAPI_DeleteObject($hBitmap)

    ; Lädt das Screenshot-Bitmap von einer Datei
    $hImage = _GDIPlus_ImageLoadFromFile(@MyDocumentsDir & "\GDIPlus_Image.jpg")

    ; Gibt das Pixelformat der gespeicherten Datei zurück
    $aRet = _GDIPlus_ImageGetPixelFormat($hImage)
    MemoWrite("String mit Beschreibung des Pixelformats: " & $aRet[1]);
    MemoWrite("Pixelformat als Integer-Konstante             : " & $aRet[0]);

    ; Ressourcen freigeben
    _GDIPlus_ImageDispose($hImage)

    ; Gibt die durch Microsoft Windows GDI+ verwendeten Ressourcen wieder frei
    _GDIPlus_Shutdown()

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Gibt eine Zeile im Memo-Fenster aus
Func MemoWrite($sMessage = '')
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite