Creates a GraphicsPath object and initializes the fill mode
#include <GDIPlus.au3>
_GDIPlus_PathCreate ( [$iFillMode = 0] )
| $iFillMode | [optional] Fill mode of the interior of the path figures: 0 - The areas are filled according to the even-odd parity rule 1 - The areas are filled according to the nonzero winding rule |
| Success: | a handle to a new GraphicsPath object. |
| Failure: | 0 and sets the @error flag to non-zero, @extended may contain GPSTATUS error code ($GPIP_ERR* see GPIPlusConstants.au3). |
After you are done with the object, call _GDIPlus_PathDispose() to release the object resources.
_GDIPlus_PathCreate2, _GDIPlus_PathDispose
Suche nach GdipCreatePath in der MSDN Bibliothek.
#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
Example()
Func Example()
Local $hGUI, $hGraphic, $hBrush, $hPen, $hPath, $hFamily, $tLayout
; Create GUI
$hGUI = GUICreate("GDI+", 420, 160)
GUISetState(@SW_SHOW)
; Draw a string using path
_GDIPlus_Startup()
$hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI) ;Create a graphics object from a window handle
$hBrush = _GDIPlus_BrushCreateSolid(0xFFDD2200)
$hPen = _GDIPlus_PenCreate(0xFFFFBB00, 2)
$hPath = _GDIPlus_PathCreate() ;Create new path object
$hFamily = _GDIPlus_FontFamilyCreate("Arial") ;Create font family object
$tLayout = _GDIPlus_RectFCreate() ;Create string bounding rectangle X=0, Y=0
_GDIPlus_PathAddString($hPath, "AutoIt rulez!", $tLayout, $hFamily, 0, 72, 0) ;Add the outline of the string to the path
_GDIPlus_GraphicsSetSmoothingMode($hGraphic, $GDIP_SMOOTHINGMODE_HIGHQUALITY) ;Sets the graphics object rendering quality (antialiasing)
_GDIPlus_GraphicsClear($hGraphic, 0xFF000000)
_GDIPlus_GraphicsFillPath($hGraphic, $hPath, $hBrush) ;Fill path to graphics handle (GUI)
_GDIPlus_GraphicsDrawPath($hGraphic, $hPath, $hPen) ;Draw path to graphics handle (GUI)
; Loop until the user exits.
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
; Clean up resources
_GDIPlus_FontFamilyDispose($hFamily)
_GDIPlus_PathDispose($hPath)
_GDIPlus_PenDispose($hPen)
_GDIPlus_BrushDispose($hBrush)
_GDIPlus_GraphicsDispose($hGraphic)
_GDIPlus_Shutdown()
EndFunc ;==>Example