Funktionreferenz


_GDIPlus_PenSetDashCap

Beschreibung anzeigen in

Setzt den Stil der Strich-Endkappe des Zeichenstiftes

#include <GDIPlus.au3>
_GDIPlus_PenSetDashCap ( $hPen [, $iDash = 0] )

Parameter

$hPen Handle zu einem Zeichenstift-Objekt
$iDash [optional] Stil der einzelnen Striche. Kann einer der folgenden sein:
$GDIP_DASHCAPFLAT - Eine quadratische Endkappe, die beide Enden jeder Linie abflacht
$GDIP_DASHCAPROUND - Eine kreisförmige Endkappe, die beide Enden jeder Linie abrundet
$GDIP_DASHCAPTRIANGLE - Eine dreieckige Endkappe, die beide Enden jeder Linie anspitzt

Rückgabewert

Erfolg: True
Fehler: False und setzt das @error Flag auf ungleich null, das @extended Flag kann den GPSTATUS-Fehlercode ($GPID_ERR* siehe GDIPlusConstants.au3) enthalten.

Verwandte Funktionen

_GDIPlus_PenGetDashCap

Siehe auch

Suche nach GdipSetPenDashCap197819 in der MSDN Bibliothek.

Beispiel

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $hGui, $hGraphic, $hPen

    ; Erstellt eine GUI
    $hGui = GUICreate("GDI+", 400, 300)
    GUISetState(@SW_SHOW)

    ; Erzeugt die Ressourcen
    _GDIPlus_Startup()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGui)
    $hPen = _GDIPlus_PenCreate(0xFF000000, 8)
    _GDIPlus_PenSetDashStyle($hPen, $GDIP_DASHSTYLEDASHDOT)
    _GDIPlus_PenSetDashCap($hPen, $GDIP_DASHCAPTRIANGLE)

    ; Den Stil der Strich-Endkappe des Zeichenstiftes anzeigen
    MsgBox($MB_SYSTEMMODAL, "Information", "Strich-Endkappe des Zeichenstiftes: " & _GDIPlus_PenGetDashCap($hPen))

    ; Zeichnet eine Linie
    _GDIPlus_GraphicsDrawLine($hGraphic, 10, 150, 390, 150, $hPen)

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Ressourcen freigeben
    _GDIPlus_PenDispose($hPen)
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_Shutdown()
EndFunc   ;==>Example