_GUICtrlAVI_Stop
Beschreibung anzeigen in
Stoppt einen spielenden AVI-Clip
#include <GuiAVI.au3>
_GUICtrlAVI_Stop ( $hWnd )
Parameter
| $hWnd | Control-ID / Handle des Controls |
Rückgabewert
| Erfolg: | True |
| Fehler: | False |
Bemerkungen
- - - - - - - - Erklärung der Controls - - - - - - - -
Verwandte Funktionen
Beispiel
Beispiel 1
; verwendet die AuotIt-Funktion
#include <GuiAVI.au3>
#include <GUIConstantsEx.au3>
_Example_Internal()
Func _Example_Internal()
Local $idAVI, $idBtn_Start, $idBtn_Stop
; Erstellt eine GUI
GUICreate("AVI: Abspielen / Stoppen (Intern)", 300, 200)
$idAVI = GUICtrlCreateAvi(@SystemDir & "\shell32.dll", 160, 10, 10)
$idBtn_Start = GUICtrlCreateButton("Start", 50, 150, 70, 22)
$idBtn_Stop = GUICtrlCreateButton("Stopp", 150, 150, 70, 22)
GUISetState(@SW_SHOW)
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
ExitLoop
Case $idBtn_Start
; Spielt einen Tel des AVI Clips ab
_GUICtrlAVI_Play($idAVI)
Case $idBtn_Stop
; Stoppt den AVI Clip
_GUICtrlAVI_Stop($idAVI)
EndSwitch
WEnd
; Schließt den AVI Clip
_GUICtrlAVI_Close($idAVI)
GUIDelete()
EndFunc ;==>_Example_Internal
Beispiel 2
; verwendet die UDF
#include <GuiAVI.au3>
#include <GUIConstantsEx.au3>
_Beispiel_External()
Func _Beispiel_External()
Local $hGui, $hAVI, $idBtn_Start, $idBtn_Stop
; Erstellt eine GUI
$hGui = GUICreate("AVI: Abspielen (Extern)", 300, 200)
$hAVI = _GUICtrlAVI_Create($hGui, @SystemDir & "\Shell32.dll", 160, 10, 10)
$idBtn_Start = GUICtrlCreateButton("Start", 50, 150, 70, 22)
$idBtn_Stop = GUICtrlCreateButton("Stopp", 150, 150, 70, 22)
GUISetState(@SW_SHOW)
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
ExitLoop
Case $idBtn_Start
; Spielt einen Tel des AVI Clips ab
_GUICtrlAVI_Play($hAVI)
Case $idBtn_Stop
; Stoppt den AVI Clip
_GUICtrlAVI_Stop($hAVI)
EndSwitch
WEnd
; Schließt den AVI Clip
_GUICtrlAVI_Close($hAVI)
GUIDelete()
EndFunc ;==>_Beispiel_External