Funktionreferenz

_GUICtrlComboBoxEx_FindStringExact

Beschreibung anzeigen in

Sucht einen exakten String

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_FindStringExact ( $hWnd, $sText [, $iIndex = -1] )

Parameter

$hWnd Handle des Controls
$sText zu suchender String
$iIndex [optional] 0-basierender Index des Items bei dem die Suche beginnen soll

Rückgabewert

Erfolg: ein 0-basierender Index des gefundenen Items
Fehler: -1

Bemerkungen

Findet den ersten String welcher mit den festgelegten Zeichen von $sText beginnt

Wenn die Suche das Ende der Listbox erreicht, wird sie am Anfang der Listbox fortgesetzt bis zu dem in $iIndex festgelegten Item.

Falls $iIndex –1 ist, wird die komplette Listbox von Anfang an durchsucht.

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlComboBox_SelectString

Beispiel

#include <GuiComboBoxEx.au3>
#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $hGui, $hImage, $sDelimiter = ";", $hCombo

    Opt("GUIDataSeparatorChar", $sDelimiter)

    ; Erstellt eine GUI
    $hGui = GUICreate("ComboBoxEx: Sucht einen exakten String", 400, 300)
    $hCombo = _GUICtrlComboBoxEx_Create($hGui, "Dies ist;meIN tExT", 2, 2, 394, 100, $CBS_SIMPLE)
    GUISetState(@SW_SHOW)

    $hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 110)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 131)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 165)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 168)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 137)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 146)
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x0000FF, 16, 16))
    _GUICtrlComboBoxEx_SetImageList($hCombo, $hImage)

    _GUICtrlComboBoxEx_BeginUpdate($hCombo)
    For $x = 0 To 8
        _GUICtrlComboBoxEx_AddString($hCombo, StringFormat("%03d : Zufallstring", Random(1, 100, 1)), $x, $x)
    Next
    _GUICtrlComboBoxEx_EndUpdate($hCombo)

    ; Sucht einen exakten String
    MsgBox($MB_SYSTEMMODAL, "Information", "Gefunden bei: " & _GUICtrlComboBoxEx_FindStringExact($hCombo, "meIN tExT"))

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example