Funktionreferenz

_GUICtrlComboBox_SelectString

Beschreibung anzeigen in

Durchsucht die ListBox der ComboBox nach einem Item, welches mit den Zeichen des festgelegten Strings beginnt

#include <GuiComboBox.au3>
_GUICtrlComboBox_SelectString ( $hWnd, $sText [, $iIndex = -1] )

Parameter

$hWnd Control-ID / Handle des Controls
$sText String der die zu suchenden Zeichen enthält
$iIndex [optional] legt den 0-basierenden Index des Items fest bei dem die Suche beginnen soll

Rückgabewert

Erfolg: Der Index des markierten Items
Fehler: -1

Bemerkungen

Wenn die Suche das Ende der Liste erreicht, wird sie am Anfang der Liste bis zu dem durch den wParam Parameter festgelegten Item fortgesetzt.

Falls $iIndex –1 ist, wird die komplette Liste vom Anfang an durchsucht.
Ein String wird nur markiert, wenn die Zeichen am Anfang des Ergebnisstrings stehen

Falls es eine Übereinstimmung gibt, wird es markiert und in das Edit-Control kopiert

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlComboBox_FindString, _GUICtrlComboBox_FindStringExact, _GUICtrlComboBoxEx_FindStringExact

Beispiel

#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $idCombo

    ; Erstellt eine GUI
    GUICreate("ComboBox: Einen String auswählen", 400, 296)
    $idCombo = GUICtrlCreateCombo("", 2, 2, 396, 296, BitOR($CBS_SIMPLE, $CBS_DISABLENOSCROLL, $WS_VSCROLL))
    GUISetState(@SW_SHOW)

    ; Fügt Dateien hinzu
    _GUICtrlComboBox_BeginUpdate($idCombo)
    _GUICtrlComboBox_AddDir($idCombo, @WindowsDir & "\*.exe")
    ; Fügt einen String hinzu
    _GUICtrlComboBox_AddString($idCombo, "Dieser String wurde hinzugefügt")
    ; Fügt Dateien hinzu
    _GUICtrlComboBox_AddDir($idCombo, "", $DDL_DRIVES, False)
    _GUICtrlComboBox_EndUpdate($idCombo)

    ; Wählt einen String aus
    _GUICtrlComboBox_SelectString($idCombo, "Dieser")

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example