Funktionreferenz

_GUICtrlListBox_AddString

Beschreibung anzeigen in

Fügt einen String hinzu

#include <GuiListBox.au3>
_GUICtrlListBox_AddString ( $hWnd, $sText )

Parameter

$hWnd Control-ID / Handle des Controls
$sText hinzuzufügender String

Rückgabewert

Erfolg: Ein 0-basierender Index des Strings
Fehler: -1

Bemerkungen

Falls es nicht genügend Speicher für den String gibt, lautet der Rückgabewert $LB_ERRSPACE.

Falls die Listbox den Stil $LBS_SORT nicht aufweist, wird der String am Ende der Liste eingefügt.
Andernfalls wird der String in die Liste eingefügt und die Liste ist somit sortiert.

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlListBox_AddFile, _GUICtrlListBox_DeleteString, _GUICtrlListBox_InitStorage, _GUICtrlListBox_InsertString

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiListBox.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $idListBox

    ; Erstellt eine GUI
    GUICreate("ListBox: Fügt einen String hinzu", 400, 296)
    $idListBox = GUICtrlCreateList("", 2, 2, 396, 296, BitOR($WS_BORDER, $WS_VSCROLL, $LBS_NOTIFY, $LBS_DISABLENOSCROLL, $WS_HSCROLL))

    GUISetState(@SW_SHOW)

    ; Fügt Strings hinzu
    _GUICtrlListBox_BeginUpdate($idListBox)
    For $iI = 1 To 9
        _GUICtrlListBox_AddString($idListBox, StringFormat("%03d : Zufallstring", Random(1, 100, 1)))
    Next
    _GUICtrlListBox_InsertString($idListBox, "Exakter teXt", 3)
    _GUICtrlListBox_InsertString($idListBox, "Dies ist der String nach dem wir suchen", 6)
    _GUICtrlListBox_InsertString($idListBox, _
            "Fügt einen langen String hinzu, so das die horizontale Scrollbar erscheint und " & _
            "der ganze Text angezeigt werden kann.", 9)
    _GUICtrlListBox_UpdateHScroll($idListBox)
    _GUICtrlListBox_EndUpdate($idListBox)

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example