Funktionreferenz

_GUICtrlListBox_InsertString

Beschreibung anzeigen in

Fügt einen String in die Liste ein

#include <GuiListBox.au3>
_GUICtrlListBox_InsertString ( $hWnd, $sText [, $iIndex = -1] )

Parameter

$hWnd Control-ID / Handle des Controls
$sText einzufügender Textstring
$iIndex [optional] legt den 0-basierenden Index der Position fest, wo der String eingefügt werden soll.
Falls dieser Parameter -1 ist, wird der String ans Ende der Liste angehängt.

Rückgabewert

Erfolg: der 0-basierende Index der Itemposition
Fehler: -1

Bemerkungen

Falls $iIndex -1, wird der String ans Ende der Liste angehängt. Im Gegensatz zu _GUICtrlListBox_AddString(), veranlasst diese Funktion nicht, dass die Liste mit dem Stil $LBS_SORT sortiert wird.

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlListBox_AddString, _GUICtrlListBox_DeleteString, _GUICtrlListBox_InitStorage

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiListBox.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $idListBox

    ; Erstellt eine GUI
    GUICreate("ListBox: Fügt einen String ein", 400, 296)
    $idListBox = GUICtrlCreateList("", 2, 2, 396, 296, BitOR($WS_BORDER, $LBS_NOTIFY, $LBS_DISABLENOSCROLL, $WS_HSCROLL))
    GUISetState(@SW_SHOW)

    ; Fügt Strings hinzu
    _GUICtrlListBox_BeginUpdate($idListBox)
    For $iI = 1 To 9
        _GUICtrlListBox_AddString($idListBox, StringFormat("%03d : Zufallstring", Random(1, 100, 1)))
    Next
    _GUICtrlListBox_InsertString($idListBox, "Fügt einen langen String hinzu, so das die horizontale Scrollbar erscheint und " & _
            "der ganze Text angezeigt werden kann.", 4)
    _GUICtrlListBox_UpdateHScroll($idListBox)
    _GUICtrlListBox_EndUpdate($idListBox)

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example