Funktionreferenz


_GUICtrlListBox_ClickItem

Beschreibung anzeigen in

Klick ein Item an

#include <GuiListBox.au3>
_GUICtrlListBox_ClickItem ( $hWnd, $iIndex [, $sButton = "left" [, $bMove = False [, $iClicks = 1 [, $iSpeed = 0]]]] )

Parameter

$hWnd Control-ID / Handle des Controls
$iIndex legt den 0-basierenden Index des Items fest
$sButton [optional] mit welchem Button geklickt werden soll
$bMove [optional] Falls True wird die Maus bewegt. Falls False, wird die Maus nicht bewegt.
$iClicks [optional] Anzahl von Klicks
$iSpeed [optional] Bewegungsgeschwindigkeit der Maus

Rückgabewert

Keine.

Bemerkungen

- - - - - - - - Erklärung der Controls - - - - - - - -

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiListBox.au3>

Example()

Func Example()
    Local $idListBox

    ; Erstellt eine GUI
    GUICreate("ListBox: Item anklicken", 400, 296)
    $idListBox = GUICtrlCreateList("", 2, 2, 396, 296)
    GUISetState(@SW_SHOW)

    ; Fügt Strings hinzu
    _GUICtrlListBox_BeginUpdate($idListBox)
    For $iI = 1 To 9
        _GUICtrlListBox_AddString($idListBox, StringFormat("%03d : Zufallstring", Random(1, 100, 1)))
    Next
    _GUICtrlListBox_EndUpdate($idListBox)

    ; Klickt ein Item an
    _GUICtrlListBox_ClickItem($idListBox, 4, "left", True)

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example