Funktionreferenz

_GUICtrlListBox_GetSelItems

Beschreibung anzeigen in

Füllt einen Puffer mit einem Array der markierten Items

#include <GuiListBox.au3>
_GUICtrlListBox_GetSelItems ( $hWnd )

Parameter

$hWnd Control-ID / Handle des Controls

Rückgabewert

Gibt ein Array mit dem folgenden Format zurück:
    [0] - Gesamtanzahl der Items im Array
    [1] - Index des markierten Items
    [2] - Index des markierten Items
    [n] - Index des markierten Items

Bemerkungen

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlListBox_GetSelItemsText

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiListBox.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $sItems, $aItems, $idListBox

    ; Erstellt eine GUI
    GUICreate("ListBox: Ermittelt die ausgewählten Items", 400, 296)
    $idListBox = GUICtrlCreateList("", 2, 2, 396, 296, BitOR($LBS_STANDARD, $LBS_EXTENDEDSEL))
    GUISetState(@SW_SHOW)

    ; Fügt Strings hinzu
    _GUICtrlListBox_BeginUpdate($idListBox)
    For $iI = 1 To 9
        _GUICtrlListBox_AddString($idListBox, StringFormat("%03d : Zufallstring", Random(1, 100, 1)))
    Next
    _GUICtrlListBox_EndUpdate($idListBox)

    ; Wählt einige Items aus
    _GUICtrlListBox_SetSel($idListBox, 3)
    _GUICtrlListBox_SetSel($idListBox, 4)
    _GUICtrlListBox_SetSel($idListBox, 5)

    ; Ermittelt die Idizes der ausgewählten Items
    $aItems = _GUICtrlListBox_GetSelItems($idListBox)
    For $iI = 1 To $aItems[0]
        If $iI > 1 Then $sItems &= ", "
        $sItems &= $aItems[$iI]
    Next
    MsgBox($MB_SYSTEMMODAL, "Information", "Ausgewählte Items: " & $sItems)

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example