Funktionreferenz

_GUICtrlListBox_GetText

Beschreibung anzeigen in

Ermittelt den Text des festgelegten Indexes

#include <GuiListBox.au3>
_GUICtrlListBox_GetText ( $hWnd, $iIndex )

Parameter

$hWnd Control-ID / Handle des Controls
$iIndex legt den 0-basierenden Index des zu ermittelnden Strings fest

Rückgabewert

Gibt den Itemstring zurück.

Bemerkungen

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlListBox_GetTextLen

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiListBox.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $idListBox

    ; Erstellt eine GUI
    GUICreate("ListBox: Text ermitteln", 400, 296)
    $idListBox = GUICtrlCreateList("", 2, 2, 396, 296, BitOR($LBS_STANDARD, $LBS_EXTENDEDSEL))
    GUISetState(@SW_SHOW)

    ; Fügt Strings hinzu
    _GUICtrlListBox_BeginUpdate($idListBox)
    For $iI = 1 To 9
        _GUICtrlListBox_AddString($idListBox, StringFormat("%03d : Zufallstring", Random(1, 100, 1)))
    Next
    _GUICtrlListBox_EndUpdate($idListBox)

    ; Zeigt den Itemtext
    MsgBox($MB_SYSTEMMODAL, "Information", "Item 5 Text: " & _GUICtrlListBox_GetText($idListBox, 4))

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example