Ersetzt den Text eines Items
#include <GuiListBox.au3>
_GUICtrlListBox_ReplaceString ( $hWnd, $iIndex, $sText )
$hWnd | Control-ID / Handle des Controls |
$iIndex | legt den 0-basierenden Index des Items fest |
$sText | String, mit dem der bisherige String ersetzt werden soll |
Erfolg: | True |
Fehler: | False |
- - - - - - - - Erklärung der Controls - - - - - - - -
#include <GUIConstantsEx.au3>
#include <GuiListBox.au3>
#include <MsgBoxConstants.au3>
Example()
Func Example()
Local $sText, $idListBox
; Erstellt eine GUI
GUICreate(" ListBox: Ersetzt den Text eines Items", 400, 296)
$idListBox = GUICtrlCreateList("", 2, 2, 396, 296, BitOR($LBS_STANDARD, $LBS_EXTENDEDSEL))
GUISetState(@SW_SHOW)
; Fügt Strings hinzu
_GUICtrlListBox_BeginUpdate($idListBox)
For $iI = 1 To 9
$sText = StringFormat("%03d : Zufallstring ", Random(1, 100, 1))
For $iX = 1 To Random(1, 20, 1)
$sText &= Chr(Random(65, 90, 1))
Next
_GUICtrlListBox_AddString($idListBox, $sText)
Next
_GUICtrlListBox_EndUpdate($idListBox)
; Ersetzt den Text eines Items
MsgBox($MB_SYSTEMMODAL, "Information", "Ersetzt den Text vom Index 3")
_GUICtrlListBox_ReplaceString($idListBox, 3, "erledigt")
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>Example