_GUICtrlListView_FindInText
Beschreibung anzeigen in
Sucht nach einem Item, welches den bestimmten Text irgendwo in seinem Text enthält
#include <GuiListView.au3>
_GUICtrlListView_FindInText ( $hWnd, $sText [, $iStart = -1 [, $bWrapOK = True [, $bReverse = False]]] )
Parameter
| $hWnd | Control-ID / Handle des Controls |
| $sText | zu suchender Text |
| $iStart | [optional] 0-basierender Index des Items, von wo die Suche beginnen soll oder -1 um vom Anfang zu beginnen. Das bestimmte Item wird bei der Suche ausgeschlossen. |
| $bWrapOK | [optional] Falls True, wird die Suche mit beim ersten Item fortgesetzt, falls nichts passendes gefunden wurde |
| $bReverse | [optional] Falls True wird die Suche bei $iStart - 1 bis 0 starten. Falls $bWrapOK = True wird die Suche fortgesetzt |
Rückgabewert
| Erfolg: | Der 0-basierende Index des Items |
| Fehler: | -1 |
Bemerkungen
Bei der Suche wird die Groß-/Kleinschreibung nicht beachtet. Die Suche funktioniert nur mit dem Item.
Im Gegensatz zu _GUICtrlListView_FindText() durchsucht diese Funktion auch alle Subitems nach dem Text.
- - - - - - - - Erklärung der Controls - - - - - - - -
Verwandte Funktionen
Beispiel
#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>
Example()
Func Example()
GUICreate("ListView: Sucht nach dem Zielitem (v" & @AutoItVersion & ")", 400, 300)
Local $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
GUISetState(@SW_SHOW)
; Setzt das ANSI Format
;~ _GUICtrlListView_SetUnicodeFormat($idListview, False)
; Fügt die Spalten hinzu
_GUICtrlListView_InsertColumn($idListview, 0, "Items", 100)
; Fügt die Items hinzu
_GUICtrlListView_BeginUpdate($idListview)
Local $iI
For $iI = 1 To 49
_GUICtrlListView_AddItem($idListview, "Item " & $iI)
Next
_GUICtrlListView_AddItem($idListview, "Zielitem")
For $iI = 51 To 100
_GUICtrlListView_AddItem($idListview, "Item " & $iI)
Next
_GUICtrlListView_EndUpdate($idListview)
; Sucht nach dem Zielitem
$iI = _GUICtrlListView_FindInText($idListview, "zIeL")
MsgBox($MB_SYSTEMMODAL, "Information", "Index des Zielitems: " & $iI)
_GUICtrlListView_EnsureVisible($idListview, $iI)
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>Example