Funktionreferenz


_GUICtrlListView_BeginUpdate

Beschreibung anzeigen in

Deaktiviert die Aktualisierung des Control-Items bis _GUICtrlListView_EndUpdate() aufgerufen wird

#include <GuiListView.au3>
_GUICtrlListView_BeginUpdate ( $hWnd )

Parameter

$hWnd Control-ID / Handle des Controls

Rückgabewert

Erfolg: True
Fehler: False

Bemerkungen

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlListView_EndUpdate

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiListView.au3>

Example()

Func Example()
    Local $hImage, $idListView

    GUICreate("ListView: Aktualisierung beginnen", 400, 300)
    $idListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUICtrlSetStyle($idListView, $LVS_ICON)
    GUISetState(@SW_SHOW)

    ; Lädt die Bilder
    $hImage = _GUIImageList_Create(32, 32)
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap(GUICtrlGetHandle($idListView), 0xFF0000, 32, 32))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap(GUICtrlGetHandle($idListView), 0x00FF00, 32, 32))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap(GUICtrlGetHandle($idListView), 0x0000FF, 32, 32))
    _GUICtrlListView_SetImageList($idListView, $hImage, 0)

    ; Fügt die Items hinzu
    _GUICtrlListView_BeginUpdate($idListView)
    For $iI = 1 To 10
        _GUICtrlListView_AddItem($idListView, "Rot", 0)
        _GUICtrlListView_AddItem($idListView, "Grün", 1)
        _GUICtrlListView_AddItem($idListView, "Blau", 2)
    Next
    _GUICtrlListView_EndUpdate($idListView)

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example