Funktionreferenz


_GUICtrlListView_GetColumn

Beschreibung anzeigen in

Ermittelt die Attribute einer Spalte

#include <GuiListView.au3>
_GUICtrlListView_GetColumn ( $hWnd, $iIndex )

Parameter

$hWnd Control-ID / Handle des Controls
$iIndex 0-basierender Index einer Spalte

Rückgabewert


Array mit dem folgenden Format:
    [0] - Untersuchung der Spaltenüberschrift und dem Text des Subitems in der Spalte:
        0 - Text ist linksbündig
        1 - Text ist rechtsbündig
        2 - Text ist zentriert
    [1] - True falls das Item ein Bild von einer Imagelist darstellt
    [2] - True falls das Bitmap rechts neben dem Text erscheint
    [3] - True falls die Überschrift ein Bild enthält
    [4] - Breite der Spalte in Pixel
    [5] - Spaltenüberschrift
    [6] - Index des Subitems passend zur Spalte
    [7] - 0-basierender Index eines Bildes innerhalb der Imagelist
    [8] - 0-basierende Reihenfolge der Spalten

Bemerkungen

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlListView_JustifyColumn, _GUICtrlListView_SetColumn

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    GUICreate("ListView: Attribute der Spalte ermitteln (v" & @AutoItVersion & ")", 500, 300)
    Local $idListview = GUICtrlCreateListView("col0|col1|col2", 2, 2, 394, 268)
    $idListview = GUICtrlCreateListView("Spalte1|Spalte2|Spalte3", 2, 2, 394, 268)
    _GUICtrlListView_SetExtendedListViewStyle($idListview, BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_CHECKBOXES))
    _GUICtrlListView_SetColumnWidth($idListview, 0, 100)
    GUISetState(@SW_SHOW)

    ; Setzt das ANSI Format
;~     _GUICtrlListView_SetUnicodeFormat($idListview, False)

    GUICtrlCreateListViewItem("Index0|Daten0|mehr0", $idListview)
    GUICtrlCreateListViewItem("Index1|Daten1|mehr1", $idListview)
    GUICtrlCreateListViewItem("Index2|Daten2|mehr2", $idListview)
    GUICtrlCreateListViewItem("Index3|Daten3|mehr3", $idListview)
    GUICtrlCreateListViewItem("Index4|Daten4|mehr4", $idListview)

    ; Ändert die Attribute einer Spalte
    Local $aInfo = _GUICtrlListView_GetColumn($idListview, 0)
    MsgBox($MB_SYSTEMMODAL, "Information", "Spalte 0 Breite: " & $aInfo[4])
    _GUICtrlListView_SetColumn($idListview, 0, "New Spalte 0", 150)
    $aInfo = _GUICtrlListView_GetColumn($idListview, 0)
    MsgBox($MB_SYSTEMMODAL, "Information", "Spalte 0 Breite: " & $aInfo[4])

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>Example