GUICtrlCreateListViewItem
Erstellt einen Eintrag in einer mehrspaltigen Liste (ListView).
GUICtrlCreateListViewItem ( "text", listviewID )
Parameter
| text | Die Texte der einzelnen Spalten welche durch ein Trennzeichen getrennt. Das Trennzeichen kann mit Opt("GUIDataSeparatorChar") bestimmt werden. |
| listviewID | Die Control-ID des ListView-Controls, zu dem der Eintrag hinzugefügt wird. |
Rückgabewert
| Erfolg: | Die Identifikationsnummer (Control-ID) des neuen Controls. |
| Fehler: | 0. |
Bemerkungen
Diese Funktion erzeugt die einzelnen ListView-Einträge, die der Benutzer auswählen kann.
Die einzelnen Einträge funktionieren wie normale Controls und können mit GUICtrlSetData() belegt werden.
Einträge können wie jedes andere Control durch GUICtrlDelete() gelöscht werden.
Die ListView-Einträge können per Drag & Drop in jedes Edit- oder Input-Control gezogen werden, das den Status $GUI_ACCEPTFILES hat.
Siehe GUICtrlCreateListView() zur Veränderung der Größe der Spalten.
Das spezielle Flag $GUI_BKCOLOR_LV_ALTERNATE kann zusammen mit dem ListView-Control dazu genutzt werden, den ListviewItems-Zeilen abwechselnd andere Hintergrundfarben zu geben.
Die ungeraden Zeilen bekommen die Farbe, welche durch GUICtrlSetBkColor() des ListView-Controls zugewiesen wird.
Die geraden Zeilen bekommen die Farbe, welche durch GUICtrlSetBkColor() des ListViewItem Controls zugewiesen wird.
Die oben angeführten Die Konstanten sind in GUIConstantsEx.au3 definiert.
- - - - - - - - Erklärung der Controls - - - - - - - -
Verwandte Funktionen
GUICtrlCreateListView, GUICtrlDelete, GUICtrlRead, GUICtrlSetData, GUICtrlSetState, GUIDataSeparatorChar (Option), GUIGetMsg
Beispiel
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>
Example()
Func Example()
GUICreate("Listview Einträge", 220, 250, 100, 200, -1, $WS_EX_ACCEPTFILES)
GUISetBkColor(0x00E0FFFF) ; Ändert die Hintergrundfarbe
Local $idListview = GUICtrlCreateListView("Spalte1 |Spalte2|Spalte3", 10, 10, 200, 150) ;,$LVS_SORTDESCENDING)
Local $idButton = GUICtrlCreateButton("Wert?", 75, 170, 70, 20)
Local $idItem1 = GUICtrlCreateListViewItem("Eintrag2|Spalte22|Spalte23", $idListview)
Local $idItem2 = GUICtrlCreateListViewItem("Eintrag1|Spalte12|Spalte13", $idListview)
Local $idItem3 = GUICtrlCreateListViewItem("Eintrag3|Spalte32|Spalte33", $idListview)
GUICtrlCreateInput("", 20, 200, 150)
GUICtrlSetState(-1, $GUI_DROPACCEPTED) ; Erlaubt drag&drop
GUISetState(@SW_SHOW)
GUICtrlSetData($idItem2, "EINTRAG1")
GUICtrlSetData($idItem3, "||SPALTE33")
GUICtrlDelete($idItem1)
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
ExitLoop
Case $idButton
MsgBox($MB_SYSTEMMODAL, "Listview Einträge", GUICtrlRead(GUICtrlRead($idListview)), 2)
Case $idListview
MsgBox($MB_SYSTEMMODAL, "Listview", "angeklickt=" & GUICtrlGetState($idListview), 2)
EndSwitch
WEnd
EndFunc ;==>Example