Setzt die Hintergrundfarbe eines Controls.
GUICtrlSetBkColor ( controlID, backgroundcolor )
ControlID | Die Identifikationsnummer des Controls (Control-ID), wie von einer GUICtrlCreate... Funktion zurückgegeben, oder -1 für das zuletzt erzeugte Control. |
backgroundcolor | Die RGB-Farbe, die verwendet werden soll. |
Erfolg: | 1. |
Fehler: | 0. |
Derzeit können nur Button, Label, Checkbox, Group, Radio, Edit, Input, List, Listview, ListviewItem, Treeview, TreeviewItem, Graphic, Progress, Slider und Combo Controls eingefärbt werden.
Progressbar, Checkbox, Radio, Group, Progress oder Combo-Controls können nicht verändert werden, wenn der "Windows XP style" verwendet wird.
Buttons werden immer im Windows Classic Stil dargestellt. Sie können keinen $BS_ICON Stil haben.
Das spezielle Flag $GUI_BKCOLOR_TRANSPARENT kann verwendet werden um Labels, Group, Radio und Checkbox Controls einen transparenten Hintergrund zu geben.
Das spezielle Flag $GUI_BKCOLOR_LV_ALTERNATE kann zusammen mit dem ListView-Control dazu genutzt werden, den ListviewItems-Zeilen abwechselnd andere Hintergrundfarben zu geben.
Die ungeraden Zeilen bekommen die Farbe, welche durch GUICtrlSetBkColor() dem ListView-Control zugewiesen wird.
Die geraden Zeilen bekommen die Farbe, welche durch GUICtrlSetBkColor() dem ListViewItem Control zugewiesen wird.
- - - - - - - - Erklärung der Controls - - - - - - - -
GUICtrlCreate..., GUICtrlSetColor, GUICtrlSetDefBkColor
#include <ColorConstants.au3>
#include <GUIConstantsEx.au3>
Example()
Func Example()
; Erstellt eine GUI mit verschiedenen Controls.
Local $hGui = GUICreate("Beispiel", 300, 200)
; Erstellt ein Label-Control.
Local $idLabel = GUICtrlCreateLabel("Ein Textstring", 10, 10, 185, 17)
Local $idButton_Close = GUICtrlCreateButton("Schließen", 210, 170, 85, 25)
; Setzt die Hintergrundfarbe des Label-Controls.
GUICtrlSetBkColor($idLabel, $COLOR_RED)
; Zeigt die GUI
GUISetState(@SW_SHOW, $hGui)
; Schließt das Editorfenster durch die Verwendung des Klassennamens (classname) vom Editor.
While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE, $idButton_Close
ExitLoop
EndSwitch
WEnd
; Löscht die vorherige GUI und alle Controls.
GUIDelete($hGui)
EndFunc ;==>Example
#include <ColorConstants.au3>
#include <GUIConstantsEx.au3>
#include <ListViewConstants.au3>
Example()
Func Example()
; Erstellt eine GUI mit einem Listview.
Local $hGUI = GUICreate("Farbige ListView Items", 250, 170, 100, 200, -1)
Local $idListview = GUICtrlCreateListView("col1|col2|col3", 10, 10, 230, 150)
; Wechselt zwischen der Hintergrundfarbe des Listview und der Hintergrundfarbe des Listviewelements.
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_LV_ALTERNATE)
; Setzt die Hintergrundfarbe für das Listview.
; Ungerade Listviewelemente werden mit der Hintergrundfarbe des Listview angezeigt,
; gerade mit der Hintergrundfarbe des Listviewelements.
GUICtrlSetBkColor(-1, $COLOR_AQUA)
; Erstellt Listviewelemente und setzt die Hintergrundfarbe für jedes.
GUICtrlCreateListViewItem("item1|col12|col13", $idListview)
; Die folgende Zeile könnte gelöscht werden, da hier die Hintergrundfarbe vom Listview verwendet wird.
GUICtrlSetBkColor(-1, $COLOR_GREEN)
GUICtrlCreateListViewItem("item2|col22|col23", $idListview)
GUICtrlSetBkColor(-1, $COLOR_GREEN)
GUICtrlCreateListViewItem("item3|col32|col33", $idListview)
; Die folgende Zeile könnte gelöscht werden, da hier die Hintergrundfarbe vom Listview verwendet wird.
GUICtrlSetBkColor(-1, $COLOR_GREEN)
; Wechselt die Farbe eines einzelnen Listviewelements.
GUICtrlCreateListViewItem("Now|change|color", $idListview)
GUICtrlSetBkColor(-1, $COLOR_LIME)
GUICtrlCreateListViewItem("item5|col52|col53", $idListview)
; Die folgende Zeile könnte gelöscht werden, da hier die Hintergrundfarbe vom Listview verwendet wird.
GUICtrlSetBkColor(-1, $COLOR_GREEN)
GUICtrlCreateListViewItem("item6|col62|col63", $idListview)
GUICtrlSetBkColor(-1, $COLOR_GREEN)
GUISetState(@SW_SHOW, $hGUI)
While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
ExitLoop
EndSwitch
WEnd
; Löscht die vorherige GUI und alle Steuerelemente
GUIDelete($hGUI)
EndFunc ;==>Example