GUICtrlSetColor
Beschreibung anzeigen in
Setzt die Textfarbe eines Controls.
GUICtrlSetColor ( controlID, textcolor )
Parameter
| ControlID | Die Identifikationsnummer des Controls (Control-ID), wie von einer GUICtrlCreate... Funktion zurückgegeben, oder -1 für das zuletzt erzeugte Control. |
| textcolor | Die RGB-Farbe, die verwendet werden soll. |
Rückgabewert
| Erfolg: | 1. |
| Fehler: | 0. |
Bemerkungen
Folgende Items können momentan gefärbt werden: Button, Label, Checkbox, Group, Radio, Edit, Input, List, Listview, ListviewItem, Treeview, TreeviewItem, Graphic, Progress und Combo
Checkbox, Radio, Group oder Progress-Controls können nicht gefärbt werden, wenn der "Windows XP style" verwendet wird. Dieser Stil kann durch den Aufruf von _WinAPI_SetThemeAppProperties(0) erzwungen werden.
Button-Controls werden immer im "Windows Classic style" gefärbt.
- - - - - - - - Erklärung der Controls - - - - - - - -
Verwandte Funktionen
GUICtrlCreate..., GUICtrlSetBkColor, GUICtrlSetDefColor, _WinAPI_SetThemeAppProperties
Beispiel
#include <ColorConstants.au3>
#include <GUIConstantsEx.au3>
Example()
Func Example()
; Erstellt eine GUI mit verschiedenen Controls.
Local $hGui = GUICreate("Beispiel", 300, 200)
; Erstellt ein Label-Control.
Local $idLabel = GUICtrlCreateLabel("Ein Textstring", 10, 10, 185, 17)
Local $idButton_Close = GUICtrlCreateButton("Schließen", 210, 170, 85, 25)
; Setzt die Farbe des Label-Controls.
GUICtrlSetColor($idLabel, $COLOR_RED)
; Zeigt die GUI
GUISetState(@SW_SHOW, $hGui)
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE, $idButton_Close
ExitLoop
EndSwitch
WEnd
; Löscht die vorherige GUI und alle Controls.
GUIDelete($hGui)
EndFunc ;==>Example