Setzt den Status des "Anhakfeldes" des festgelegten Menüitems entweder auf angehakt oder leer
#include <GuiMenu.au3>
_GUICtrlMenu_CheckMenuItem ( $hMenu, $iItem [, $bCheck = True [, $bByPos = True]] )
$hMenu | Handle des Menüs |
$iItem | ID oder Position des zu prüfenden Menüitems |
$bCheck | [optional] True um es anzuhaken, False um die Markierung zu entfernen |
$bByPos | [optional] Menü-ID Flag: True - $iItem ist eine 0-basierende Itemposition False - $iItem ist eine Menüitem ID |
Erfolg: | Der vorherige Status des Menüitems (entweder $MF_CHECKED oder $MF_UNCHECKED) |
Fehler: | -1 |
Ein Item in einer Menüleiste kann kein Anhakfeld haben. Der $iItem Parameter erkennt ein Item welches ein Untermenü oder ein Command Item öffnet. Bei einem Item welches ein Untermenü öffnet, muss der $Item Parameter auf die Position des Items festgelegt werden.
Für ein Command Item kann der $Item Parameter entweder die Itemposition oder deren ID angeben.
- - - - - - - - Erklärung der Controls - - - - - - - -
Suche nach CheckMenuItem in der MSDN Bibliothek.
#include <GUIConstantsEx.au3>
#include <GuiMenu.au3>
Example()
Func Example()
Local $hGui, $hFile, $idEdit, $hHelp, $hMain
Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $e_idExit, $e_idCut, $e_idCopy, $e_idPaste, $e_idAbout
; Erstellt eine GUI
$hGui = GUICreate("Menu", 400, 300)
; Erstellt den Menüpunkt Datei
$hFile = _GUICtrlMenu_CreateMenu()
_GUICtrlMenu_InsertMenuItem($hFile, 0, "&Neu", $e_idNew)
_GUICtrlMenu_InsertMenuItem($hFile, 1, "&Öffnen", $e_idOpen)
_GUICtrlMenu_InsertMenuItem($hFile, 2, "&Speichern", $e_idSave)
_GUICtrlMenu_InsertMenuItem($hFile, 3, "", 0)
_GUICtrlMenu_InsertMenuItem($hFile, 4, "B&eenden", $e_idExit)
; Erstellt den Menüpunkt Bearbeiten
$idEdit = _GUICtrlMenu_CreateMenu()
_GUICtrlMenu_InsertMenuItem($idEdit, 0, "&Ausschneiden", $e_idCut)
_GUICtrlMenu_InsertMenuItem($idEdit, 1, "K&opieren", $e_idCopy)
_GUICtrlMenu_InsertMenuItem($idEdit, 2, "&Einfügen", $e_idPaste)
; Erstellt den Menüpunkt Hilfe
$hHelp = _GUICtrlMenu_CreateMenu()
_GUICtrlMenu_InsertMenuItem($hHelp, 0, "&Über", $e_idAbout)
; Erstellt das Hauptmenü
$hMain = _GUICtrlMenu_CreateMenu()
_GUICtrlMenu_InsertMenuItem($hMain, 0, "&Datei", 0, $hFile)
_GUICtrlMenu_InsertMenuItem($hMain, 1, "&Bearbeiten", 0, $idEdit)
_GUICtrlMenu_InsertMenuItem($hMain, 2, "&Hilfe", 0, $hHelp)
; Setzt das neue Menü
_GUICtrlMenu_SetMenu($hGui, $hMain)
GUISetState(@SW_SHOW)
; Prüft, ob das Menü das angegebene Item enthält
_GUICtrlMenu_CheckMenuItem($hHelp, 0)
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>Example