Funktionreferenz


_GUICtrlMenu_CheckRadioItem

Beschreibung anzeigen in

Markiert ein festgelegtes Menüitem und stellt es als Radioitem dar

#include <GuiMenu.au3>
_GUICtrlMenu_CheckRadioItem ( $hMenu, $iFirst, $iLast, $iCheck [, $bByPos = True] )

Parameter

$hMenu Handle des Menüs
$iFirst ID oder Position des ersten Menüitems in der Gruppe
$iLast ID oder Position des letzten Menüitems in der Gruppe
$iCheck zu markierende ID oder Position des Menüitems
$bByPos [optional] Menü-ID Flag:
    True - $iFirst, $iLast und $iCheck sind 0-basierenden Itempositionen
    False - $iFirst, $iLast und $iCheck sind Menüitem IDs

Rückgabewert

Erfolg: True
Fehler: False

Bemerkungen

Diese Funktion setzt das $MFT_RADIOCHECK Typ Flag und den Status $MFS_CHECKED für das durch $iCheck festgelegte Item
und leert beide Flags zur gleichen Zeit für alle anderen Items in der Gruppe. Das markierte Item wird als bullet Bitmap anstelle eines check-mark Bitmap dargestellt.

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlMenu_CheckMenuItem

Siehe auch

Suche nach CheckMenuRadioItem in der MSDN Bibliothek.

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiMenu.au3>

Example()

Func Example()
    Local $hGui, $hFile, $idEdit, $hHelp, $hMain
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $e_idExit, $e_idCut, $e_idCopy, $e_idPaste, $e_idAbout

    ; Erstellt eine GUI
    $hGui = GUICreate("Menu", 400, 300)

    ; Erstellt den Menüpunkt Datei
    $hFile = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hFile, 0, "&Neu", $e_idNew)
    _GUICtrlMenu_InsertMenuItem($hFile, 1, "&Öffnen", $e_idOpen)
    _GUICtrlMenu_InsertMenuItem($hFile, 2, "&Speichern", $e_idSave)
    _GUICtrlMenu_InsertMenuItem($hFile, 3, "", 0)
    _GUICtrlMenu_InsertMenuItem($hFile, 4, "&Beenden", $e_idExit)

    ; Erstellt den Menüpunkt "Bearbeiten"
    $idEdit = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($idEdit, 0, "&Ausschneiden", $e_idCut)
    _GUICtrlMenu_InsertMenuItem($idEdit, 1, "K&opieren", $e_idCopy)
    _GUICtrlMenu_InsertMenuItem($idEdit, 2, "&Einfügen", $e_idPaste)

    ; Erstellt den Menüpunkt Hilfe
    $hHelp = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hHelp, 0, "&Über Menü", $e_idAbout)

    ; Erstellt das Hauptmenü
    $hMain = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hMain, 0, "&Datei", 0, $hFile)
    _GUICtrlMenu_InsertMenuItem($hMain, 1, "&Bearbeiten", 0, $idEdit)
    _GUICtrlMenu_InsertMenuItem($hMain, 2, "&Hilfe", 0, $hHelp)

    ; Setzt das neue Menü
    _GUICtrlMenu_SetMenu($hGui, $hMain)
    GUISetState(@SW_SHOW)

    ; Hakt das "Öffnen"-Menüitem an
    _GUICtrlMenu_CheckRadioItem($hFile, 0, 4, 1)

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example