_GUICtrlMonthCal_GetColorArray
Beschreibung anzeigen in
Ermittelt die Farbe für einen festgelegten Abschnitt eines Monatskalender Controls
#include <GuiMonthCal.au3>
_GUICtrlMonthCal_GetColorArray ( $hWnd, $iColor )
Parameter
| $hWnd | Control-ID / Handle des Controls |
| $iColor | Wert des Typs Integer, der festlegt, welche Farbe des Monatskalenders ermittelt werden soll Dieser Wert kann einer der folgenden sein: $MCSC_BACKGROUND - Hintergrundfarbe, die zwischen den Monaten dargestellt wird $MCSC_MONTHBK - Hintergrundfarbe, die innerhalb des Monats dargestellt wird $MCSC_TEXT - Farbe, die verwendet wird, um Text innerhalb eines Monats darzustellen $MCSC_TITLEBK - Hintergrundfarbe, die in dem Titel des Kalenders dargestellt wird $MCSC_TITLETEXT - Farbe, die verwendet wird, um Text innerhalb des Kalendertitels darzustellen $MCSC_TRAILINGTEXT - Farbe für den Text der Vor- und Nachspanntage |
Rückgabewert
| Erfolg: | Ein Array mit dem folgenden Format: [0] - enthält die zurückgegebene Zahl [1] - enthält COLORREF rgb Farbe [2] - enthält Hex BGR Farbe [3] - enthält Hex RGB Farbe |
| Fehler: | Setzt das @error Flag auf ungleich 0 |
Bemerkungen
Vor- und Nachspanntage sind die Tage des vorherigen und nachfolgenden Monats, die im aktuellen Monatskalender eingeblendet werden.
- - - - - - - - Erklärung der Controls - - - - - - - -
Verwandte Funktionen
Beispiel
#include "Extras\HelpFileInternals.au3"
#include <ColorConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <GuiMonthCal.au3>
#include <WindowsStylesConstants.au3>
Example()
Func Example()
Local $idMonthCal
; Erstellt eine GUI
GUICreate("Month Calendar: Ermittelt die Farbe für einen festgelegten Abschnitt", 625, 300)
$idMonthCal = GUICtrlCreateMonthCal("", 4, 4, -1, -1, $WS_BORDER, 0x00000000)
; Erstellt ein Memo Control
_MemoCreate(4, 168, 417, 128, BitOR($WS_VSCROLL, $ES_MULTILINE))
GUICtrlSendMsg($_g_idLst_Memo, $EM_SETREADONLY, True, 0)
GUICtrlSetBkColor($_g_idLst_Memo, 0xFFFFFF)
GUISetState(@SW_SHOW)
_GUICtrlMonthCal_SetColor($idMonthCal, $MCSC_MONTHBK, $CLR_DARKSEAGREEN)
; Ermittelt Kalender-Farben
_MemoWrite(_FormatOutPut("Hintergrundfarbe, die zwischen den Monaten dargestellt wird:", _GUICtrlMonthCal_GetColorArray($idMonthCal, $MCSC_BACKGROUND)))
_MemoWrite(_FormatOutPut(@CRLF & "Hintergrundfarbe, die innerhalb des Monats dargestellt wird:", _GUICtrlMonthCal_GetColorArray($idMonthCal, $MCSC_MONTHBK)))
_MemoWrite(_FormatOutPut(@CRLF & "Farbe, die verwendet wird, um Text innerhalb eines Monats darzustellen:", _GUICtrlMonthCal_GetColorArray($idMonthCal, $MCSC_TEXT)))
_MemoWrite(_FormatOutPut(@CRLF & "Hintergrundfarbe, die in dem Titel des Kalenders dargestellt wird:", _GUICtrlMonthCal_GetColorArray($idMonthCal, $MCSC_TITLEBK)))
_MemoWrite(_FormatOutPut(@CRLF & "Farbe, die verwendet wird, um Text innerhalb des Kalendertitels darzustellen:", _GUICtrlMonthCal_GetColorArray($idMonthCal, $MCSC_TITLETEXT)))
_MemoWrite(_FormatOutPut(@CRLF & "Farbe für den Text der Vor- und Nachspanntage:", _GUICtrlMonthCal_GetColorArray($idMonthCal, $MCSC_TRAILINGTEXT)))
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>Example
Func _FormatOutPut($sText, $aColors)
Return $sText & _
@CRLF & @TAB & "COLORREF rgb Farbe:" & @TAB & @TAB & $aColors[1] & _
@CRLF & @TAB & "Hex BGR Farbe :" & @TAB & @TAB & $aColors[2] & _
@CRLF & @TAB & "Hex RGB Farbe :" & @TAB & @TAB & $aColors[3]
EndFunc ;==>_FormatOutPut