Funktionreferenz


_GUICtrlMonthCal_GetMinReqRectArray

Beschreibung anzeigen in

Ermittelt die minimale Größe, um einen kompletten Monat in einem MonthCal-Control darzustellen

#include <GuiMonthCal.au3>
_GUICtrlMonthCal_GetMinReqRectArray ( $hWnd )

Parameter

$hWnd Control-ID / Handle des Controls

Rückgabewert

Erfolg: True, Handle wird auf 0 gesetzt
[0] - Anzahl
[0] - X Koordinate der oberen linken Ecke des Rechtecks
[1] - Y Koordinate der oberen linken Ecke des Rechtecks
[2] - X Koordinate der unteren rechten Ecke des Rechtecks
[3] - Y Koordinate der unteren rechten Ecke des Rechtecks
Fehler: Setzt das @error Flag auf ungleich null

Bemerkungen

Die minimal benötigte Fenstergröße für ein MonthCal-Control ist von der aktuell verwendeten Schriftart, den Stilen des Controls, Systemeigenschaften und regionalen Einstellungen abhängig.

- - - - - - - - Erklärung der Controls - - - - - - - -

Beispiel

#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <GuiMonthCal.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $idMonthCal

    ; Erstellt eine GUI
    GUICreate("Month Calendar: Ermittelt die minimale Größe um einen kompletten Monat darzustellen", 650, 300)
    $idMonthCal = GUICtrlCreateMonthCal("", 4, 4, -1, -1, BitOR($WS_BORDER, $MCS_MULTISELECT), 0x00000000)

    ; Erstellt ein Memo Control
    $g_idMemo = GUICtrlCreateEdit("", 4, 168, 392, 128, BitOR($WS_VSCROLL, $ES_MULTILINE))
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUICtrlSendMsg($g_idMemo, $EM_SETREADONLY, True, 0)
    GUICtrlSetBkColor($g_idMemo, 0xFFFFFF)
    GUISetState(@SW_SHOW)

    ; Ermittelt die minimale Größe um einen kompletten Monat darzustellen
    MemoWrite(_FormatOutPut(_GUICtrlMonthCal_GetMinReqRectArray($idMonthCal)))

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

Func _FormatOutPut($aRect)
    Return "Mindestbreite: " & @TAB & $aRect[3] & @CRLF & "Mindesthöhe:" & @TAB & $aRect[4]
EndFunc   ;==>_FormatOutPut

; Schreibt eine Nachricht in das Memo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite