Funktionreferenz


_GUICtrlToolbar_GetButtonInfo

Beschreibung anzeigen in

Ermittelt Informationen für einen Button

#include <GuiToolbar.au3>
_GUICtrlToolbar_GetButtonInfo ( $hWnd, $iCommandID )

Parameter

$hWnd Handle des Controls
$iCommandID Button Command ID

Rückgabewert

Gibt ein Array mit dem folgenden Format zurück:
    [0] - 0-basierender Index des Buttonbildes
    [1] - Buttonstatus. Kann eine Kombination der folgenden sein:
        $TBSTATE_CHECKED - Der Button ist angeklickt
        $TBSTATE_PRESSED - Der Button ist angeklickt
        $TBSTATE_ENABLED - Der Button akzeptiert Benutzereingaben
        $TBSTATE_HIDDEN - Der Button ist nicht sichtbar
        $TBSTATE_INDETERMINATE - Der Button ist ausgegraut
        $TBSTATE_WRAP - Dem Button folgt ein Zeilenumbruch
        $TBSTATE_ELLIPSES - Der Text des Buttons ist ausgeschnitten
        $TBSTATE_MARKED - Der Button ist markiert
    [2] - Buttonstil. Kann eine Kombination der folgenden sein:
        $BTNS_BUTTON - Standardbutton
        $BTNS_CHECK - Schaltet zwischen gedrückt und nicht gedrückt hin und her
        $BTNS_CHECKGROUP - Button der solange gedrückt dargestellt wird bis ein anderer Button in der Gruppe gedrückt wird
        $BTNS_DROPDOWN - Erstellt ein Dropdown Button welcher eine Liste darstellt
        $BTNS_GROUP - Button der solange gedrückt dargestellt wird bis ein anderer Button in der Gruppe gedrückt wird
        $BTNS_NOPREFIX - Der Buttontext hat keinen Shortcutbuchstaben
        $BTNS_SEP - Erstellt einen Trenner
        $BTNS_SHOWTEXT - legt fest, dass der Buttontext angezeigt werden soll
        $BTNS_WHOLEDROPDOWN - legt fest, dass der Button einen Dropdown Pfeil hat
    [3] - Buttonbreite
    [4] - Buttonparameter

Bemerkungen

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlToolbar_SetButtonInfo

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiToolbar.au3>
#include <WinAPIConstants.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGui, $hToolbar, $aButton
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $idHelp

    ; Erstellt eine GUI
    $hGui = GUICreate("Toolbar", 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGui)
    $g_idMemo = GUICtrlCreateEdit("", 2, 36, 396, 262, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 10, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Fügt die Standard-Systembitmaps hinzu
    Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; Fügt die Buttons hinzu
    _GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    ; Ändert die Eigenschaften des Speichern-Buttons
    _GUICtrlToolbar_SetButtonInfo($hToolbar, $e_idSave, $STD_PRINT, BitOR($TBSTATE_PRESSED, $TBSTATE_ENABLED), -1, 100, 1234)

    ; Zeigt Informationen über den Speichern-Button an
    $aButton = _GUICtrlToolbar_GetButtonInfo($hToolbar, $e_idSave)
    MemoWrite("Index des Buttonbildes : " & $aButton[0])
    MemoWrite("Buttonstatus ..........: " & $aButton[1])
    MemoWrite("Buttonstil ............: " & $aButton[2])
    MemoWrite("Buttonbreite ..........: " & $aButton[3])
    MemoWrite("Buttonparameter .......: " & $aButton[4])

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Schreibt eine Nachricht in das Memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite