Funktionreferenz

_GUICtrlToolbar_SetButtonInfo

Beschreibung anzeigen in

Setzt Informationen für einen Button

#include <GuiToolBar.au3>
_GUICtrlToolbar_SetButtonInfo ( $hWnd, $iCommandID [, $iImage = $I_IMAGE [, $iState = -1 [, $iStyle = -1 [, $iWidth = -1 [, $iParam = -1]]]]] )

Parameter

$hWnd Handle des Controls
$iCommandID Button Command ID
$iImage [optional] 0-basierender Index des Buttonbildes.
Wird dieser Parameter auf $I_IMAGECALLBACK gesetzt, sendet das Control die $TBN_GETDISPINFO Nachricht um den Bilderindex zu empfangen, wenn es notwendig ist.
Setzt man es auf $I_IMAGENONE, so wird festgelegt, dass der Button kein Bild beinhaltet.
Das Buttonlayout enthält nur Platz für den Text.
Dieser Wert ist auf $I_IMAGE (Standard) zu setzen, wenn die Schaltfläche ein Bild enthält.
Falls der Button eine Trennung ist, so ist dies die Breite der Trennung in Pixel.
$iState [optional] Buttonstatus. Kann eine Kombination der folgenden sein:
    $TBSTATE_CHECKED - Der Button ist angeklickt
    $TBSTATE_PRESSED - Der Button ist angeklickt
    $TBSTATE_ENABLED - Der Button akzeptiert Benutzereingaben
    $TBSTATE_HIDDEN - Der Button ist nicht sichtbar
    $TBSTATE_INDETERMINATE - Der Button ist ausgegraut
    $TBSTATE_WRAP - Dem Button folgt ein Zeilenumbruch
    $TBSTATE_ELLIPSES - Der Text des Buttons ist ausgeschnitten
    $TBSTATE_MARKED - Der Button ist markiert
$iStyle [optional] Buttonstil. Kann eine Kombination der folgenden sein:
    $BTNS_AUTOSIZE - Das Toolbar-Control sollte nicht die Standardbreite des Buttons verwenden
    $BTNS_BUTTON - Standardbutton
    $BTNS_CHECK - Schaltet zwischen gedrückt und nicht gedrückt hin und her
    $BTNS_CHECKGROUP - Button der solange gedrückt dargestellt wird bis ein anderer Button in der Gruppe gedrückt wird
    $BTNS_DROPDOWN - Erstellt ein Dropdown Button welcher eine Liste darstellt
    $BTNS_GROUP - Button der solange gedrückt dargestellt wird bis ein anderer Button in der Gruppe gedrückt wird
    $BTNS_NOPREFIX - Der Buttontext hat keinen Shortcutbuchstaben
    $BTNS_SEP - Erstellt einen Trenner
    $BTNS_SHOWTEXT - legt fest, dass der Buttontext angezeigt werden soll
    $BTNS_WHOLEDROPDOWN - legt fest, dass der Button einen Dropdown Pfeil hat
$iWidth [optional] Buttonbreite
$iParam [optional] Anwendungsspezifischer Wert

Rückgabewert

Erfolg: True
Fehler: False

Bemerkungen

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

$tagTBBUTTONINFO, _GUICtrlToolbar_GetButtonInfo

Beispiel

#include "Extras\HelpFileInternals.au3"

#include <GUIConstantsEx.au3>
#include <GuiToolbar.au3>
#include <WinAPIConstants.au3>
#include <WindowsStylesConstants.au3>

Example()

Func Example()
    Local $hGui, $hToolbar, $aButton
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $e_idHelp

    ; Erstellt eine GUI
    $hGui = GUICreate("Toolbar", 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGui)
    _MemoCreate(2, 36, 396, 262, $WS_VSCROLL)
    GUISetState(@SW_SHOW)

    ; Fügt die Standard-Systembitmaps hinzu
    Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; Fügt die Buttons hinzu
    _GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idHelp, $STD_HELP)

    ; Ändert die Eigenschaften des Speichern-Buttons
    _GUICtrlToolbar_SetButtonInfo($hToolbar, $e_idSave, $STD_PRINT, BitOR($TBSTATE_PRESSED, $TBSTATE_ENABLED), -1, 100, 1234)

    ; Zeigt Informationen über den Speichern-Button an
    $aButton = _GUICtrlToolbar_GetButtonInfo($hToolbar, $e_idSave)
    _MemoWrite("Index des Buttonbildes : " & $aButton[0])
    _MemoWrite("Buttonstatus ..........: " & $aButton[1])
    _MemoWrite("Buttonstil ............: " & $aButton[2])
    _MemoWrite("Buttonbreite ..........: " & $aButton[3])
    _MemoWrite("Buttonparameter .......: " & $aButton[4])

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example