Funktionreferenz

_GUICtrlToolbar_SetExtendedStyle

Beschreibung anzeigen in

Setzt die erweiterten Fensterstile des Controls

#include <GuiToolBar.au3>
_GUICtrlToolbar_SetExtendedStyle ( $hWnd, $iStyle )

Parameter

$hWnd Handle des Controls
$iStyle erweiterte Fensterstile des Controls. Kann einer oder mehrere der folgenden Werte sein:
    $TBSTYLE_EX_DRAWDDARROWS - Erlaubt es, dass Buttons einen separaten Dropdown Pfeil haben
    $TBSTYLE_EX_MIXEDBUTTONS - Erlaubt gemixte Buttons mit Text und Bild
    $TBSTYLE_EX_HIDECLIPPEDBUTTONS - versteckt teilweise ausgeschnittene Buttons
    $TBSTYLE_EX_DOUBLEBUFFER - veranlasst, dass die Toolbar doppelt gepuffert wird

Rückgabewert

Gibt die vorherigen erweiterten Fensterstile zurück.

Bemerkungen

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlToolbar_GetExtendedStyle

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiMenu.au3>
#include <GuiToolbar.au3>
#include <WinAPIConstants.au3>
#include <WindowsConstants.au3>

Global $hGui, $g_idMemo

Example()

Func Example()
    Local $hToolbar
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $idHelp

    ; Erstellt eine GUI
    $hGui = GUICreate("Toolbar", 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGui)
    _GUICtrlToolbar_SetExtendedStyle($hToolbar, $TBSTYLE_EX_DRAWDDARROWS)
    $g_idMemo = GUICtrlCreateEdit("", 2, 36, 396, 262, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 10, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Fügt die Standard Systembitmaps hinzu
    Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; Fügt die Buttons hinzu
    _GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW, 0, $idBtnS_DROPDOWN)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    ; Zeigt die verwendeten erweiterten Stile
    MemoWrite("Erweiterte Stile: " & _GUICtrlToolbar_GetExtendedStyle($hToolbar))

    GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Schreibt eine Nachricht in das Memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite

; Verarbeitet die TBN_DROPDOWN Nachricht
Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $wParam
    Local $tNMHDR, $iCode, $hMenu

    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    $iCode = DllStructGetData($tNMHDR, "Code")

    If $iCode = $TBN_DROPDOWN Then
        $hMenu = _GUICtrlMenu_CreatePopup()
        _GUICtrlMenu_AddMenuItem($hMenu, "Template 1", 2000)
        _GUICtrlMenu_AddMenuItem($hMenu, "Template 2", 2001)
        _GUICtrlMenu_AddMenuItem($hMenu, "Template 3", 2002)
        _GUICtrlMenu_TrackPopupMenu($hMenu, $hGui)
        _GUICtrlMenu_DestroyMenu($hMenu)
    EndIf
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY