Funktionreferenz


_GUICtrlToolbar_SetUnicodeFormat

Beschreibung anzeigen in

Setzt das Unicode Zeichen-Format-Flag

#include <GuiToolBar.au3>
_GUICtrlToolbar_SetUnicodeFormat ( $hWnd [, $bUnicode = False] )

Parameter

$hWnd Handle des Controls
$bUnicode [optional] Unicode Zeicheneinstellung:
    True - Control verwendet Unicode Zeichen
    False - Control verwendet ANSI Zeichen

Rückgabewert

Gibt die vorherige Zeichen-Format-Flag Einstellung zurück.

Bemerkungen

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlToolbar_GetUnicodeFormat

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiToolbar.au3>
#include <WinAPIConstants.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $idHelp

    ; Erstellt eine GUI
    Local $hGUI = GUICreate("Toolbar (v" & @AutoItVersion & ")", 400, 300)
    Local $hToolbar = _GUICtrlToolbar_Create($hGUI)
    $g_idMemo = GUICtrlCreateEdit("", 2, 36, 396, 262, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 10, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Setzt das ANSI Format
;~     _GUICtrlToolbar_SetUnicodeFormat($hToolbar, False)

    ; Fügt die Standard Systembitmaps hinzu
    Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; Fügt die Buttons hinzu
    _GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    ; Zeigt das Unicode Format
    Local $bUnicode = _GUICtrlToolbar_GetUnicodeFormat($hToolbar)
    MemoWrite("Unicode format .: " & $bUnicode)

    ; Ändert das Unicode Format
    _GUICtrlToolbar_SetUnicodeFormat($hToolbar, Not $bUnicode)
    MemoWrite("Unicode Format .: " & _GUICtrlToolbar_GetUnicodeFormat($hToolbar))

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Schreibt eine Nachricht in das Memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite