_GUICtrlTreeView_DisplayRect
Beschreibung anzeigen in
Gibt das begrenzende Rechteck für ein Treeitem zurück
#include <GuiTreeView.au3>
_GUICtrlTreeView_DisplayRect ( $hWnd, $hItem [, $bTextOnly = False] )
Parameter
| $hWnd | Control-ID / Handle des Controls |
| $hItem | Handle zu dem Item dessen Rechteck zurückgegeben werden soll |
| $bTextOnly | [optional] Falls True wird das begrenzende Rechteck inklusive nur dem Text des Items. Sonst wird die komplette Zeile die das Item betrifft eingeschlossen. |
Rückgabewert
| Erfolg: | Ein Array mit dem folgenden Format: $aRect[0] - X Koordinate der oberen linken Ecke des Rechtecks $aRect[1] - Y Koordinate der oberen linken Ecke des Rechtecks $aRect[2] - X Koordinate der unteren rechten Ecke des Rechtecks $aRect[3] - Y Koordinate der unteren rechten Ecke des Rechtecks |
| Fehler: | Setzt das @error Flag auf ungleich null |
Bemerkungen
- - - - - - - - Erklärung der Controls - - - - - - - -
Verwandte Funktionen
_GUICtrlTreeView_DisplayRectEx
Beispiel
#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiTreeView.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>
Example()
Func Example()
GUICreate("TreeView: Zeigt das begrenzende Rechteck an (v" & @AutoItVersion & ")", 500, 300)
Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)
Local $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
GUISetState(@SW_SHOW)
Local $hImage = _GUIImageList_Create(16, 16, 5, 3)
_GUIImageList_AddIcon($hImage, "shell32.dll", 110)
_GUIImageList_AddIcon($hImage, "shell32.dll", 131)
_GUIImageList_AddIcon($hImage, "shell32.dll", 165)
_GUIImageList_AddIcon($hImage, "shell32.dll", 168)
_GUIImageList_AddIcon($hImage, "shell32.dll", 137)
_GUIImageList_AddIcon($hImage, "shell32.dll", 146)
_GUICtrlTreeView_SetNormalImageList($idTreeView, $hImage)
Local $ahItem[6]
For $x = 0 To _GUIImageList_GetImageCount($hImage) - 1
$ahItem[$x] = _GUICtrlTreeView_Add($idTreeView, 0, StringFormat("[%02d] Neues Item", $x), $x, $x)
Next
Local $aRect = _GUICtrlTreeView_DisplayRect($idTreeView, $ahItem[2])
MsgBox($MB_SYSTEMMODAL, "Information", StringFormat("Item 2 Rechteck : [%d, %d, %d, %d]", $aRect[0], $aRect[1], $aRect[2], $aRect[3]))
_GUICtrlTreeView_ClickItem($idTreeView, $ahItem[2], "left", False, 2)
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>Example