Funktionreferenz

_GUICtrlTreeView_DisplayRectEx

Beschreibung anzeigen in

Gibt das begrenzende Rechteck für ein Treeitem zurück

#include <GuiTreeView.au3>
_GUICtrlTreeView_DisplayRectEx ( $hWnd, $hItem [, $bTextOnly = False] )

Parameter

$hWnd Control-ID / Handle des Controls
$hItem Handle zu dem Item, dessen Rechteck zurückgegeben werden soll
$bTextOnly [optional] Falls True, enthält das begrenzende Rechteck nur den Text des Items.
    Sonst wird die komplette Zeile, die das Item in Beschlag nimmt, eingeschlossen.

Rückgabewert

Erfolg: $tagRECT Struktur, die das begrenzende Rechteck enthält. Die Koordinaten sind relativ zu der oberen linken Ecke des Controls.
Fehler: Setzt das @error Flag auf ungleich null

Bemerkungen

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

$tagRECT, _GUICtrlTreeView_DisplayRect

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiTreeView.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    GUICreate("TreeView: Gibt das begrenzende Rechteck für ein Treeitem zurück (v" & @AutoItVersion & ")", 600, 300)

    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)
    Local $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState(@SW_SHOW)

    ; Setzt das ANSI Format
;~     _GUICtrlTreeView_SetUnicodeFormat($idTreeView, False)

    Local $hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 110)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 131)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 165)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 168)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 137)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 146)
    _GUICtrlTreeView_SetNormalImageList($idTreeView, $hImage)

    Local $aidItem[6]
    For $x = 0 To _GUIImageList_GetImageCount($hImage) - 1
        $aidItem[$x] = _GUICtrlTreeView_Add($idTreeView, 0, StringFormat("[%02d] Neues Item", $x), $x, $x)
    Next
    Local $tRECT = _GUICtrlTreeView_DisplayRectEx($idTreeView, $aidItem[2])
    MsgBox($MB_SYSTEMMODAL, "Information", StringFormat("Item 2 Rechteck : [%d, %d, %d, %d]", DllStructGetData($tRECT, "Left"), _
            DllStructGetData($tRECT, "Top"), DllStructGetData($tRECT, "Right"), DllStructGetData($tRECT, "Bottom")))
    _GUICtrlTreeView_SelectItem($idTreeView, $aidItem[2])

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example