Funktionreferenz

_GUICtrlTreeView_Index

Beschreibung anzeigen in

Ermittelt die Position eines Items in der Liste

#include <GuiTreeView.au3>
_GUICtrlTreeView_Index ( $hWnd, $hItem )

Parameter

$hWnd Control-ID / Handle des Controls
$hItem Handle des Items

Rückgabewert

Erfolg: die Indexposition
Fehler: -1

Bemerkungen

Falls $hItem ein Item eines Children ist, ist die Position der Index unter dem Überzweig
Falls $hItem kein Parent hat, wird diese Funktion den Index dieses Items ermitteln

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlTreeView_GetItemByIndex

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiTreeView.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>

Global $g_hImage, $g_hStateImage

Example()

Func Example()
    GUICreate("TreeView: Index (v" & @AutoItVersion & ")", 400, 300)

    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS)
    Local $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState(@SW_SHOW)

    _CreateNormalImageList()
    _GUICtrlTreeView_SetNormalImageList($idTreeView, $g_hImage)

    ; Setzt das ANSI Format
;~  _GUICtrlTreeView_SetUnicodeFormat($idTreeView, False)

    _CreateStateImageList()
    _GUICtrlTreeView_SetStateImageList($idTreeView, $g_hStateImage)

    _GUICtrlTreeView_BeginUpdate($idTreeView)
    Local $ahItem[10], $aidChildItem[30], $iYItem = 0
    For $x = 4 To 0 Step -1
        $ahItem[$x] = _GUICtrlTreeView_Add($idTreeView, 0, StringFormat("[Item-Index %02d]", $x), 4, 5)
        _GUICtrlTreeView_SetStateImageIndex($idTreeView, $ahItem[$x], 1)
        For $y = 2 To 0 Step -1
            $aidChildItem[$iYItem] = _GUICtrlTreeView_AddChild($idTreeView, $ahItem[$x], StringFormat("[Child-Index %02d]", $y), 0, 3)
            _GUICtrlTreeView_SetStateImageIndex($idTreeView, $aidChildItem[$iYItem], 1)
            $iYItem += 1
        Next
    Next
    _GUICtrlTreeView_EndUpdate($idTreeView)

    Local $iRand = Random(0, 29, 1)
    MsgBox($MB_SYSTEMMODAL, "Information", StringFormat("Index des Child-Items an Position %d (bei 0 beginnend):" & @CRLF & "%d", $iRand, _GUICtrlTreeView_Index($idTreeView, $aidChildItem[$iRand])))
    _GUICtrlTreeView_SelectItem($idTreeView, $aidChildItem[$iRand])

    $iRand = Random(0, 4, 1)
    MsgBox($MB_SYSTEMMODAL, "Information", StringFormat("Position (bei 0 beginnend) des Items mit dem Index %d:" & @CRLF & "%d", $iRand, _GUICtrlTreeView_Index($idTreeView, $ahItem[$iRand])))
    _GUICtrlTreeView_SelectItem($idTreeView, $ahItem[$iRand])

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

Func _CreateNormalImageList()
    $g_hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($g_hImage, "shell32.dll", 110)
    _GUIImageList_AddIcon($g_hImage, "shell32.dll", 131)
    _GUIImageList_AddIcon($g_hImage, "shell32.dll", 165)
    _GUIImageList_AddIcon($g_hImage, "shell32.dll", 168)
    _GUIImageList_AddIcon($g_hImage, "shell32.dll", 137)
    _GUIImageList_AddIcon($g_hImage, "shell32.dll", 146)
EndFunc   ;==>_CreateNormalImageList

Func _CreateStateImageList()
    $g_hStateImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($g_hStateImage, "shell32.dll", 3)
    _GUIImageList_AddIcon($g_hStateImage, "shell32.dll", 4)
EndFunc   ;==>_CreateStateImageList