Funktionreferenz

_GUIScrollBars_EnableScrollBar

Beschreibung anzeigen in

Aktiviert/Deaktiviert die Scrollbar

#include <GuiScrollBars.au3>
_GUIScrollBars_EnableScrollBar ( $hWnd [, $iSBflags = $SB_BOTH [, $iArrows = $ESB_ENABLE_BOTH]] )

Parameter

$hWnd Handle des Fensters
$iSBflags [optional] Legt den Typ der Scrollbar fest. Dieser Parameter kann einer der folgenden Werte sein:
    $SB_BOTH - Aktiviert oder deaktiviert die Pfeile auf der horizontalen und vertikalen Scrollbar, welche zu dem festgelegten Fenster gehört.
    $SB_CTL - Gibt an, das die Scrollbar vom Typ ScrollBar ist. Der $hWnd-Parameter muss dabei das Handle des ScrollBar-Controls sein.
    $SB_HORZ - Aktiviert oder deaktiviert die Pfeile auf der horizontalen Scrollbar, welche zu dem festgelegten Fenster gehört.
    $SB_VERT - Aktiviert oder deaktiviert die Pfeile auf der vertikalen Scrollbar, welche zu dem festgelegten Fenster gehört.
$iArrows [optional] Legt fest, ob die Pfeile der Scrollbar aktiviert oder deaktiviert werden sollen und gibt an, welche Pfeile aktiviert oder deaktiviert werden sollen.
    Dieser Parameter kann einer der folgenden Werte sein:
    $ESB_DISABLE_BOTH - Deaktiviert beide Pfeile der Scrollbar.
    $ESB_DISABLE_DOWN - Deaktiviert den "nach unten"-Pfeil der vertikalen Scrollbar.
    $ESB_DISABLE_LEFT - Deaktiviert den "nach links"-Pfeil der vertikalen Scrollbar.
    $ESB_DISABLE_LTUP - Deaktiviert den "nach links"-Pfeil der horizontalen Scrollbar oder den "nach oben"-Pfeil der vertikalen Scrollbar.
    $ESB_DISABLE_RIGHT - Deaktiviert den "nach rechts"-Pfeil der horizontalen Scrollbar.
    $ESB_DISABLE_RTDN - Deaktiviert den "nach rechts"-Pfeil der horizontalen Scrollbar oder den "nach unten"-Pfeil der vertikalen Scrollbar.
    $ESB_DISABLE_UP - Deaktiviert den "nach oben"-Pfeil der vertikalen Scrollbar.
    $ESB_ENABLE_BOTH - Aktiviert beide Pfeile der Scrollbar.

Rückgabewert

Erfolg: True
Fehler: False

Bemerkungen

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUIScrollBars_ShowScrollBar

Siehe auch

Suche nach EnableScrollBar in der MSDN Bibliothek.

Beispiel

#include "Extras\HelpFileInternals.au3"

#include <GUIConstantsEx.au3>
#include <GuiScrollBars.au3>
#include <WindowsStylesConstants.au3>

Example()

Func Example()
    Local $hGuiMsg, $hGui

    $hGui = GUICreate("ScrollBar: Beispiel", 400, 400, -1, -1, BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU, $WS_SIZEBOX))
    _MemoCreate(2, 32, 380, 226, BitOR($WS_HSCROLL, $WS_VSCROLL))
    GUICtrlSetResizing($_g_idLst_Memo, $GUI_DOCKALL)
    GUICtrlSetFont($_g_idLst_Memo, 9, 400, 0, "Courier New")
    GUISetBkColor(0x88AABB)

    GUISetState(@SW_SHOW)

    _GUIScrollBars_Init($hGui)

    _MemoWrite("Deaktiviert den 'nach unten'-Pfeil: " & _GUIScrollBars_EnableScrollBar($hGui, $SB_VERT, $ESB_DISABLE_DOWN))
    Sleep(3000)
    _MemoWrite("Deaktiviert den 'nach oben'-Pfeil: " & _GUIScrollBars_EnableScrollBar($hGui, $SB_VERT, $ESB_DISABLE_UP))
    Sleep(3000)
    _MemoWrite("Aktiviert beide Pfeile: " & _GUIScrollBars_EnableScrollBar($hGui, $SB_VERT, $ESB_ENABLE_BOTH))
    Sleep(3000)
    _MemoWrite("Deaktiviert den 'nach links'-Pfeil: " & _GUIScrollBars_EnableScrollBar($hGui, $SB_HORZ, $ESB_DISABLE_LEFT))
    Sleep(3000)
    _MemoWrite("Deaktiviert den 'nach rechts'-Pfeil: " & _GUIScrollBars_EnableScrollBar($hGui, $SB_HORZ, $ESB_DISABLE_RIGHT))
    Sleep(3000)
    _MemoWrite("Aktiviert beide Pfeile: " & _GUIScrollBars_EnableScrollBar($hGui, $SB_HORZ, $ESB_ENABLE_BOTH))

    While 1
        $hGuiMsg = GUIGetMsg()

        Switch $hGuiMsg
            Case $GUI_EVENT_CLOSE;, $nExititem
                ExitLoop
        EndSwitch
    WEnd

    Exit
EndFunc   ;==>Example