Funktionreferenz

_GUIScrollBars_GetScrollBarInfoEx

Beschreibung anzeigen in

Ermittelt Informationen über die festgelegten Scrollbar

#include <GuiScrollBars.au3>
_GUIScrollBars_GetScrollBarInfoEx ( $hWnd, $iObject )

Parameter

$hWnd Handle des Fensters
$iObject Legt das Scrollbar-Objekt fest. Dieser Parameter kann einer der folgenden Werte sein:
    $OBJID_CLIENT - Der $hWnd Parameter ist ein Handle des ScrollBar-Controls.
    $OBJID_HSCROLL - Die horizontale Scrollbar des $hWnd Fensters.
    $OBJID_VSCROLL - Die vertikale Scrollbar des $hWnd Fensters.

Rückgabewert

Erfolg: eine $tagSCROLLBARINFO Struktur
Fehler: und setzt das @error Flag auf ungleich 0

Bemerkungen

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

$tagSCROLLBARINFO, _GUIScrollBars_GetScrollBarRect, _GUIScrollBars_GetScrollBarRGState, _GUIScrollBars_GetScrollBarXYLineButton, _GUIScrollBars_GetScrollBarXYThumbBottom, _GUIScrollBars_GetScrollBarXYThumbTop

Siehe auch

Suche nach GetScrollBarInfo in der MSDN Bibliothek.

Beispiel

#include "Extras\HelpFileInternals.au3"

#include <GUIConstantsEx.au3>
#include <GuiScrollBars.au3>
#include <WindowsStylesConstants.au3>

Example()

Func Example()
    Local $hGuiMsg, $hGui, $tSCROLLBARINFO

    $hGui = GUICreate("ScrollBar: Beispiel", 400, 400, -1, -1, BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU, $WS_SIZEBOX))
    _MemoCreate(2, 2, 380, 360, BitOR($WS_HSCROLL, $WS_VSCROLL))
    GUICtrlSetResizing($_g_idLst_Memo, $GUI_DOCKALL)
    GUICtrlSetFont($_g_idLst_Memo, 9, 400, 0, "Courier New")
    GUISetBkColor(0x88AABB)

    GUISetState(@SW_SHOW)

    _GUIScrollBars_Init($hGui)

    $tSCROLLBARINFO = _GUIScrollBars_GetScrollBarInfoEx($hGui, $OBJID_HSCROLL)
    _MemoWrite("Horizontal" & @CRLF & "--------------------------------------")
    _MemoWrite("Links.........: " & DllStructGetData($tSCROLLBARINFO, "Left"))
    _MemoWrite("Oben..........: " & DllStructGetData($tSCROLLBARINFO, "Top"))
    _MemoWrite("Rechts........: " & DllStructGetData($tSCROLLBARINFO, "Right"))
    _MemoWrite("Unten.......: " & DllStructGetData($tSCROLLBARINFO, "Bottom"))
    _MemoWrite("dxyLineButton: " & DllStructGetData($tSCROLLBARINFO, "dxyLineButton"))
    _MemoWrite("xyThumbTop...: " & DllStructGetData($tSCROLLBARINFO, "xyThumbTop"))
    _MemoWrite("xyThumbBottom: " & DllStructGetData($tSCROLLBARINFO, "xyThumbBottom"))
    For $x = 0 To 5
        _MemoWrite("rgstate[" & $x & "]...: " & DllStructGetData($tSCROLLBARINFO, "rgstate", $x + 1))
    Next

    While 1
        $hGuiMsg = GUIGetMsg()

        Switch $hGuiMsg
            Case $GUI_EVENT_CLOSE
                ExitLoop
        EndSwitch
    WEnd

    Exit
EndFunc   ;==>Example