_GUIScrollBars_SetScrollRange

Beschreibung anzeigen in

Setzt die minimale und maximale Scrollposition für die festgelegte Scrollbar

#include <GuiScrollBars.au3>
_GUIScrollBars_SetScrollRange ( $hWnd, $iBar, $iMinPos, $iMaxPos )

Parameter

$hWnd	Handle des Fensters
$iBar	Legt den Typ der Scrollbar fest. Dieser Parameter kann einer der folgenden Werte sein: $SB_CTL - Setzt den Bereich eines ScrollBar-Controls. Der $hWnd Parameter muss dabei das Handle des ScrollBar-Control sein. $SB_HORZ - Setzt den Bereich einer standardmäßigen horizontalen Scrollbar. $SB_VERT - Setzt den Bereich einer standardmäßigen vertikalen Scrollbar.
$iMinPos	Legt die minimale Scrollposition fest
$iMaxPos	Legt die maximale Scrollposition fest

Rückgabewert

Erfolg:	True
Fehler:	False

Bemerkungen

- - - - - - - - Erklärung der Controls - - - - - - - -

Siehe auch

Suche nach SetScrollRange in der MSDN Bibliothek.

Beispiel

#include "Extras\HelpFileInternals.au3"

#include <GUIConstantsEx.au3>
#include <GuiScrollBars.au3>
#include <WindowsStylesConstants.au3>

Example()

Func Example()
    Local $hGuiMsg, $hGui, $aRangeMinMax

    $hGui = GUICreate("ScrollBar: Beispiel", 400, 400, -1, -1, BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU, $WS_SIZEBOX))
    _MemoCreate(2, 2, 380, 380, BitOR($WS_HSCROLL, $WS_VSCROLL))
    GUICtrlSetResizing($_g_idLst_Memo, $GUI_DOCKALL)
    GUICtrlSetFont($_g_idLst_Memo, 9, 400, 0, "Courier New")
    GUISetBkColor(0x88AABB)

    GUISetState(@SW_SHOW)

    _GUIScrollBars_Init($hGui)

    $aRangeMinMax = _GUIScrollBars_GetScrollRange($hGui, $SB_VERT)
    _MemoWrite("Vertikaler Min/Max Bereich: " & $aRangeMinMax[0] & "/" & $aRangeMinMax[1])
    $aRangeMinMax = _GUIScrollBars_GetScrollRange($hGui, $SB_HORZ)
    _MemoWrite("Horizontaler Min/Max Bereich: " & $aRangeMinMax[0] & "/" & $aRangeMinMax[1])
    Sleep(1000)
    _GUIScrollBars_SetScrollRange($hGui, $SB_VERT, 3, 30)
    $aRangeMinMax = _GUIScrollBars_GetScrollRange($hGui, $SB_VERT)
    _MemoWrite("Neuer vertikaler Min/Max Bereich: " & $aRangeMinMax[0] & "/" & $aRangeMinMax[1])
    Sleep(1000)
    _GUIScrollBars_SetScrollRange($hGui, $SB_HORZ, 10, 98)
    $aRangeMinMax = _GUIScrollBars_GetScrollRange($hGui, $SB_HORZ)
    _MemoWrite("Neuer horizontaler Min/Max Bereich: " & $aRangeMinMax[0] & "/" & $aRangeMinMax[1])

    While 1
        $hGuiMsg = GUIGetMsg()

        Switch $hGuiMsg
            Case $GUI_EVENT_CLOSE
                ExitLoop
        EndSwitch
    WEnd

    Exit
EndFunc   ;==>Example