Funktionreferenz

_GUIToolTip_SetDelayTime

Beschreibung anzeigen in

Setzt die Dauer der Initial-, Popup- und Reshow-Dauer eines Tooltips

#include <GuiToolTip.au3>
_GUIToolTip_SetDelayTime ( $hWnd, $iDuration, $iTime )

Parameter

$hWnd Handle des Controls (welches von _GUIToolTip_Create zurückgegeben wird.)
$iDuration Flag welches festlegt, welcher Dauerwert gesetzt werden soll:
    $TTDT_AUTOMATIC (0) - Setzt alle drei Verzögerungszeiten auf die Standardeinstellung. Siehe Bemerkungen.
    $TTDT_RESHOW (1) - Verzögerungszeit bis nachfolgende ToolTip Fenster angezeigt werden, wenn der Mauszeiger von einem Tool auf ein anderes zu bewegen
    $TTDT_AUTOPOP (2) - Zeit die das ToolTip Fenster sichtbar bleibt falls der Mauszeiger innerhalb der begrenzenden Rechtecks steht
    $TTDT_INITIAL (3) - Zeit die der Mauszeiger innerhalb des Tool stehen muss bevor das Fenster erscheint

Die Konstanten sind in ToolTipConstants.au3 definiert.
$iTime Verzögerungszeit in Millisekunden

Rückgabewert

Keine.

Bemerkungen

Die standardmäßige Verzögerungszeit basieren auf der Doppelklickzeit. Die Autopop-Zeit wird zehn mal so groß wie die Initial-Zeit sein und die Reshow-Zeit ist ein Fünftel der Initial-Zeit.
Für die standardmäßige Zeit von 500ms, betragen die Verzögerungen der Initial-, Autopop- und Reshow-Zeit 500ms, 5000ms und 100ms.

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUIToolTip_GetDelayTime

Beispiel

#include <GUIConstantsEx.au3>
#include <GUIToolTip.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $hGUI = GUICreate("ToolTip Get/Set DelayTime (v" & @AutoItVersion & ")", 350, 200)

    Local $idButton = GUICtrlCreateButton("This is a button", 30, 32, 130, 28)
    Local $hButton = GUICtrlGetHandle($idButton)
    ; Create a tooltip control
    Local $hToolTip = _GUIToolTip_Create($hGUI)

    ; Add a tool to the tooltip control
    _GUIToolTip_AddTool($hToolTip, 0, "This is the ToolTip text", $hButton)

    ; set the time for how long the tooltip displays, to 1500 ms ($TTDT_AUTOPOP)
    _GUIToolTip_SetDelayTime($hToolTip, $TTDT_AUTOPOP, 1500)
    GUISetState(@SW_SHOW)

    ; Retrieve and display the time that the tooltip displays
    MsgBox($MB_SYSTEMMODAL, 'Message', 'Display time : ' & _GUIToolTip_GetDelayTime($hToolTip, $TTDT_AUTOPOP) & ' ms')

    While 1
        If GUIGetMsg() = $GUI_EVENT_CLOSE Then ExitLoop
    WEnd
    _GUIToolTip_Destroy($hToolTip)
    GUIDelete($hGUI)

EndFunc   ;==>Example